troublesave

<cfcomponent displayname="Lectures" extends="com.sebtools.Records" output="no">

<cffunction name="exportLecture" access="public" returntype="numeric" output="no" hint="I export a lecture to AAT.">

	<cfset var qCategory = Parent.AAT.Categories.getCategories(CategoryName="RESEARCH, TEACHING AND CLINICAL CONTRIBUTIONS: REPORT OF TEACHING: LOCAL CONTRIBUTIONS: GRADUATE MEDICAL COURSES, SEMINARS AND INVITED TEACHING PRESENTATIONS: TEACHING ROLES",fieldlist="CategoryID",maxrows=1)>
	<cfset var sAAT = {}>
	<cfset var AATContent = "">

	<cfsavecontent variable="AATContent"><cfoutput>
<table border="0" cellspacing="0" cellpadding="10" width="850">
    <tbody>
        <tr>
            <td style="vertical-align:top">#Year(Arguments.ActivityDateStart)#</td>
            <td style="vertical-align:top">
				<em>Department/Residency Conference -- OU School of Community Medicine</em> ( #Arguments.Instructor# )<br />
            	Teaching Role: Lecturer -- <em>#Arguments.LectureName#</em> (#DateFormat(Arguments.ActivityDateStart,"m/d/yyyy")#)
            </td>
        </tr>
    </tbody>
</table>
	</cfoutput></cfsavecontent>

	<cfif StructKeyExists(Arguments,"ActivityID")>
		<cfset sAAT["ActivityID"] = Arguments.ActivityID>
	</cfif>

	<cfset sAAT["PersonIDs"] = Arguments.EDPersons>
	<cfset sAAT["CategoryID"] = qCategory.CategoryID>
	<cfset sAAT["ActivityName"] = "Department/Residency Conference Lecture">
	<cfset sAAT["ActivityDateStart"] = Arguments.ActivityDateStart>
	<cfset sAAT["ActivityDescription"] = AATContent>

	<cfreturn Parent.AAT.Activities.saveActivity(ArgumentCollection=sAAT)>
</cffunction>

<cffunction name="saveLecture" access="public" returntype="string" output="no" hint="I save one Lecture.">

	<cfset var LectureID = 0>
	<cfset var qLecture = 0>
	<cfset var qConference = Parent.Conferences.getConference(arguments.ConferenceID)>
	<cfset var sExport = Duplicate(Arguments)>
	<cfset var sUpdate = {}>

	<cfset LectureID = saveRecord(argumentCollection=arguments)>

	<!--- Export new lectures to AAT --->
	<!---
	New lecture (no LectureID argument) = add new AAT activity
	Existing lecture with a corresponding AAT Activity = update AAT Activity
	Existing lecture with no corresponding AAT Activity = do nothing
	--->

	<cfif NOT StructKeyExists(Arguments,"LectureID") AND LectureID>

		<cfset qLecture = getLecture(LectureID=LectureID,fieldlist="Instructor")>

		<cfset sExport["ActivityDateStart"] = qConference.ConferenceDate>
		<cfset sExport["Instructor"] = qLecture.Instructor>

		<cfset sUpdate["LectureID"] = LectureID>
		<cfset sUpdate["AATActivityID"] = exportLecture(ArgumentCollection=sExport)>

		<cfset saveRecord(ArgumentCollection=sUpdate)>

	<cfelseif StructKeyExists(Arguments,"LectureID")>

		<cfset qLecture = getLecture(LectureID=LectureID,fieldlist="Instructor,AATActivityID,LectureName")>

		<cfif isBoolean(qLecture.AATActivityID) AND qLecture.AATActivityID>

			<!--- Must get updated lecture --->
			<cfset sExport["ActivityID"] = qLecture.AATActivityID>
			<cfset sExport["ActivityDateStart"] = qConference.ConferenceDate>
			<cfset sExport["Instructor"] = qLecture.Instructor>
			<cfset sExport["LectureName"] = qLecture.LectureName>
			<cfset exportLecture(ArgumentCollection=sExport)>
		</cfif>

	</cfif>

	<cfreturn LectureID>
</cffunction>

</cfcomponent>