South African individual income tax rates 2016

# taxable income
ti(i) = i <= 73650 ? 0 : i - 73650

# tax on taxable income
t(ti) = \
  (ti <= 181900) ? \
    0.18 * ti \
  :((ti <= 284100) ? \
    32742 + 0.26 * (ti - 181900) \
  :((ti <= 393200) ? \
    59314 + 0.31 * (ti - 284100) \
  :((ti <= 550100) ? \
    93135 + 0.36 * (ti - 393200) \
  :((ti <= 701300) ? \
    149619 + 0.38 * (ti - 550100) \
  : \
    208587 + 0.41 * (ti - 701300) \
  ))))

set arrow from 73650,graph(0,0) to 73650,graph(1,1) nohead
set arrow from 255550,graph(0,0) to 255550,graph(1,1) nohead
set arrow from 357750,graph(0,0) to 357750,graph(1,1) nohead
set arrow from 466850,graph(0,0) to 466850,graph(1,1) nohead
set arrow from 623750,graph(0,0) to 623750,graph(1,1) nohead
set arrow from 774950,graph(0,0) to 774950,graph(1,1) nohead

set grid
set xrange [0:1000000]
set yrange [0:350000]
set y2range [0:70]
set y2tics
set samples 100000

set title "South African individual income tax rates 2016"
set xlabel "Annual income"
set ylabel "Tax rands"
set y2label "Tax percentage"
set format x '%.0f'
set key opaque

set terminal pngcairo enhanced
set output "tax.png"

plot t(ti(x)) title "Tax rands" axes x1y1, \
     t(ti(x))/x*100 title "Tax percentage" axes x1y2