Gradle Eclipse Problem

-----------------------
Structure
-----------------------
base
 - model
   - src/main/java/...
   - build.gradle
 - api
   - src/main/java/...
   - build.gradle
 - impl
   - src/main/java/...
   - build.gradle
 - web
   - src/main/java/...
   - src/main/webapp/...
   - build.gradle
 - ear
   - src/main/application/...
   - build.gradle
 - build.gradle
 - settings.gradle

-----------------------
base/model/build.gradle
-----------------------
dependencies {
    compile ext.libraries.'hibernate-envers'
    compile ext.libraries.'jboss-javaee-6.0'
}
-----------------------
base/api/build.gradle
-----------------------
dependencies {
    compile project(':model')
    compile ext.libraries.'cal10n-api'
    compile ext.libraries.'jboss-javaee-6.0'
}
-----------------------
base/impl/build.gradle
-----------------------
dependencies {
    compile project(':model')
    compile project(':api')
    compile ext.libraries.'jboss-javaee-6.0'
}
-----------------------
base/web/build.gradle
-----------------------
apply plugin: 'war'

configurations {
    all*.exclude group: 'xml-apis', module: 'xml-apis'
}

dependencies {
    compile ext.libraries.'rewrite-integration-faces'
    compile ext.libraries.'rewrite-servlet'
    compile ext.libraries.'rewrite-integration-cdi'

    providedCompile project(':model')
    providedCompile project(':api')
    providedCompile project(':impl')
    providedCompile ext.libraries.'cal10n-api'
    providedCompile ext.libraries.'logback-classic'
    providedCompile ext.libraries.'myfaces-extcdi-bundle-jsf20'
    providedCompile ext.libraries.'jboss-javaee-6.0'

    testCompile ext.testLibraries.'geronimo-servlet_3.0_spec'
}
-----------------------
base/ear/build.gradle
-----------------------
apply plugin: 'ear'
apply plugin: 'java'

configurations {
    all*.exclude group: 'org.jboss.spec', module: 'jboss-javaee-6.0'
    all*.exclude group: 'com.sun.faces', module: 'jsf-api'
    all*.exclude group: 'org.apache.geronimo.specs', module: 'geronimo-servlet_3.0_spec'
    all*.exclude group: 'junit', module: 'junit'
    all*.exclude group: 'xalan', module: 'xalan'
}

dependencies {
    deploy project(path: ':web',  configuration: 'archives')
    deploy project(':impl')

    earlib project(':model')
    earlib project(':api')
    earlib ext.libraries.'cal10n-api'
    earlib ext.libraries.'logback-classic'
    earlib ext.libraries.'myfaces-extcdi-bundle-jsf20'
}

ear {
    deploymentDescriptor {
        webModule(":web", "/admin")
        module(":impl", "java")
    }
}
-----------------------
base/build.gradle
-----------------------
allprojects{
    apply plugin: 'eclipse-wtp'

    ext.langLevel = 1.6

    configurations {
        all*.exclude group: 'xml-apis', module: 'xml-apis'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url 'http://repository.jboss.org/nexus/content/groups/public' }
    }

    ext.commonsBeanutilsVersion = '1.8.3'
    ext.commonsCollectionsVersion = '3.2.1'
    ext.commonsFileuploadVersion = '1.2.2'
    ext.commonsIoVersion = '2.4'
    ext.cal10nVersion = '0.7.4'
    ext.logbackVersion = '1.0.6'
    ext.slf4jVersion = '1.6.6'
    ext.hibernateVersion = '4.1.6.Final'
    ext.jbossSpecVersion = '3.0.2.Final'
    ext.arquillianVersion = '1.0.0.Final'
    ext.seleniumVersion = '2.21.0'
    ext.jsfApiVersion = '2.1.11'
    ext.geronimoSpecVersion = '1.0'
    ext.junitVersion = '4.10'
    ext.derbyVersion = '10.9.1.0'
    ext.rewriteVersion = '1.1.0.Final'
    ext.extCdiVersion = '1.0.5'

    ext.libraries = [
        'commons-beanutils':[group:'commons-beanutils', name:'commons-beanutils', version: ext.commonsBeanutilsVersion],
        'commons-collections':[group:'commons-collections', name:'commons-collections', version: ext.commonsCollectionsVersion],
        'commons-fileupload':[group:'commons-fileupload', name:'commons-fileupload', version: ext.commonsFileuploadVersion],
        'commons-io':[group:'commons-io', name:'commons-io', version: ext.commonsIoVersion],
        'cal10n-api':[group:'ch.qos.cal10n', name:'cal10n-api', version: ext.cal10nVersion],
        'logback-core':[group:'ch.qos.logback', name:'logback-core', version: ext.logbackVersion],
        'logback-classic':[group:'ch.qos.logback', name:'logback-classic', version: ext.logbackVersion],
        'jcl-over-slf4j':[group:'org.slf4j', name:'jcl-over-slf4j', version: ext.slf4jVersion],
        'jul-to-slf4j':[group:'org.slf4j', name:'jul-to-slf4j', version: ext.slf4jVersion],
        'log4j-over-slf4j':[group:'org.slf4j', name:'log4j-over-slf4j', version: ext.slf4jVersion],
        'slf4j-api':[group:'org.slf4j', name:'slf4j-api', version: ext.slf4jVersion],
        'hibernate-envers':[group:'org.hibernate',  name:'hibernate-envers', version: ext.hibernateVersion],
        'jboss-javaee-6.0':[group:'org.jboss.spec', name:'jboss-javaee-6.0', version: ext.jbossSpecVersion],
        'rewrite-integration-faces':[group:'org.ocpsoft.rewrite', name:'rewrite-integration-faces', version: ext.rewriteVersion],
        'rewrite-servlet':[group:'org.ocpsoft.rewrite', name:'rewrite-servlet', version: ext.rewriteVersion],
        'rewrite-integration-cdi':[group:'org.ocpsoft.rewrite', name:'rewrite-integration-cdi',version: ext.rewriteVersion],
        'myfaces-extcdi-bundle-jsf20':[group:'org.apache.myfaces.extensions.cdi.bundles', name:'myfaces-extcdi-bundle-jsf20', version: ext.extCdiVersion]
    ]

    ext.testLibraries = [
        'jsf-api':[group:'com.sun.faces', name:'jsf-api', version: ext.jsfApiVersion],
        'geronimo-servlet_3.0_spec':[group:'org.apache.geronimo.specs', name:'geronimo-servlet_3.0_spec', version: ext.geronimoSpecVersion],
        'junit' :[group:'junit', name:'junit',  version: ext.junitVersion]
    ]

    version = '1.0'
}

def javaProjects() {
    subprojects.findAll { project -> (project.name != 'basic-profile')}
}

configure(javaProjects()) {
    apply plugin: 'java'

    sourceCompatibility = ext.langLevel
    targetCompatibility = ext.langLevel

    dependencies { testCompile testLibraries.'junit'
        compile ext.libraries.'slf4j-api'
    }

    jar { manifest.attributes provider: 'gradle' }
}
-----------------------
base/settings.gradle
-----------------------
include "model", "api", "impl", "web", "ear"