PKGBUILD: audio-recorder 1.6.2-3

# Maintainer: Spike29 <leguen.yannick@gmail.com>
# Contributor: Lucas Saliés Brum <lucas@archlinux.com.br>

pkgname=audio-recorder
pkgver=1.6.2
pkgrel=3
pkgdesc="Audio recorder for GNOME and Unity Desktops"
arch=('i686' 'x86_64')
url='https://launchpad.net/audio-recorder'
license=('GPL3')
depends=('gst-plugins-base' 'gtk3' 'libappindicator-gtk3')
makedepends=('intltool')
optdepends=('pulseaudio: for extended recording capabilities'
        'gst-plugins-good: for WAV and Flac encoding'
        'gst-plugins-bad: for AAC encoding'
        'gst-plugins-ugly: for MP3 encoding')
provides=('audio-recorder')
install="$pkgname.install"
conflicts=('audio-recorder-bzr' 'audio-recorder-from-deb')
source=("https://launchpad.net/${pkgname}/trunk/version1.6-2/+download/${pkgname}-1.6-2.tar.gz"
        "fix_gtk3.16_build.patch")
md5sums=('746443bf42981b9e9c342f6d7e3d3855'
         'c3c94120820e28f3fa8da4c48a0a4b11')

prepare() {
  cd "$srcdir/$pkgname"
  # Fix build with GTK 3.16
  # https://bugs.launchpad.net/audio-recorder/+bug/1442219
  patch -p1 < ../fix_gtk3.16_build.patch
}

build() {
  cd "$srcdir/$pkgname"
  ./configure --prefix=/usr
  make
}

package() {
  cd "$srcdir/$pkgname"
  make DESTDIR="$pkgdir/" install
}