Spendensystem

#include <a_samp>
#include <SII>
#define dcmd(%1,%2,%3) if ((strcmp((%3)[1], #%1, true, (%2)) == 0) && ((((%3)[(%2) + 1] == 0) && (dcmd_%1(playerid, "")))||(((%3)[(%2) + 1] == 32) && (dcmd_%1(playerid, (%3)[(%2) + 2]))))) return 1
#define MAX_NUMBER 9999
#define MIN_NUMBER 1000

stock PrintCreatedCodes()
{
    new count = 0;
    for(new i=MIN_NUMBER;i<MAX_NUMBER;i++)
    {
        if(IsValidCode(i))
        {
            count++;
        }
    }
    printf("%i Codes sind aktiv.", count);
    return 1;
}

stock IsValidCode(code)
{
    new folder[50];
    format(folder, 50, "/InsaneSolutions/DonatorCodes/%i.txt", code);
    if(fexist(folder)) return 1;
    return 0;
}

stock CreateCode(code, money, score)
{
        new folder[50];
        format(folder, 50, "/InsaneSolutions/DonatorCodes/%i.txt", code);
        if(INI_Open(folder))
        {
            INI_WriteInt("Money", money);
            INI_WriteInt("Score", score);
            INI_Save();
            INI_Close();
        }
        printf("Code %i wurde erstellt. (Money: %i Score: %i)", code, money, score);
        return 1;
}
public OnFilterScriptInit()
{
    PrintCreatedCodes();
    return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
    dcmd(code, 4, cmdtext);
    dcmd(createcode, 10, cmdtext);
    return 0;
}

dcmd_createcode(playerid, params[])
{
    if(!IsPlayerAdmin(playerid)) return 0;
    new score, money;
    if(sscanf(params, "ii", money, score)) SendClientMessage(playerid, 0xFFFFFF, "Benutze /createcode [money] [score]");
    else
    {
        new rand;
        for(new i=MIN_NUMBER;i<MAX_NUMBER;i++)
        {
            rand = random(MAX_NUMBER-MIN_NUMBER) + MIN_NUMBER;
            if(!IsValidCode(rand))
            {
                CreateCode(rand, money, score);
                new success[128];
                format(success, 128, "{00FF00}Erfolg{FFFFFF}! Code mit Nummer %i wurde erstellt! (Wert: %i $ %i Score)", rand, money, score);
                SendClientMessage(playerid, 0xFFFFFF, success);
                break;
            }
            else if(i == MAX_NUMBER)
            {
                SendClientMessage(playerid, 0xFFFFFF, "{FFFFFF}Es konnte {FF0000}kein{FFFFFF} Code erstellt werden!");
                break;
            }
        }
    }
    return 1;
}

dcmd_code(playerid, params[])
{
    ShowPlayerDialog(playerid, 7777, 1, "{FFFFFF}Code eingeben", "{FFFFFF}Gebe hier deinen Code ein.", "Weiter", "Abbrechen");
    return 1;
    #pragma unused params
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
    if(response==1)
    {
        switch(dialogid)
        {
            case 7777:
            {
                    new id=strval(inputtext);
                    if(id < MIN_NUMBER || id > MAX_NUMBER) ShowPlayerDialog(playerid, 7777, 1, "{FF0000}Ungültiger Code!", "{FF0000}Der eingegebende Code war ungültig!\n\n{FFFFFF}Gebe deinen Code ein:", "Weiter", "Abbrechen");
                    else if(IsValidCode(id))
                    {
                        if(IsPlayerConnected(playerid))
                        {
                            new achievedmoney, achievedscore;
                            new folder[50];
                            format(folder, 50, "/InsaneSolutions/DonatorCodes/%i.txt", id);
                            if(INI_Open(folder))
                            {
                                GivePlayerMoney(playerid, INI_ReadInt("Money"));
                                achievedmoney = INI_ReadInt("Money");
                                SetPlayerScore(playerid, INI_ReadInt("Score"));
                                achievedscore = INI_ReadInt("Score");
                                INI_Close();
                            }
                            INI_Remove(folder);
                            new success[256];
                            format(success, 256, "{FFFFFF}Code akzeptiert.\n{00FF00}%i{FFFFFF}$ und {00FF00}%i{FFFFFF} Score erhalten.\nVielen Dank für die Nutzung des Spendensystems.\nSollten sie einen weiteren Code besitzen,drücken sie Weiter.", achievedmoney, achievedscore);
                            ShowPlayerDialog(playerid, 7778, 0, "{00FF00}Erfolg{FFFFFF}!", success, "Weiter", "Verlassen");
                        }
                    }
                    else ShowPlayerDialog(playerid, 7777, 1, "{FF0000}Ungültiger Code!", "{FF0000}Der eingegebende Code war ungültig!\n\n{FFFFFF}Gebe deinen Code ein:", "Weiter", "Abbrechen");
            }
            case 7778:
            {
                ShowPlayerDialog(playerid, 7777, 1, "{FFFFFF}Code eingeben", "{FFFFFF}Gebe hier deinen Code ein.", "Weiter", "Abbrechen");
            }
        }
    }
    return 0;
}



stock sscanf(string[], format[], {Float,_}:...)
{
    #if defined isnull
        if (isnull(string))
    #else
        if (string[0] == 0 || (string[0] == 1 && string[1] == 0))
    #endif
        {
            return format[0];
        }
    #pragma tabsize 4
    new
        formatPos = 0,
        stringPos = 0,
        paramPos = 2,
        paramCount = numargs(),
        delim = ' ';
    while (string[stringPos] && string[stringPos] <= ' ')
    {
        stringPos++;
    }
    while (paramPos < paramCount && string[stringPos])
    {
        switch (format[formatPos++])
        {
            case '\0':
            {
                return 0;
            }
            case 'i', 'd':
            {
                new
                    neg = 1,
                    num = 0,
                    ch = string[stringPos];
                if (ch == '-')
                {
                    neg = -1;
                    ch = string[++stringPos];
                }
                do
                {
                    stringPos++;
                    if ('0' <= ch <= '9')
                    {
                        num = (num * 10) + (ch - '0');
                    }
                    else
                    {
                        return -1;
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num * neg);
            }
            case 'h', 'x':
            {
                new
                    num = 0,
                    ch = string[stringPos];
                do
                {
                    stringPos++;
                    switch (ch)
                    {
                        case 'x', 'X':
                        {
                            num = 0;
                            continue;
                        }
                        case '0' .. '9':
                        {
                            num = (num << 4) | (ch - '0');
                        }
                        case 'a' .. 'f':
                        {
                            num = (num << 4) | (ch - ('a' - 10));
                        }
                        case 'A' .. 'F':
                        {
                            num = (num << 4) | (ch - ('A' - 10));
                        }
                        default:
                        {
                            return -1;
                        }
                    }
                }
                while ((ch = string[stringPos]) > ' ' && ch != delim);
                setarg(paramPos, 0, num);
            }
            case 'c':
            {
                setarg(paramPos, 0, string[stringPos++]);
            }
            case 'f':
            {

                new changestr[16], changepos = 0, strpos = stringPos;
                while(changepos < 16 && string[strpos] && string[strpos] != delim)
                {
                    changestr[changepos++] = string[strpos++];
                    }
                changestr[changepos] = '\0';
                setarg(paramPos,0,_:floatstr(changestr));
            }
            case 'p':
            {
                delim = format[formatPos++];
                continue;
            }
            case '\'':
            {
                new
                    end = formatPos - 1,
                    ch;
                while ((ch = format[++end]) && ch != '\'') {}
                if (!ch)
                {
                    return -1;
                }
                format[end] = '\0';
                if ((ch = strfind(string, format[formatPos], false, stringPos)) == -1)
                {
                    if (format[end + 1])
                    {
                        return -1;
                    }
                    return 0;
                }
                format[end] = '\'';
                stringPos = ch + (end - formatPos);
                formatPos = end + 1;
            }
            case 'u':
            {
                new
                    end = stringPos - 1,
                    id = 0,
                    bool:num = true,
                    ch;
                while ((ch = string[++end]) && ch != delim)
                {
                    if (num)
                    {
                        if ('0' <= ch <= '9')
                        {
                            id = (id * 10) + (ch - '0');
                        }
                        else
                        {
                            num = false;
                        }
                    }
                }
                if (num && IsPlayerConnected(id))
                {
                    setarg(paramPos, 0, id);
                }
                else
                {
                    #if !defined foreach
                        #define foreach(%1,%2) for (new %2 = 0; %2 < MAX_PLAYERS; %2++) if (IsPlayerConnected(%2))
                        #define __SSCANF_FOREACH__
                    #endif
                    string[end] = '\0';
                    num = false;
                    new
                        name[MAX_PLAYER_NAME];
                    id = end - stringPos;
                    foreach (Player, playerid)
                    {
                        GetPlayerName(playerid, name, sizeof (name));
                        if (!strcmp(name, string[stringPos], true, id))
                        {
                            setarg(paramPos, 0, playerid);
                            num = true;
                            break;
                        }
                    }
                    if (!num)
                    {
                        setarg(paramPos, 0, INVALID_PLAYER_ID);
                    }
                    string[end] = ch;
                    #if defined __SSCANF_FOREACH__
                        #undef foreach
                        #undef __SSCANF_FOREACH__
                    #endif
                }
                stringPos = end;
            }
            case 's', 'z':
            {
                new
                    i = 0,
                    ch;
                if (format[formatPos])
                {
                    while ((ch = string[stringPos++]) && ch != delim)
                    {
                        setarg(paramPos, i++, ch);
                    }
                    if (!i)
                    {
                        return -1;
                    }
                }
                else
                {
                    while ((ch = string[stringPos++]))
                    {
                        setarg(paramPos, i++, ch);
                    }
                }
                stringPos--;
                setarg(paramPos, i, '\0');
            }
            default:
            {
                continue;
            }
        }
        while (string[stringPos] && string[stringPos] != delim && string[stringPos] > ' ')
        {
            stringPos++;
        }
        while (string[stringPos] && (string[stringPos] == delim || string[stringPos] <= ' '))
        {
            stringPos++;
        }
        paramPos++;
    }
    do
    {
        if ((delim = format[formatPos++]) > ' ')
        {
            if (delim == '\'')
            {
                while ((delim = format[formatPos++]) && delim != '\'') {}
            }
            else if (delim != 'z')
            {
                return delim;
            }
        }
    }
    while (delim > ' ');
    return 0;
}