// **************************************************
// 					 KIRGO SUCCESS
// **************************************************

INSTANCE DIA_Scatty_KirgoSuccess (C_INFO)
{
	npc			= Grd_210_Scatty;
	nr			= 1;
	condition	= DIA_Scatty_KirgoSuccess_Condition;
	information	= DIA_Scatty_KirgoSuccess_Info;
	permanent	= 0;
	description = "Ich habe gegen Kirgo gekämpft!";
};

FUNC INT DIA_Scatty_KirgoSuccess_Condition()
{
	var C_NPC Kirgo; 	Kirgo = Hlp_GetNpc(Grd_251_Kirgo);

	if ( (Scatty_ChargeKirgo == LOG_RUNNING) && (Kirgo_Charged == TRUE) && ( (Kirgo.aivar[AIV_WASDEFEATEDBYSC] == TRUE) || (Kirgo.aivar[AIV_HASDEFEATEDSC] == TRUE) ) )
	{
		return 1;
	};
};

FUNC VOID DIA_Scatty_KirgoSuccess_Info()
{
	var C_NPC Kirgo; 	Kirgo = Hlp_GetNpc(Grd_251_Kirgo);

	AI_Output (other,self,"DIA_Scatty_KirgoSuccess_15_00"); //Ich habe gegen Kirgo gekämpft!
	if (Kirgo.aivar[AIV_HASDEFEATEDSC] == TRUE)
	{
		AI_Output (self,other,"DIA_Scatty_KirgoSuccess_01_01"); //Und du hast dich besiegen lassen!
		AI_Output (self,other,"DIA_Scatty_KirgoSuccess_01_02"); //Du erwartest hoffentlich nicht, dass ich durch dein Versagen beeindruckt bin ...
		Scatty_ChargeKirgo = LOG_FAILED;

		B_LogEntry( CH1_JoinOC, "Meinem Niederlage gegen Kirgo hat Scatty nicht sehr beeindruckt.");
	}
	else if (Kirgo.aivar[AIV_WASDEFEATEDBYSC] == TRUE)
	{
		AI_Output (self,other,"DIA_Scatty_KirgoSuccess_01_03"); //Und du hast ihn geschafft! Nicht schlecht für einen Anfänger wie dich! Ich bin beeindruckt!
		Scatty_ChargeKirgo = LOG_SUCCESS;

		B_LogEntry( CH1_JoinOC, "Scatty ist beeindruckt von meinem Kampf gegen Kirgo.");
		B_GiveXP (XP_kirgovictory);
	};
};