API tools faq
paste
Advertisement
Guest User

catlina.bat

a guest
Aug 10th, 2012
147
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 8.70 KB | None | 0 0
raw download clone embed print report
  1. @echo off
  2. if "%OS%" == "Windows_NT" setlocal
  3. rem ---------------------------------------------------------------------------
  4. rem Start/Stop Script for the CATALINA Server
  5. rem
  6. rem Environment Variable Prequisites
  7. rem
  8. rem CATALINA_HOME May point at your Catalina "build" directory.
  9. rem
  10. rem CATALINA_BASE (Optional) Base directory for resolving dynamic portions
  11. rem of a Catalina installation. If not present, resolves to
  12. rem the same directory that CATALINA_HOME points to.
  13. rem
  14. rem CATALINA_OPTS (Optional) Java runtime options used when the "start",
  15. rem "stop", or "run" command is executed.
  16. rem
  17. rem CATALINA_TMPDIR (Optional) Directory path location of temporary directory
  18. rem the JVM should use (java.io.tmpdir). Defaults to
  19. rem %CATALINA_BASE%\temp.
  20. rem
  21. rem JAVA_HOME Must point at your Java Development Kit installation.
  22. rem Required to run the with the "debug" argument.
  23. rem
  24. rem JRE_HOME Must point at your Java Development Kit installation.
  25. rem Defaults to JAVA_HOME if empty.
  26. rem
  27. rem JAVA_OPTS (Optional) Java runtime options used when the "start",
  28. rem "stop", or "run" command is executed.
  29. rem
  30. rem JSSE_HOME (Optional) May point at your Java Secure Sockets Extension
  31. rem (JSSE) installation, whose JAR files will be added to the
  32. rem system class path used to start Tomcat.
  33. rem
  34. rem JPDA_TRANSPORT (Optional) JPDA transport used when the "jpda start"
  35. rem command is executed. The default is "dt_shmem".
  36. rem
  37. rem JPDA_ADDRESS (Optional) Java runtime options used when the "jpda start"
  38. rem command is executed. The default is "jdbconn".
  39. rem
  40. rem JPDA_SUSPEND (Optional) Java runtime options used when the "jpda start"
  41. rem command is executed. Specifies whether JVM should suspend
  42. rem execution immediately after startup. Default is "n".
  43. rem
  44. rem JPDA_OPTS (Optional) Java runtime options used when the "jpda start"
  45. rem command is executed. If used, JPDA_TRANSPORT, JPDA_ADDRESS,
  46. rem and JPDA_SUSPEND are ignored. Thus, all required jpda
  47. rem options MUST be specified. The default is:
  48. rem
  49. rem -Xdebug -Xrunjdwp:transport=%JPDA_TRANSPORT%,
  50. rem address=%JPDA_ADDRESS%,server=y,suspend=%JPDA_SUSPEND%
  51. rem
  52. rem $Id: catalina.bat 500710 2007-01-28 00:24:33Z markt $
  53. rem ---------------------------------------------------------------------------
  54.  
  55. rem Guess CATALINA_HOME if not defined
  56. set CURRENT_DIR=%cd%
  57. if not "%CATALINA_HOME%" == "" goto gotHome
  58. set CATALINA_HOME=%CURRENT_DIR%
  59. if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
  60. cd ..
  61. set CATALINA_HOME=%cd%
  62. cd %CURRENT_DIR%
  63. :gotHome
  64. if exist "%CATALINA_HOME%\bin\catalina.bat" goto okHome
  65. echo The CATALINA_HOME environment variable is not defined correctly
  66. echo This environment variable is needed to run this program
  67. goto end
  68. :okHome
  69.  
  70. rem Get standard environment variables
  71. if exist "%CATALINA_HOME%\bin\setenv.bat" call "%CATALINA_HOME%\bin\setenv.bat"
  72.  
  73. rem Get standard Java environment variables
  74. if exist "%CATALINA_HOME%\bin\setclasspath.bat" goto okSetclasspath
  75. echo Cannot find %CATALINA_HOME%\bin\setclasspath.bat
  76. echo This file is needed to run this program
  77. goto end
  78. :okSetclasspath
  79. set BASEDIR=%CATALINA_HOME%
  80. call "%CATALINA_HOME%\bin\setclasspath.bat" %1
  81. if errorlevel 1 goto end
  82.  
  83. rem Add on extra jar files to CLASSPATH
  84. if "%JSSE_HOME%" == "" goto noJsse
  85. set CLASSPATH=%CLASSPATH%;%JSSE_HOME%\lib\jcert.jar;%JSSE_HOME%\lib\jnet.jar;%JSSE_HOME%\lib\jsse.jar
  86. :noJsse
  87. set CLASSPATH=%CLASSPATH%;%CATALINA_HOME%\bin\bootstrap.jar
  88.  
  89. if not "%CATALINA_BASE%" == "" goto gotBase
  90. set CATALINA_BASE=%CATALINA_HOME%
  91. :gotBase
  92.  
  93. if not "%CATALINA_TMPDIR%" == "" goto gotTmpdir
  94. set CATALINA_TMPDIR=%CATALINA_BASE%\temp
  95. :gotTmpdir
  96.  
  97. if not exist "%CATALINA_HOME%\conf\logging.properties" goto noJuli
  98. set JAVA_OPTS=%JAVA_OPTS% -Djava.util.logging.manager=org.apache.juli.ClassLoaderLogManager -Djava.util.logging.config.file="%CATALINA_BASE%\conf\logging.properties"
  99. :noJuli
  100.  
  101. rem ----- Execute The Requested Command ---------------------------------------
  102.  
  103. echo Using CATALINA_BASE: %CATALINA_BASE%
  104. echo Using CATALINA_HOME: %CATALINA_HOME%
  105. echo Using CATALINA_TMPDIR: %CATALINA_TMPDIR%
  106. if ""%1"" == ""debug"" goto use_jdk
  107. echo Using JRE_HOME: %JRE_HOME%
  108. goto java_dir_displayed
  109. :use_jdk
  110. echo Using JAVA_HOME: %JAVA_HOME%
  111. :java_dir_displayed
  112.  
  113. set _EXECJAVA=%_RUNJAVA%
  114. set MAINCLASS=org.apache.catalina.startup.Bootstrap
  115. set ACTION=start
  116. set SECURITY_POLICY_FILE=
  117. set DEBUG_OPTS=
  118. set JPDA=
  119.  
  120. if not ""%1"" == ""jpda"" goto noJpda
  121. set JPDA=jpda
  122. if not "%JPDA_TRANSPORT%" == "" goto gotJpdaTransport
  123. set JPDA_TRANSPORT=dt_shmem
  124. :gotJpdaTransport
  125. if not "%JPDA_ADDRESS%" == "" goto gotJpdaAddress
  126. set JPDA_ADDRESS=jdbconn
  127. :gotJpdaAddress
  128. if not "%JPDA_SUSPEND%" == "" goto gotJpdaSuspend
  129. set JPDA_SUSPEND=n
  130. :gotJpdaSuspend
  131. if not "%JPDA_OPTS%" == "" goto gotJpdaOpts
  132. set JPDA_OPTS=-Xdebug -Xrunjdwp:transport=%JPDA_TRANSPORT%,address=%JPDA_ADDRESS%,server=y,suspend=%JPDA_SUSPEND%
  133. :gotJpdaOpts
  134. shift
  135. :noJpda
  136.  
  137. if ""%1"" == ""debug"" goto doDebug
  138. if ""%1"" == ""run"" goto doRun
  139. if ""%1"" == ""start"" goto doStart
  140. if ""%1"" == ""stop"" goto doStop
  141. if ""%1"" == ""version"" goto doVersion
  142.  
  143. echo Usage: catalina ( commands ... )
  144. echo commands:
  145. echo debug Start Catalina in a debugger
  146. echo debug -security Debug Catalina with a security manager
  147. echo jpda start Start Catalina under JPDA debugger
  148. echo run Start Catalina in the current window
  149. echo run -security Start in the current window with security manager
  150. echo start Start Catalina in a separate window
  151. echo start -security Start in a separate window with security manager
  152. echo stop Stop Catalina
  153. echo version What version of tomcat are you running?
  154. goto end
  155.  
  156. :doDebug
  157. shift
  158. set _EXECJAVA=%_RUNJDB%
  159. set DEBUG_OPTS=-sourcepath "%CATALINA_HOME%\..\..\java"
  160. if not ""%1"" == ""-security"" goto execCmd
  161. shift
  162. echo Using Security Manager
  163. set SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy
  164. goto execCmd
  165.  
  166. :doRun
  167. shift
  168. if not ""%1"" == ""-security"" goto execCmd
  169. shift
  170. echo Using Security Manager
  171. set SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy
  172. goto execCmd
  173.  
  174. :doStart
  175. shift
  176. if not "%OS%" == "Windows_NT" goto noTitle
  177. set _EXECJAVA=start "Tomcat" %_RUNJAVA%
  178. goto gotTitle
  179. :noTitle
  180. set _EXECJAVA=start %_RUNJAVA%
  181. :gotTitle
  182. if not ""%1"" == ""-security"" goto execCmd
  183. shift
  184. echo Using Security Manager
  185. set SECURITY_POLICY_FILE=%CATALINA_BASE%\conf\catalina.policy
  186. goto execCmd
  187.  
  188. :doStop
  189. shift
  190. set ACTION=stop
  191. goto execCmd
  192.  
  193. :doVersion
  194. %_EXECJAVA% -classpath "%CATALINA_HOME%\lib\catalina.jar" org.apache.catalina.util.ServerInfo
  195. goto end
  196.  
  197.  
  198. :execCmd
  199. rem Get remaining unshifted command line arguments and save them in the
  200. set CMD_LINE_ARGS=
  201. :setArgs
  202. if ""%1""=="""" goto doneSetArgs
  203. set CMD_LINE_ARGS=%CMD_LINE_ARGS% %1
  204. shift
  205. goto setArgs
  206. :doneSetArgs
  207.  
  208. rem Execute Java with the applicable properties
  209. if not "%JPDA%" == "" goto doJpda
  210. if not "%SECURITY_POLICY_FILE%" == "" goto doSecurity
  211. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  212. goto end
  213. :doSecurity
  214. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Djava.security.manager -Djava.security.policy=="%SECURITY_POLICY_FILE%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  215. goto end
  216. :doJpda
  217. if not "%SECURITY_POLICY_FILE%" == "" goto doSecurityJpda
  218. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% %JPDA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  219. goto end
  220. :doSecurityJpda
  221. %_EXECJAVA% %JAVA_OPTS% %CATALINA_OPTS% %JPDA_OPTS% %DEBUG_OPTS% -Djava.endorsed.dirs="%JAVA_ENDORSED_DIRS%" -classpath "%CLASSPATH%" -Djava.security.manager -Djava.security.policy=="%SECURITY_POLICY_FILE%" -Dcatalina.base="%CATALINA_BASE%" -Dcatalina.home="%CATALINA_HOME%" -Djava.io.tmpdir="%CATALINA_TMPDIR%" %MAINCLASS% %CMD_LINE_ARGS% %ACTION%
  222. goto end
  223.  
  224. :end
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!