Computercraft Recipes

// Flexible Circuits
val circuit1 = <ore:circuit1>;
circuit1.add(<IC2:itemPartCircuit>);
circuit1.add(<StevesCarts:ModuleComponents:9>);
val circuit2 = <ore:circuit2>;
circuit2.add(<IC2:itemPartCircuitAdv>);
circuit2.add(<StevesCarts:ModuleComponents:16>);
val keyboard = <ore:keyboard>;
keyboard.add(<MoarPeripherals:blockKeyboardPc>);
keyboard.add(<MoarPeripherals:blockKeyboardMac>);
val keypart = <MoarPeripherals:itemKeyboardPart>;

val plastic = <MineFactoryReloaded:plastic.sheet>;
val cable = <ProjRed|Transmission:projectred.transmission.wire:17>;
val plateIron = <IC2:itemPlates:4>;
val plateGold = <IC2:itemPlates:3>;
val monitor1 = <ComputerCraft:CC-Peripheral:2>;
val monitor2 = <ComputerCraft:CC-Peripheral:4>;
val computer1 = <ComputerCraft:CC-Computer>;
val computer2 = <ComputerCraft:CC-Computer:16384>;
val transmitter = <WR-CBE|Core:wirelessTransceiver>;
val receiver = <WR-CBE|Core:recieverDish>; // That typo is on Chickenbones' end
val blankrecord = <MineFactoryReloaded:record.blank>;
val miniBlackHole = <PortalGun:MiniBlackHole>;
val miningLaser = <IC2:itemToolMiningLaser>;
val advAlloy = <IC2:itemPartAlloy>;
val motor = <IC2:itemRecipePart:1>;
val convexLens = <minechem:minechemOpticalMicroscopeLens:1>;


// Wireless Remote
recipes.remove(<WR-CBE|Addons:remote>);
recipes.addShaped(<WR-CBE|Addons:remote>,
[[null, transmitter, null],
 [plateIron, circuit1, plateIron],
 [null, keypart, null]]);

/*
// Minechem
recipes.remove(<minechem:minechemAtomicManipulator>);
recipes.addShaped(<minechem:minechemAtomicManipulator>,
[[<minecraft:diamond>, convexLens, miningLaser],
 [circuit2, miniBlackHole, circuit2],
 [advAlloy, motor, advAlloy]]);
*/

// Normal Computers
recipes.remove(computer1);
recipes.addShaped(computer1,
[[plastic, monitor1, plastic],
 [plastic, circuit1, plastic],
 [plastic, keyboard, plastic]]);

// Advanced Computers
recipes.remove(computer2);
recipes.addShaped(computer2,
[[plateGold, monitor2, plateGold],
 [plateGold, circuit2, plateGold],
 [plateGold, keyboard, plateGold]]);

// Command Computer
recipes.remove(<ComputerCraft:command_computer>);
recipes.addShaped(<ComputerCraft:command_computer>,
[[<IC2:itemPlates:0>, monitor2, <IC2:itemPlates:0>],
 [<IC2:itemPlates:0>, <minecraft:command_block>, <IC2:itemPlates:0>],
 [<IC2:itemPlates:0>, keyboard, <IC2:itemPlates:0>]]);


// Disk Drive
recipes.remove(<ComputerCraft:CC-Peripheral:0>);
recipes.addShaped(<ComputerCraft:CC-Peripheral:0>,
[[plastic, plastic, plastic],
 [<minecraft:compass>, circuit1, cable],
 [plastic, plastic, plastic]]);

// Printer
recipes.remove(<ComputerCraft:CC-Peripheral:3>);
recipes.addShaped(<ComputerCraft:CC-Peripheral:3>,
[[plastic, plastic, plastic],
 [<minecraft:dye:0>, circuit1, cable],
 [plastic, plastic, plastic]]);


// Normal Monitors
recipes.remove(monitor1);
recipes.addShaped(monitor1 *4,
[[plastic, plastic, plastic],
 [plastic, <IC2:blockLuminatorDark>, plastic],
 [plastic, cable, plastic]]);

// Advanced Monitors
recipes.remove(monitor2);
recipes.addShaped(monitor2 *4,
[[plateGold, plateGold, plateGold],
 [plateGold, <StevesCarts:CartModule:41>, plateGold],
 [plateGold, cable, plateGold]]);


// Wireless Modem
recipes.remove(<ComputerCraft:CC-Peripheral:1>);
recipes.addShaped(<ComputerCraft:CC-Peripheral:1>,
[[transmitter, plastic, receiver],
 [plastic, circuit1, plastic],
 [plastic, cable, plastic]]);

// Wired Modem
recipes.remove(<ComputerCraft:CC-Cable:1>);
recipes.addShaped(<ComputerCraft:CC-Cable:1>,
[[plastic, plastic, plastic],
 [cable, circuit1, cable],
 [plastic, plastic, plastic]]);

// Networking Cable
recipes.remove(<ComputerCraft:CC-Cable:0>);
recipes.addShaped(<ComputerCraft:CC-Cable:0> *4,
[[plastic, plastic, plastic],
 [cable, cable, cable],
 [plastic, plastic, plastic]]);


// Iron Turtles
recipes.remove(<ComputerCraft:CC-Turtle>);
recipes.addShaped(<ComputerCraft:CC-Turtle>,
[[plateIron, computer1, plateIron],
 [plateIron, <minecraft:chest>, plateIron],
 [plateIron, <BuildCraft|Energy:engineBlock:1>, plateIron]]);

// Gold Turtles
recipes.remove(<ComputerCraft:CC-TurtleAdvanced>);
recipes.addShaped(<ComputerCraft:CC-TurtleAdvanced>,
[[plateGold, computer2, plateGold],
 [plateGold, <minecraft:chest>, plateGold],
 [plateGold, <BuildCraft|Energy:engineBlock:1>, plateGold]]);


// Normal Pocket Computer
recipes.removeShaped(<ComputerCraft:pocketComputer:0>,
[[<minecraft:stone>, <minecraft:stone>, <minecraft:stone>],
 [<minecraft:stone>, <minecraft:golden_apple>, <minecraft:stone>],
 [<minecraft:stone>, <minecraft:glass_pane>, <minecraft:stone>]]);
recipes.addShaped(<ComputerCraft:pocketComputer:0>,
[[plastic, monitor1, plastic],
 [plastic, circuit1, plastic],
 [plastic, keypart, plastic]]);

// Advanced Pocket Computer
recipes.removeShaped(<ComputerCraft:pocketComputer:1>,
[[<minecraft:gold_ingot>, <minecraft:gold_ingot>, <minecraft:gold_ingot>],
 [<minecraft:gold_ingot>, <minecraft:golden_apple>, <minecraft:gold_ingot>],
 [<minecraft:gold_ingot>, <minecraft:glass_pane>, <minecraft:gold_ingot>]]);
recipes.addShaped(<ComputerCraft:pocketComputer:1>,
[[plateGold, monitor2, plateGold],
 [plateGold, circuit2, plateGold],
 [plateGold, keypart, plateGold]]);


// Floppy Disks
recipes.remove(<ComputerCraft:disk>);
recipes.remove(<ComputerCraft:diskExpanded>);
recipes.addShaped(<ComputerCraft:diskExpanded>,
[[plastic, <ore:nuggetIron>, plastic],
 [plastic, blankrecord, plastic],
 [plastic, <minecraft:paper>, plastic]]);