JUDAGO STR_MATH v1.3

- JUDAGO Backup of STR_MATH v1.3
- Numbered Variables - Variables that start with numbers.
- Variable expansion - Why Variables Don't Change in Loops.
- Nesting - How to Nest Variables.
 by Einstein1969

@ECHO Off
if "%~3"=="" (
    echo STR_MATH.BAT v1.3
    echo.
    echo Large number and floating point work around script
    echo for Addition, Subtraction, Division and Multiplaction.
    echo Floating point and negitive numbers supported.
    echo.
    echo Usage:
    echo STR_MATH.BAT {Number} {+-X} {Number}
    echo STR_MATH.BAT {Number} / {Number} [n max decimal places]
    echo.
    echo Division defaults to a maximum ten decimal places of output.
    echo An optional user defined max can be input as the fourth number.
    echo No rounding is performed on output of division, any remainder
    echo is discarded.
    echo.
    echo Output Will be echo'd, a "for /f" loop can be used to
    echo capture the output.
    echo.
    set /p =-Judago OCT - DEC 2011- Send bugs to strmathnew.t.remel<nul
    echo @antichef.com
    echo Provided "AS-IS"
    echo Only tested on XP
    goto :eof
)

SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION
set "_INP_OP=%~2"
set "_INP_NUM1=%~1"
set "_INP_NUM2=%~3"
set _DIV_DP=10

for %%a in (INT DP DP1 DP2 LEN LEN1 LEN2 ZERO NEG NEG1 NEG2) do set _INP_%%a=

rem ***** Start Input validation *****

if "%~2"=="/" if not "%~4"=="" (
    for /f "delims=0123456789 tokens=1*" %%a in ("A0%~4") do (
        if "%%b"=="" (
            for /f "tokens=1* delims=0" %%c in ("A0%~4") do (
                if "%%d"=="" (
                    set _DIV_DP=0
                ) else set _DIV_DP=%%d
            )
        ) else 1>&2 Echo ERROR: "%~4" not detected as a valid number of decimal places  &exit /b 1
    )
    shift /4
)

if not "%~4"=="" 1>&2 echo ERROR: Too many arguments: "%~4"&exit /b 1
if not defined _INP_NUM1 1>&2 echo ERROR: Invalid Input: "!_INP_NUM1!"&exit /b 1
if not defined _INP_NUM2 1>&2 echo ERROR: Invalid Input: "!_INP_NUM2!"&exit /b 1
if not defined _INP_OP 1>&2 echo ERROR: Invalid Operator: "!_INP_OP!"&exit /b 1
if not "!_INP_OP:~1!"=="" 1>&2 echo ERROR: Invalid Operator: "!_INP_OP!"&exit /b 1

rem ***** / ***** Start Negitive input ***** \ *****
for %%a in (1 2) do (
    if "!_INP_NUM%%a:~0,1!"=="-" if not "!_INP_NUM%%a:~1!"=="" (
        set _INP_NUM%%a=!_INP_NUM%%a:~1!
        set _INP_NEG%%a=-
    ) else 1>&2 echo ERROR: Invalid input: "!_INP_NUM%%a!"&exit /b 1
)
rem ***** \ ***** End Negitive input ***** / *****

for /f "tokens=1* delims=0123456789." %%a in ("A0!_INP_NUM1!!_INP_NUM2!") do (
    if not "%%b"=="" 1>&2 echo ERROR: Invalid input: "!_INP_NUM1!" **OR** "!_INP_NUM2!"&exit /b 1
)
for %%a in (1 2) do (
    for /f "tokens=1-3 delims=." %%b in ("0!_INP_NUM%%a!0") do (
        if not "%%d"=="" 1>&2 echo ERROR: Invalid input: "!_INP_NUM%%a!"&exit /b 1
    )
)
for /f "tokens=1* delims=/Xx+-" %%a in ("A+!_INP_OP!") do (
    if not "%%b"=="" 1>&2 echo ERROR: Invalid operator: "!_INP_OP!"&exit /b 1
)
rem ***** End input validation *****

rem ***** Start Remove leading zero's / Return for zero sums  *****
for %%a in (1 2) do (
    for /f "tokens=1* delims=0" %%b in ("A0!_INP_NUM%%a!") do (
        if "%%c"=="" (
            if /i "!_INP_OP!"=="x" echo 0
            if "!_INP_OP!"=="/" (
                if %%a==2 (
                    1>&2 Echo ERROR: Divide by zero
                    exit /b 1.
                ) else echo 0
            )
            if "!_INP_OP!"=="-" (
                if %%a==1 (
                    if defined _INP_NEG2 (
                        echo !_INP_NUM2!
                    ) else echo -!_INP_NUM2!
                ) else (
                    echo !_INP_NEG1!!_INP_NUM1!
                )
            )
            if "!_INP_OP!"=="+" (
                if %%a==1 (
                    echo !_INP_NEG2!!_INP_NUM2!
                ) else echo !_INP_NEG1!!_INP_NUM1!
            )
            exit /b 0
        ) else set _INP_NUM%%a=%%c
    )
)
rem ***** End Remove leading zero's / Return for zero sums *****

rem ***** Start Floating point normalisation *****
for %%a in (1 2) do (
    if "!_INP_NUM%%a:~0,1!"=="." set _INP_NUM%%a=0!_INP_NUM%%a!
    if "!_INP_NUM%%a:~-1!"=="." set _INP_NUM%%a=!_INP_NUM%%a!0
    for /l %%b in (0 1 9) do set _INP_NUM%%a=!_INP_NUM%%a:%%b=%%b !
    for %%c in (!_INP_NUM%%a!) do set /a _INP_LEN%%a+=1
    set _INP_NUM%%a=!_INP_NUM%%a: =!
    if "!_INP_NUM%%a!"=="!_INP_NUM%%a:.=!" (
        set _INP_DP%%a=0
    ) else (
        for /l %%d in (!_INP_LEN%%a! -1 1) do (
            if not defined _INP_DP%%a if "!_INP_NUM%%a:~%%d,1!"=="." (
                set /a _INP_DP%%a=!_INP_LEN%%a! - %%d
            )
        )
    )
    set _INP_NUM%%a=!_INP_NUM%%a:.=!
)

if !_INP_DP1! gtr !_INP_DP2! (
    set /a _INP_DP=_INP_DP1 - 1
) else set /a _INP_DP=_INP_DP2 - 1

for /l %%a in (!_INP_DP1! 1 !_INP_DP!) do set _INP_NUM1=!_INP_NUM1!0
for /l %%a in (!_INP_DP2! 1 !_INP_DP!) do set _INP_NUM2=!_INP_NUM2!0
rem ***** End Floating point normalisation *****

rem ***** Start Negitive output checking *****
if /i "!_INP_OP!"=="x" (
    if "!_INP_NEG1!!_INP_NEG2!"=="-" set _INP_NEG=-
) else if "!_INP_OP!"=="+" (
    if "!_INP_NEG1!!_INP_NEG2!"=="--" set _INP_NEG=-
    if defined _INP_NEG2 if not defined _INP_NEG1 (
        call :isgreater !_INP_NUM1! !_INP_NUM2!
        if "!_GTR_RES!"=="3" (
            set _INP_NUM1=%_INP_NUM2%
            set _INP_NUM2=%_INP_NUM1%
            set _INP_NEG=-
        )
        set _INP_OP=-
    )
    if defined _INP_NEG1 if not defined _INP_NEG2 (
        call :isgreater !_INP_NUM1! !_INP_NUM2!
        if "!_GTR_RES!"=="3" (
            set _INP_NUM1=%_INP_NUM2%
            set _INP_NUM2=%_INP_NUM1%
        ) else if "!_GTR_RES!"=="1" set _INP_NEG=-
        set _INP_OP=-
    )
) else if "!_INP_OP!"=="-" (
    if "!_INP_NEG1!!_INP_NEG2!"=="" (
        call :isgreater !_INP_NUM1! !_INP_NUM2!
        if "!_GTR_RES!"=="3" (
            set _INP_NUM1=%_INP_NUM2%
            set _INP_NUM2=%_INP_NUM1%
            set _INP_NEG=-
        )
    )
    if "!_INP_NEG1!!_INP_NEG2!"=="--" (
        call :isgreater !_INP_NUM1! !_INP_NUM2!
        if "!_GTR_RES!"=="3" (
            set _INP_NUM1=%_INP_NUM2%
            set _INP_NUM2=%_INP_NUM1%
        ) else if "!_GTR_RES!"=="1" set _INP_NEG=-
    )
    if defined _INP_NEG2 if not defined _INP_NEG1 set _INP_OP=+
    if defined _INP_NEG1 if not defined _INP_NEG2 (
        set _INP_NEG=-
        set _INP_OP=+
    )
) else if "!_INP_OP!"=="/" (
    if "!_INP_NEG1!!_INP_NEG2!"=="--" set _INP_NEG=
    if "!_INP_NEG1!!_INP_NEG2!"=="-"  set _INP_NEG=-
)
rem ***** End Negitive output checking *****

if "!_INP_OP!"=="-" goto subtract
if "!_INP_OP!"=="+" goto add
if /i "!_INP_OP!"=="X" goto multiply
if "!_INP_OP!"=="/" goto divide
goto help

:SUBTRACT
if "%~1"=="@" (
    set _SUB_NUM1=%~2
    set _SUB_NUM2=%~3
) else (
    set _SUB_NUM1=!_INP_NUM1!
    set _SUB_NUM2=!_INP_NUM2!
)
for %%a in (CHA RES LEN1 LEN2 CAR TOT) do set _SUB_%%a=
for %%a in (1 2) do (
    for /l %%b in (0 1 9) do set _SUB_NUM%%a=!_SUB_NUM%%a:%%b=%%b !
    for %%c in (!_SUB_NUM%%a!) do set /a _SUB_LEN%%a+=1
    set _SUB_NUM%%a=!_SUB_NUM%%a: =!
)
if !_SUB_LEN1! gtr !_SUB_LEN2! (
    set /a _SUB_LEN=_SUB_LEN1 - 1
) else set /a _SUB_LEN=_SUB_LEN2 - 1
for /l %%b in (!_SUB_LEN1! 1 !_SUB_LEN!) do set _SUB_NUM1=0!_SUB_NUM1!
for /l %%b in (!_SUB_LEN2! 1 !_SUB_LEN!) do set _SUB_NUM2=0!_SUB_NUM2!
for /l %%a in (!_SUB_LEN! -1 0) do (
    set /a _SUB_RES=!_SUB_NUM1:~%%a,1! - !_SUB_NUM2:~%%a,1!
    if !_SUB_RES! lss 0 (
        set _SUB_TAKE=
        for /l %%b in (%%a -1 0) do if not defined _SUB_TAKE (
            if not "%%b"=="%%a" (
                if not "!_SUB_NUM1:~%%b,1!"=="0" (
                    set /a _SUB_CHA=!_SUB_NUM1:~%%b,1! - 1
                    set /a _SUB_TAKE=%%b + 1
                    for %%c in (!_SUB_TAKE!) do set _SUB_NUM1=!_SUB_NUM1:~0,%%b!!_SUB_CHA!!_SUB_NUM1:~%%c!
                    set /a _SUB_RES=1!_SUB_NUM1:~%%a,1! - !_SUB_NUM2:~%%a,1!

                ) else (
                    set /a _SUB_CHA=%%b + 1
                    for %%c in (!_SUB_CHA!) do set _SUB_NUM1=!_SUB_NUM1:~0,%%b!9!_SUB_NUM1:~%%c!
                )
            )
        )
    )
    set _SUB_TOT=!_SUB_RES!!_SUB_TOT!
)
for /f "tokens=1* delims=0" %%a in ("A0!_SUB_TOT!") do set _SUB_TOT=%%b
if not defined _SUB_TOT set _SUB_TOT=0
if not "%~1"=="@" (
    call :FINISH _SUB_TOT
    echo %_INP_NEG%!_SUB_TOT!
)
goto :eof

:ADD
if /I "%~1"=="@" (
    set _ADD_NUM1=%~2
    set _ADD_NUM2=%~3
) else (
    set _ADD_NUM1=!_INP_NUM1!
    set _ADD_NUM2=!_INP_NUM2!
)
for %%a in (LEN1 LEN2 CAR TOT) do set _ADD_%%a=
for %%a in (1 2) do (
    for /l %%b in (0 1 9) do set _ADD_NUM%%a=!_ADD_NUM%%a:%%b=%%b !
    for %%c in (!_ADD_NUM%%a!) do set /a _ADD_LEN%%a+=1
    set _ADD_NUM%%a=!_ADD_NUM%%a: =!
)
if !_ADD_LEN1! gtr !_ADD_LEN2! (
    set /a _ADD_LEN=_ADD_LEN1 - 1
) else set /a _ADD_LEN=_ADD_LEN2 - 1
for /l %%b in (!_ADD_LEN1! 1 !_ADD_LEN!) do set _ADD_NUM1=0!_ADD_NUM1!
for /l %%b in (!_ADD_LEN2! 1 !_ADD_LEN!) do set _ADD_NUM2=0!_ADD_NUM2!
for /l %%a in (!_ADD_LEN! -1 0) do (
    set /a _ADD_CAR=_ADD_CAR + !_ADD_NUM1:~%%a,1! + !_ADD_NUM2:~%%a,1!
    set _ADD_TOT=!_ADD_CAR:~-1!!_ADD_TOT!
    set _ADD_CAR=!_ADD_CAR:~0,-1!
    if not defined _ADD_CAR set _ADD_CAR=0
)
if !_ADD_CAR! gtr 0 set _ADD_TOT=!_ADD_CAR!!_ADD_TOT!
if not "%~1"=="@" (
    Call :FINISH _ADD_TOT
    echo %_INP_NEG%!_ADD_TOT!
)
goto :eof

:MULTIPLY
set /a _INP_DP=(_INP_DP * 2) + 1
set _MUL_NUM1=!_INP_NUM1!
set _MUL_NUM2=!_INP_NUM2!
for %%a in (CAR TOT) do set _MUL_%%a=0
for %%a in (X10 REV1 REV2) do set _MUL_%%a=
for %%a in (1 2) do (
    for /l %%b in (0 1 9) do set _MUL_NUM%%a=!_MUL_NUM%%a:%%b=%%b !
    for %%c in (!_MUL_NUM%%a!) do set _MUL_REV%%a=%%c !_MUL_REV%%a!
)
for %%a in (!_MUL_REV1!) do (
    set _MUL_ROW=!_MUL_X10!
    for %%b in (!_MUL_REV2!) do (
        set /a _MUL_CAR=^(%%a * %%b^) + _MUL_CAR
        set _MUL_ROW=!_MUL_CAR:~-1!!_MUL_ROW!
        set _MUL_CAR=!_MUL_CAR:~0,-1!
        if not defined _MUL_CAR set _MUL_CAR=0
    )
    for /f "tokens=1* delims=0" %%c in ("A0!_MUL_CAR!!_MUL_ROW!") do (
        if not "%%d"=="" (
            call :ADD @ %%d !_MUL_TOT!
            set _MUL_TOT=!_ADD_TOT!
        )
    )
    set _MUL_CAR=
    set _MUL_X10=!_MUL_X10!0
)
Call :FINISH _MUL_TOT
echo %_INP_NEG%!_MUL_TOT!
goto :eof

:DIVIDE
for %%a in (DONE LEN1 LEN2 X10 PAD) do set _DIV_%%a=
for /l %%a in (1 1 %_DIV_DP%) do set _DIV_PAD=0!_DIV_PAD!
set /a _INP_DP=_DIV_DP - 1
set _DIV_NUM1=!_INP_NUM1!!_DIV_PAD!
set _DIV_NUM2=!_INP_NUM2!
set _DIV_TOT=0
set _DIV_LOOP=10
for %%a in (1 2) do (
    for /f "tokens=1* delims=0" %%d in ("A0!_DIV_NUM%%a!") do set _DIV_NUM%%a=%%e
    for /l %%b in (0 1 9) do set _DIV_NUM%%a=!_DIV_NUM%%a:%%b=%%b !
    for %%c in (!_DIV_NUM%%a!) do set /a _DIV_LEN%%a+=1
    set _DIV_NUM%%a=!_DIV_NUM%%a: =!
)
set /a _DIV_LEN1-=1
for /l %%a in (!_DIV_LEN2! 1 !_DIV_LEN1!) do (
    set _DIV_X10=0!_DIV_X10!
    set /a _DIV_LOOP+=10
)
for /l %%a in (0 1 !_DIV_LOOP!) do (
    if not defined _DIV_DONE (
        call :ISGREATER !_DIV_NUM1! !_DIV_NUM2!!_DIV_X10!
        if !_GTR_RES! leq 2 (
            call :SUBTRACT @ !_DIV_NUM1! !_DIV_NUM2!!_DIV_X10!
            set _DIV_NUM1=!_SUB_TOT!
            call :ADD @ !_DIV_TOT! 1!_DIV_X10!
            set _DIV_TOT=!_ADD_TOT!
        ) else if defined _DIV_X10 (
            set _DIV_X10=!_DIV_X10:~1!
        ) else set _DIV_DONE=1
    )
)
Call :finish _DIV_TOT
if "!_DIV_TOT!"=="0" (
    echo 0
    1>&2 echo ERROR: Insufficient decimal places^(!_DIV_DP!^)
) else (
    echo !_INP_NEG!!_DIV_TOT!
)
Goto :eof

:FINISH
set _FIN_NUM=!%~1!
set _FIN_FLAG=
if not defined _INP_DP (
    set _INP_DP=0
) else set /a _INP_DP+=1
if not "!_INP_DP!"=="0" (
    for /l %%a in (1 1 !_INP_DP!) do if "!_FIN_NUM:~%_INP_DP%!"=="" set _FIN_NUM=0!_FIN_NUM!
    set _FIN_NUM=!_FIN_NUM:~0^,-%_INP_DP%!.!_FIN_NUM:~-%_INP_DP%!
    for /l %%a in (!_INP_DP! -1 1) do (
        if "!_FIN_NUM:~-1!"=="0" set _FIN_NUM=!_FIN_NUM:~0^,-1!
        if "!_FIN_NUM:~-1!"=="." set _FIN_NUM=!_FIN_NUM:~0^,-1!
    )
)
for /f "tokens=1* delims=0" %%a in ("A0!_FIN_NUM!") do (
    if "%%b"=="" (
        set _FIN_NUM=0
    ) else set _FIN_NUM=%%b
)
if "!_FIN_NUM:~0,1!"=="." set _FIN_NUM=0!_FIN_NUM!
IF NOT DEFINED _FIN_NUM SET _FIN_NUM=0
set %1=!_FIN_NUM!
goto :eof


:ISGREATER
for /f "tokens=1* delims=0" %%a in ("A0%~1") do (
    if "%%b"=="" (
        set _GTR_NUM1=0
    ) else set _GTR_NUM1=%%b
)
for /f "tokens=1* delims=0" %%a in ("A0%~2") do (
    if "%%b"=="" (
        set _GTR_NUM2=0
    ) else set _GTR_NUM2=%%b
)
for %%a in (RES lEN1 lEN2) do set _GTR_%%a=
for %%a in (1 2) do (
    for /l %%b in (0 1 9) do set _GTR_NUM%%a=!_GTR_NUM%%a:%%b=%%b !
    for %%c in (!_GTR_NUM%%a!) do set /a _GTR_lEN%%a+=1
    set _GTR_NUM%%a=!_GTR_NUM%%a: =!
)
if !_GTR_lEN1! gtr !_GTR_lEN2! (
    set _GTR_RES=1
) else if !_GTR_lEN2! gtr !_GTR_lEN1! (
    set _GTR_RES=3
) else (
    set /a _GTR_lEN1-=1
    for /l %%a in (0 1 !_GTR_lEN1!) do (
        if not defined _GTR_RES (
            if !_GTR_NUM1:~%%a^,1! gtr !_GTR_NUM2:~%%a^,1! set _GTR_RES=1
            if !_GTR_NUM2:~%%a^,1! gtr !_GTR_NUM1:~%%a^,1! set _GTR_RES=3
        )
    )
)
if not defined _GTR_RES set _GTR_RES=2
goto :eof

######

This is a verbatim copy of a how to I posted on another site a while ago. I assure you I wrote every word, I just didn't post it here first:



Content of this page:

Numbered Variables - Variables that start with numbers.
Variable expansion - Why Variables Don't Change in Loops.
Nesting - How to Nest Variables.





Batch Script Variable Expansion, Win2000 and Up.

Variable expansion in Windows 2000 and higher batch scripts.

A great deal of questions in the Programming forum are related to problems caused by the nature of variable expansion in batch scripts. Here I will attempt to outline some of the most common issues.


My variable doesn't seem to work for some reason???


Does the variable in question start with a number?

Batch variables shouldn't start with numbers, in some circumstances they will work, but it's more trouble than it's worth. Variables that start with numbers conflict with parameters, lets say we have a variable called "2var", we can normally set to it fine but when expanding "%2var%" it is interpreted as the batch parameter "%2" then the text "var%";. A delayed expansion variable !2var! will work fine in most cases.

It is also worth noting that "set /a", flatout refuses to assign to variables that start with numbers and won't perform arithmetic on them unless they are expanded.



Why doesn't [insert variable name] change in my for loop/if statement?


Firstly you must understand the manner that variables are expanded and how batch scripts are interpreted.

Batch scripts are read line-by-line into the command processor cmd.exe(or command.com for DOS and Win9x). Any variables are replaced with their values and then the line is executed; variables are updated after each line is interpreted.

Enter code blocks: A group of commands enclosed in brackets is a code block. They are most commonly seen trailing for loops or if statements but can be used on there own. Code blocks are treated differently in terms of variable expansion, they are treated as one line. This means any variables that are set inside the block don't get updated until the block has finished execution, in the case of for loops the variables aren't updated until the entire loop has finished executing.

Here's an example:

Normal code:



set test=Hello!
echo %test%

The result is:


Hello!

Inside a code block:


set test=Goodbye!
if 1==1 (
    set test=Hello!
    echo %test%
)

The result is:


Goodbye!

It may seem like an unexpected result but you must consider that %test% was expanded to what it was set to before the code block was executed because it is considered one line.

Windows 2000 and up has a way to combat this problem, delayed expansion. To use delayed expansion add this to the top of the script:


setlocal enabledelayedexpansion

With that in place any variables that need to be set to and updated within a code block should be marked with ! exclamation marks instead of % percentage signs. In the script above if delayed expansion was enabled "echo !test!" would have yielded "Hello!".

Unfortunately delayed expansion has it's problems:

1. Recursion, if a script calls itself a way to avoid executing "setlocal enabledelayedexpansion" on every recursion is important because setlocal can only nest a finite number of times. If you call setlocal too many times you may get an error along the lines of "maximum setlocal recursion level reached".

2. Where is my exclamation mark^^!, with delayed expansion enabled exclamation marks must be prefixed with two ^^ carets if they don't mark a variable. This can be a real problem when the exclamation marks are contained in a file a for /f loop is iterating over because they disappear right out of the for loop variable %%! %%! %%!. Variables that already contain ! exclamation marks before delayed expansion is enabled are unaffected, as are variables obtained using "set /p".

3. Environment variable vs local environment variable, unfortunately there is, to the best of my knowledge, no way to use delayed expansion with out using setlocal. If a script uses setlocal all variables set within it are reset to their original states on exit, often without even calling endlocal. This can be a mixed blessing, sometimes you don't need the variable returned, other times it can be very useful....

If there are just a few variables you want returned it is possible to use the default expansion to your advantage; you can return as many as you want in this fashion:


endlocal & set variable=%variable%


or


(
    endlocal
    set variable=%variable%
)




How do I nest variables?

Spoiler: This may take a while, the rest of this how to it nesting related.


There are actually a couple of ways to nest variables, some even work right back to DOS, others make use of delayed expansion. It's even possible to go a couple of levels deep.

All of these examples are for batch scripts as opposed to the interactive command line, nesting still works on the command line but the number of % percentage signs is different.

The call method:

Firstly you need to know that % single percentage signs expand variables and %% double percentage signs expand to a single percentage(it's to do with the way input is parsed). Call can work with some commands to expand/update variables multiple times on a single line, just be aware that it only works with some commands. Set and echo are two commands calling will work for, while others like if won't work. If(he he) your command won't take this abuse you can set an intermediate variable, just use set the way echo is used below.

It starts simple then turns into a headache quickly as each level reduces two %% percentage signs to one and the next level does the same.

There are probably better ways to work this out, but here is one way:

The bottom nested variable is the one you want to display/use it requires one % percentage sign on either side, double it and add one for the next level(three on each side now), the next level requires you to double this and add one(now it's seven each side), and so on. Each time you do this you must also add an extra call to the front of the command.

Here are a couple of examples:


set level1=Hello!
set level2=level1
call echo %%%level2%%%

set level1=Hello!
set level2=level1
set level3=level2
call call echo %%%%%%%level3%%%%%%%

set level1=Hello!
set level2=level1
set level3=level2
set level4=level3
call call call echo %%%%%%%%%%%%%%%level4%%%%%%%%%%%%%%%

Following this method it is possible to go through many levels (any sane person would probably find another way) so naturally I kept going, the last level that worked was level11!(on xp sp3) The line length was 4161 characters, level12 yielded "Line input too long" - Geeze I think I'm going to write a compliant or something ;)

That's great you say, but I have a variable that when combined with another will make one super variable (which I shall rule the world with! BU WA HA HA HA!) well I got you supervillains covered too.

The call method works with these too; the most common use is numbered variables so that's the example I will use here.


set num=1
set var=test
set test1=Hello!
call echo %%%var%%num%%%

I only used one call here because "var" and "num" both expand the first time and %test1% expands the second time. If you want to further nest/expand the above principles still apply, but you must remember that %test1% counts as a level, and that it still needs the % percentage signs to expand test1 from %var% and %num%.


set num=1
set var=test
set test1=level1
set level1=Hello!!
call call echo %%%%%%%var%%num%%%%%%%


Although the above can happen it's more likely that the base variable is constant.


set num=1
set test1=Hello!!
call echo %%test%num%%%

It's even more common that you have x variables that a numbered, for this I suggest the for /l loop:


set test0=Greetings good friend!
set test1=Hello My friend!
set test2=Um..........
set test3=How about that local sports team?
set test4=Um.......I don't like sports.
set test5=........Oh...........
set test6=How about this weather?
set test7=Yeah..........
set test8=um......goodbye.....
set test9=...oh..uh..yeah...goodbye.....
set num=9
for /l %%a in (0,1,%num%) do call echo %%test%%a%%

This brings me to an important point, alternatives to delayed expansion; if you don't want to/can't use it delayed expansion call can help. Just treat a variable like it's nested but don't add the extra % percentage sign because you will expand the contents as a variable instead of displaying/using the contents.


set test=Goodbye already!
(
    set test=Hello!!
    call echo %%test%%
    echo %test%
)

Your command, unlike echo or set, won't take it you say? Using set is just as useless because they are set in the same code block? for /f can help, just do your command(in place of echo) with %%~a instead of "%test%". Some special characters will have problems, but only if "test" contains any double quotes.


set test=Well well.....
(
    set test=Hello!
    for /f "delims=" %%a in ('call echo "%%test%%"') do echo %%~a
    echo %test%
)


Enter delayed expansion:

Delayed expansion makes nesting variables much easier for a single level. Simply use ! exclamation marks on the outer variable and either standard variable(s) or text and standard variable(s) within. This should cover what I was rambling on about before:


setlocal enabledelayedexpansion
set level1=Hello!
set level2=level1
set num=2
echo !%level2%!
echo !level%num%!
for /l %%a in (1,1,2) do echo !level%%a!

Now what happens if you want to combine two variables both set in the same code block?


setlocal enabledelayedexpansion
(
    set part1=Hello^^!
    set num=1
    for /f "delims=" %%a in ("!num!") do echo !part%%a!
)