PORTAL system (McLuhan) for pawno ru

/*
Разработчик: McLuhan

Система создание порталов (вход / выход):
Чтобы создать портал(вход / выход), сначала нужно установить входную точку, командой /makepickupen
Потом нужно установить выходную точку, командой /makepickupex
Потом нужно задать параметры порталу(только после этого он создастся), делается это командой /makepickupend
/makepickupend [0 - ничего, 1 - вход, 2 - выход] [3D текст] [виртуальный мир выхода]
1 аргумент: устанавливаем, вход это или выход, или же ничего не писать (т. к. над 3D текстом пишется, вход это или выход)
2 аргумент: вводим название портала, то есть куда телепортирует портал (нужно вместо пробелов использовать "_", потом система изменяет их на пробелы)
3 аргумент: вводим ID виртуального мира, который установится при телепортировании.

portal - http://imgdepo.ru/show/4490045

Примечание: Когда пишем 3D текст нужно вместо пробелов использовать "_"
*/

#include <a_samp>
main();
#include <sscanf2>
#include <YSI\y_commands>
#include <a_mysql>
#include <streamer>
#include <foreach>

#define m_host " " // заполнить
#define m_user " " // заполнить
#define m_base " " // заполнить
#define m_pass " " // заполнить
#define MTN    (-1)
#define table_pickups   "pickups"
#define SPVI        SetPVarInt
#define GPVI        GetPVarInt
#define SPVF        SetPVarFloat
#define GPVF        GetPVarFloat
#define SCM         SendClientMessage
#define cWhite      0xffffffaa
#define cYellow     0xffff00aa
#define ccWhite     "{ffffff}"
#define MSGUSE      "{75a3ff}[Использование] {ffffff}"
#define MSGPERF     "{01dfa5}[Выполнено] {ffffff}"
#define MSGHELP     "{ffcc33}[Подсказка] {ffffff}"
#define MSGERROR    "{cc0000}[Ошибка] {ffffff}"
#define MAX_PICKUP  100 // максимальное количество порталов

enum pickupsEnum { Float: pickupPos[3], Float: tpPos[4], pickupVw, tpVw, pickupInt, tpInt, pickup, Text3D: text3D, pType };
new
    allpickups = 0,
    pickupText[MAX_PICKUP][50],
    pInfo[MAX_PICKUP][pickupsEnum], // 100
    cmID,
    cmdstr[144],
    PLN[MAX_PLAYERS][MAX_PLAYER_NAME];

public OnFilterScriptInit()
{
    mysql_log(LOG_ERROR | LOG_WARNING | LOG_DEBUG, LOG_TYPE_TEXT);
    cmID = mysql_connect(m_host, m_user, m_base, m_pass);
    mysql_function_query(cmID, "SET NAMES cp1251;", false, "", "");
    mysql_function_query(cmID, "SET SESSION character_set_server = cp1251;", false, "", "");
    new query[31+1];
    format(query, sizeof query, "SELECT * FROM `"table_pickups"`"), mysql_function_query(cmID, query, true, "mysqlquery_loadPickups", "");
    return 1;
}

public OnFilterScriptExit()
{
    mysql_close(cmID);
    return 1;
}

public OnPlayerConnect(playerid)
{
    GetPlayerName(playerid, PLN[playerid], MAX_PLAYER_NAME);
    return 1;
}

public OnPlayerDisconnect(playerid, reason)
{
    return 1;
}

public OnPlayerPickUpDynamicPickup(playerid, pickupid)
{
    for(new i = 0; i < allpickups; i++)
    {
        if(pickupid == pInfo[i][pickup])
        {
            SetPlayerPos(playerid, pInfo[i][tpPos][0], pInfo[i][tpPos][1], pInfo[i][tpPos][2]), SetPlayerFacingAngle(playerid, pInfo[i][tpPos][3]);
            SetPlayerVirtualWorld(playerid, pInfo[i][tpVw]), SetPlayerInterior(playerid, pInfo[i][tpInt]), SetCameraBehindPlayer(playerid);
        }
    }
    return 1;
}

public OnPlayerCommandText(playerid, cmdtext[])
{
    return 1;
}

public OnDialogResponse(playerid, dialogid, response, listitem, inputtext[])
{
    return 1;
}

forward mysqlquery_loadPickups();
public mysqlquery_loadPickups()
{
    new rowsfield[2];
    cache_get_data(rowsfield[0], rowsfield[1]);
    if(rowsfield[0])
    {
        for(new i = 0; i < rowsfield[0]; i++)
        {
            new _pickupPos[100], _tpPos[111], _text[1+34+50+37];
            cache_get_field_content(i, "pickupPos", _pickupPos, cmID);
            cache_get_field_content(i, "tpPos", _tpPos, cmID);
            sscanf(_pickupPos, "p<,>fff", pInfo[allpickups][pickupPos][0], pInfo[allpickups][pickupPos][1], pInfo[allpickups][pickupPos][2]);
            sscanf(_tpPos, "p<,>ffff", pInfo[allpickups][tpPos][0], pInfo[allpickups][tpPos][1], pInfo[allpickups][tpPos][2], pInfo[allpickups][tpPos][3]);
            pInfo[allpickups][pickupVw] = cache_get_field_content_int(i, "pickupVw", cmID);
            pInfo[allpickups][tpVw] = cache_get_field_content_int(i, "tpVw", cmID);
            pInfo[allpickups][pickupInt] = cache_get_field_content_int(i, "pickupInt", cmID);
            pInfo[allpickups][tpInt] = cache_get_field_content_int(i, "tpInt", cmID);
            pInfo[allpickups][pType] = cache_get_field_content_int(i, "type", cmID);
            new _type[37+1];
            if(pInfo[allpickups][pType] == 1) _type = "{0b615e}>> {ceecf5}Вход {0b615e}<<\n";
            else if(pInfo[allpickups][pType] == 2) _type = "{0b615e}>> {ceecf5}Выход {0b615e}<<\n";
            else _type = " ";
            cache_get_field_content(i, "text", pickupText[allpickups], cmID), format(_text, sizeof _text, "%s"ccWhite"[ {0489b1}%s "ccWhite"]", _type, pickupText[allpickups]);
            pInfo[allpickups][pickup] = CreateDynamicPickup(19134, 23, pInfo[allpickups][pickupPos][0], pInfo[allpickups][pickupPos][1], pInfo[allpickups][pickupPos][2], pInfo[allpickups][pickupVw], pInfo[allpickups][pickupInt], -1, 40.0);
            pInfo[allpickups][text3D] = CreateDynamic3DTextLabel(_text, cWhite, pInfo[allpickups][pickupPos][0], pInfo[allpickups][pickupPos][1], pInfo[allpickups][pickupPos][2]+0.1, 15.0, INVALID_PLAYER_ID, INVALID_VEHICLE_ID, 0, pInfo[allpickups][pickupVw], pInfo[allpickups][pickupInt], -1, 20.0);
            allpickups++;
        }
    }
    printf("~ Load Pickups [ %i ]: загрузка завершена успешно.", allpickups);
    return 1;
}

stock SCMADM(adml, string[])
{
    new outstring[144];
    foreach(new i : Player) if(GPVI(i, "pld_admin") >= adml) format(outstring, sizeof outstring, "[ADMMSG] "ccWhite"%s", string), SCM(i, cYellow, outstring);
    // GPVI(i, "pld_admin") - заменить на свой ПВар / массив адм. уровня игрока
    return 1;
}

YCMD:makepickupen(playerid, params[], help)
{
    // if: администратор ли вы
    new Float: pos[3];
    GetPlayerPos(playerid, pos[0], pos[1], pos[2]);
    SPVI(playerid, "makepickup_pickupInt", GetPlayerInterior(playerid)), SPVI(playerid, "makepickup_pickupVw", GetPlayerVirtualWorld(playerid));
    SPVI(playerid, "makepickup_step", 1), SPVF(playerid, "makepickupen_x", pos[0]), SPVF(playerid, "makepickupen_y", pos[1]), SPVF(playerid, "makepickupen_z", pos[2]);
    SCM(playerid, -1, ""MSGPERF"Вы указали координату расположения пикапа.");
    SCM(playerid, -1, ""MSGHELP"Чтобы указать точку конечного телепортирования, введите /makepickupex.");
    return 1;
}

YCMD:makepickupex(playerid, params[], help)
{
    // if: администратор ли вы
    if(GPVI(playerid, "makepickup_step") < 1) return SCM(playerid, -1, ""MSGERROR"Чтобы указать конечную точку телепортирования, нужно пройти первый этап создания.");
    new Float: pos[4];
    GetPlayerPos(playerid, pos[0], pos[1], pos[2]), GetPlayerFacingAngle(playerid, pos[3]);
    SPVI(playerid, "makepickup_tpInt", GetPlayerInterior(playerid));
    SPVI(playerid, "makepickup_step", 2), SPVF(playerid, "makepickupex_x", pos[0]), SPVF(playerid, "makepickupex_y", pos[1]), SPVF(playerid, "makepickupex_z", pos[2]), SPVF(playerid, "makepickupex_a", pos[3]);
    SCM(playerid, -1, ""MSGPERF"Вы указали точку конечного телепортирования.");
    SCM(playerid, -1, ""MSGHELP"Чтобы закончить создание пикапа, введите /makepickupend.");
    return 1;
}

YCMD:makepickupend(playerid, params[], help)
{
    // if: администратор ли вы
    if(GPVI(playerid, "makepickup_step") < 2) return SCM(playerid, -1, ""MSGERROR"Чтобы закончить создание пикапа, нужно пройти второй этап создания.");
    new _3dtext[50];
    if(sscanf(params, "is[50]i", params[0], _3dtext, params[2])) return SCM(playerid, -1, ""MSGUSE"/makepickupend [0 - ничего, 1 - вход, 2 - выход] [3D текст] [виртуальный мир выхода]");
    for(new i; i != strlen(_3dtext); i++) if(_3dtext[i] == '_') _3dtext[i] = ' ';
    pInfo[allpickups][pickupPos][0] = GetPVarFloat(playerid, "makepickupen_x"), pInfo[allpickups][pickupPos][1] = GetPVarFloat(playerid, "makepickupen_y"), pInfo[allpickups][pickupPos][2] = GetPVarFloat(playerid, "makepickupen_z");
    pInfo[allpickups][tpPos][0] = GetPVarFloat(playerid, "makepickupex_x"), pInfo[allpickups][tpPos][1] = GetPVarFloat(playerid, "makepickupex_y"), pInfo[allpickups][tpPos][2] = GetPVarFloat(playerid, "makepickupex_z"), pInfo[allpickups][tpPos][3] = GetPVarFloat(playerid, "makepickupex_a");
    pInfo[allpickups][pickupVw] = GPVI(playerid, "makepickup_pickupVw"), pInfo[allpickups][tpVw] = params[2];
    pInfo[allpickups][pickupInt] = GPVI(playerid, "makepickup_pickupInt"), pInfo[allpickups][tpInt] = GPVI(playerid, "makepickup_tpInt");
    pInfo[allpickups][pType] = params[0];
    new _text[1+34+50+37];
    new _type[37+1];
    if(pInfo[allpickups][pType] == 1) _type = "{0b615e}>> {ceecf5}Вход {0b615e}<<\n";
    else if(pInfo[allpickups][pType] == 2) _type = "{0b615e}>> {ceecf5}Выход {0b615e}<<\n";
    else _type = " ";
    format(_text, sizeof _text, "%s"ccWhite"[ {0489b1}%s "ccWhite"]", _type, _3dtext);
    pickupText[allpickups] = _3dtext;
    pInfo[allpickups][pickup] = CreateDynamicPickup(19134, 23, pInfo[allpickups][pickupPos][0], pInfo[allpickups][pickupPos][1], pInfo[allpickups][pickupPos][2], pInfo[allpickups][pickupVw], pInfo[allpickups][pickupInt], -1, 40.0);
    pInfo[allpickups][text3D] = CreateDynamic3DTextLabel(_text, cWhite, pInfo[allpickups][pickupPos][0], pInfo[allpickups][pickupPos][1], pInfo[allpickups][pickupPos][2]+1, 15.0, INVALID_PLAYER_ID, INVALID_VEHICLE_ID, 0, pInfo[allpickups][pickupVw], pInfo[allpickups][pickupInt], -1, 20.0);
    format(cmdstr, sizeof cmdstr, "Администратор (%i)%s создал пикап(вход OR выход). (\"%s\")", playerid, PLN[playerid], _3dtext), SCMADM(1, cmdstr);
    new query[1+159+100+100+11+11+11+11+50+15];
    format(query, sizeof query, "INSERT INTO `"table_pickups"` (`pickupPos`, `tpPos`, `pickupVw`, `tpVw`, `pickupInt`, `tpInt`, `text`, `type`) VALUES ('%f,%f,%f', '%f,%f,%f,%f', '%i', '%i', '%i', '%i', '%s', '%i')"
    , pInfo[allpickups][pickupPos][0], pInfo[allpickups][pickupPos][1], pInfo[allpickups][pickupPos][2], pInfo[allpickups][tpPos][0], pInfo[allpickups][tpPos][1], pInfo[allpickups][tpPos][2], pInfo[allpickups][tpPos][3], pInfo[allpickups][pickupVw], pInfo[allpickups][tpVw], pInfo[allpickups][pickupInt], pInfo[allpickups][tpInt], pickupText[allpickups], pInfo[allpickups][pType]);
    mysql_function_query(cmID, query, false, "", "");
    allpickups++;
    SPVI(playerid, "makepickup_step", 0);
    return 1;
}

YCMD:gotopickup(playerid, params[], help)
{
    // if: администратор ли вы
    if(sscanf(params, "i", params[0])) return format(cmdstr, sizeof cmdstr, ""MSGUSE"/gotopickup [номер пикапа] (0-%i)", allpickups-1), SCM(playerid, -1, cmdstr);
    if(params[0] < 0 || params[0] > allpickups-1) return format(cmdstr, sizeof cmdstr, ""MSGERROR"Номер пикапа должен быть в пределах 0-%i.", allpickups-1), SCM(playerid, -1, cmdstr);
    SetPlayerPos(playerid, pInfo[params[0]][pickupPos][0], pInfo[params[0]][pickupPos][1], pInfo[params[0]][pickupPos][2]);
    SetPlayerInterior(playerid, pInfo[params[0]][pickupInt]), SetPlayerVirtualWorld(playerid, pInfo[params[0]][pickupVw]);
    format(cmdstr, sizeof cmdstr, ""MSGPERF"Вы телепортированы к пикапу (№%i), \"%s\".", params[0], pickupText[params[0]]), SCM(playerid, -1, cmdstr);
    return 1;
}