//improved below by srbs

//you can add in any character below at the end, and their values will increase from 9's value of 35
//remember to update the space's value in-map and a few lines down
//also note: for the ^, you need ^^ and for a ", you need ^"
chars = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789" //`~!@#$%^^&*()-_=+;:'^",<.>/?
charret = [
    if (=s $arg1 " ") [
        result 40 //change this value for the space.
    ] [
        i = (strstr $chars $arg1)
        result (? (> $i 25) (- $i 26) $i)
    ]
]

//improved below by RaZgRiZ, fixes by srbs
getletter = [gridpower 3; cancelsel; entfind base $arg1; gotosel; delent; sleep 10 [editdrag; copy; newent base @arg1; cancelsel]]
printletter = [gridpower 3; entfind sound $arg1; gotosel; delent; sleep 10 [editdrag; paste; newent sound @arg1; cancelsel]]
printword = [
    if (> (strlen $arg1) 32) [echo "Maximum length of 32 characters exceeded"] [
        loop i (strlen $arg1) [
            sleep (* 100 $i) [
                getletter (charret (substr [@@@arg1] @i 1))
                sleep 20 [printletter @@i]
            ]
        ]
    ]
]