Anti-Moneyhack (c) by Kaliber

/* Sa-Mp Include Anti-Money-Hack
 *
 * (c) by Kaliber, 2014
 *
 */
#if !defined _samp_included
    #include <a_samp>
#endif
#if defined _a_hack_included
    #endinput
#endif
#define _a_hack_included

forward A_C_OnPlayerConnect(playerid);
static geld[MAX_PLAYERS];
native __GivePlayerMoney(playerid, money) = GivePlayerMoney;
@MoneyTimer(playerid);

public OnPlayerConnect(playerid) {
    geld[playerid]=0;
    SetTimerEx("@MoneyTimer",999,0,"i",playerid);
    return CallLocalFunction("A_C_OnPlayerConnect","i",playerid);
}
#if defined _ALS_OnPlayerConnect
    #undef OnPlayerConnect
#else
    #define _ALS_OnPlayerConnect
#endif
#define OnPlayerConnect A_C_OnPlayerConnect

stock _GivePlayerMoney(playerid, money) return geld[playerid] += money,__GivePlayerMoney(playerid, money);
#if defined _ALS_GivePlayerMoney
    #undef GivePlayerMoney
#else
    #define _ALS_GivePlayerMoney
#endif
#define GivePlayerMoney _GivePlayerMoney

@MoneyTimer(playerid) {
    if(!IsPlayerConnected(playerid)) return 0;
    if(GetPlayerMoney(playerid) > geld[playerid]) return Ban(playerid); //Hier hat er Geld gecheatet!!!
    /*
        Um einen Reset des Geldes zu machen könnt ihr auch einfach folgendes schreiben:
        ResetPlayerMoney(playerid);
        GivePlayerMoney(playerid, geld[playerid]);
    */
    return SetTimerEx("@MoneyTimer",999,0,"i",playerid);
}