screen sort system

~F8::
; Записываем и разделяем чат в переменную в момент создания скриншота
FileRead, chatlog, %A_MyDocuments%\GTA San Andreas User Files\SAMP\chatlog.txt
chat := StrSplit(chatlog, "`n")
sleep 3000
; Узнаем размер чата из sa-mp.cfg
FileRead, config, %A_MyDocuments%\GTA San Andreas User Files\SAMP\sa-mp.cfg
cfg := StrSplit(config, "`n")
for i, el in cfg
{
    if RegExMatch(el, "pagesize=(.*)", s)
    pagesize := s1
}
pagesize += 0 ; string to number

switch := false

; Выясняем, какой из скриншотов был сделан последним через дату его создания
loop, %A_MyDocuments%\GTA San Andreas User Files\SAMP\screens\*.png
{
    FileGetTime, time, %A_LoopFileFullPath%, C
    if (time > maxtime)
    {
        maxtime := time
        screen := A_LoopFileFullPath
    }
}

Loop %pagesize%
{
    string := chat[chat.MaxIndex() - pagesize - 1 + A_Index]
    ; Регулярное выражение
    if RegExMatch(string, "^\[\d{2}:\d{2}:\d{2}\] \* Вы арестовали .*\.")
    {
        saveScreen(screen, "arrests")
        switch := true
    }
    ; Регулярное выражение
    if RegExMatch(string, "^\[\d{2}:\d{2}:\d{2}\] \* Вы изъяли .* у .*")
    {
        saveScreen(screen, "licenses")
        switch := true
    }
    ; Регулярное выражение
    if RegExMatch(string, "^\[\d{2}:\d{2}:\d{2}\] \[R\] (.*)\: Произвел задержание. Напарник: Lewis_Flow")
    {
        saveScreen(screen, "newbee")
        switch := true
    }
    ; Регулярное выражение
    if RegExMatch(string, "^\[\d{2}:\d{2}:\d{2}\] \[DRUGS\] Сотрудник FBI Lewis_Flow сдал\(а\) конфискованные наркотики \(\d+ гр\)\.")
    {
        saveScreen(screen, "drugs")
        switch := true
    }
}
if (switch)
{
    FileDelete, %screen%
}
return

/*
Функция сохранения скриншота
Параметры:
screen - полный путь до скриншота, который будет перемещаться
pattern - папка, в которую будет сохранен скриншот
*/
saveScreen(screen, pattern) {
    IfNotExist, %A_MyDocuments%\GTA San Andreas User Files\SAMP\screens\%pattern%\
    {
        FileCreateDir, %A_MyDocuments%\GTA San Andreas User Files\SAMP\screens\%pattern%
    }
    count := 1
    loop, %A_MyDocuments%\GTA San Andreas User Files\SAMP\screens\%pattern%\*.png
    count++
    FileCopy, %screen%, %A_MyDocuments%\GTA San Andreas User Files\SAMP\screens\%pattern%\%count%.png
    /*
    Если вы пользуетесь SAMP API, можете добавить отпись в чате о сохранении, выглядит это примерно так:
    addchatmessageEx(0xFFFFFF00, "[SORT SYSTEM] screen has saved as {FFFFFF}" pattern "\" count ".png")
    */
}