CBLLight 83 v1.0 Source

{Xmin,Xmax,Ymin,Ymax}->\LCLZOOM
Lbl CA
1->I
FnOff
PlotsOff
AxesOff
60\^-1/94->D
1->S
0->R
0->Xmin
94->Xmax
Lbl RS
0->Ymin
1->Ymax
ClrHome
ClrDraw
Text(0,0,"INTERVAL:"
Text(0,35,94D/S
Text(7,0,"MULTI:"
Text(7,23,S
Text(14,0,"REALTIME:"
Text(14,35,sub("FALSETRUE ",5R+1,5
Lbl D1
DispGraph
Pause
Lbl LO
Menu("SETUP MENU - 1",
     "START",C,
     "VIEW CONFIG",D1,
     "SET INTERVAL",I,
     "SET REALTIME",R,
     "MULTI: "+sub("12345",S,1)+"X",S,
     "RESET CONFIG",CA,
     "MORE...",MO
Lbl MO
Menu("SETUP MENU - 2",
     "BACK",LO,
     "AST",AS,
     "EXIT",X
Lbl R
not(R)->R
Goto RS
Lbl I
ClrHome
Menu("INPUT:",
     "SAMPLE PERIOD",II,
     "TIME/SAMPLE",IT,
     "GO BACK",IB
Lbl IB
ClrHome
If I
Goto RS
Goto H
Lbl II
D->E
ClrHome
Disp "INTERVAL:"
Input "",D
DS/94->D
If D\!=E
Goto RS
Goto IB
Lbl IT
D->E
ClrHome
INPUT "TIME per SAMPLE:",D
If D\!=E
Goto RS
Goto IB
Lbl S
ClrHome
Disp "DATA RESOLUTION:","1: 94","2: 47","3: 31","4: 23","5: 18"
For(X,2,6
Output(X,7,"SAMPLES"
End
S->E
Input "\n=",S
iPart(S->S
If S>5
5->S
If S<1
1->S
ClrHome
Menu("PRESERVE:",
     "INTERVAL",SI,
     "TIME/SAMPLE",RS
Lbl SI
DS/E->D
Goto RS
Lbl C
ClrDraw
Text(0,0,"CONFIGURING CBL/CBL2..."
0->I
Send({1,0}
Send({1,1,12}
If R
Goto RT
iPart(94/S)->T
Send({3,D,T,0,0,0,0,0,0,0}
DelVar \L1
Get(\L1
{0,-1}->\L2
Send({7}
Get(\L2
If \L2(2)\!=0
Goto EC
Lbl H2
ClrDraw
If S=1
Then
For X,1,94
Line(X,0,X,\L1(X
End
Else
1->X
dim(\L1->Z
For Y,1,93
If Z\>=iPart(X
Line(Y,0,Y,\L1(iPart(X
X+S\^-1->X
End
End
Lbl V
DispGraph
Pause
Lbl H
Menu("DATA MENU - 1",
     "RESTART",RE,
     "VIEW DATA",V,
     "SET INTERVAL",I,
     "SET REALTIME",R,
     "MULTI: "+sub("12345",S,1)+"X",S,
     "EXIT",X,
     "MORE...",RM
Lbl RM
Menu("DATA MENU - 2",
     "RESET",CA,
     "AUTO-FIT"+sub("   N/A",3R+1,3),AR,
     "MANUAL WINDOW",RA,
     "BACK",H
Lbl RE
If R
Goto H
Send({3,D,iPart(94/S),0,0,0,0,0,0,0}
Get(\L1
0->Ymin
1->Ymax
Goto H2
Lbl RA
ClrHome
Input "Ymin: ",Ymin
Input "Ymax: ",Ymax
If Ymax\<=Ymin
Ymin+.1->Ymax
ClrHome
If R=0
Goto H2
Goto C
Lbl AR
If R or min(\L1)=max(\L1
Goto H
min(\L1->Ymin
max(\L1->Ymax
Goto H2
Lbl RT
ClrDraw
Send({3,.1,-1,0,0,0,0,0,0}
1->X
Lbl R1
Get(\L1
Line(X,0,X,\L1(1
Line(X+1,Ymin,X+1,Ymax,0
getKey->K
If K=105
Goto R3
If K
Goto R2
IS>(X,93
Goto R1
1->X
Goto R1
Lbl R2
Send({1,0}
Goto H
Lbl X
ClrDraw
\LCLZOOM(1->Xmin
\LCLZOOM(2->Xmax
\LCLZOOM(3->Ymin
\LCLZOOM(4->Ymax
AxesOn
ClrHome
Output(8,1,"BY CVSOFT v1.0"
Return
Lbl AS
ClrHome
Disp "SAMPLING TOOL","INTERVAL:"
Input "",D
Input "SAMPLES: ",S
If S>999
999->S
If S<1
1->S
iPart(S->S
Send({1,0}
Send({1,1,12}
Send({3,D/S,S,0,0,0,0,0,0}
Get(\L1
Goto X
Lbl EC
ClrHome
Disp "ERROR!","CHECK INPUT AND","CBL."
Output(2,6,\L2(2
Pause
Goto RS
Lbl R3
0->R
Goto C