pause_ALS.inc - Dayrion

/*
    -------------------------------------------------------------------------------------
    * Include made by * aka Dayrion.

    public OnPlayerUnPause(playerid, time);
        - When a player return in game after being AFK. Return the time which he were AFK in seconds.
    public OnPlayerPause(playerid);
        - When a player back to the desktop or press ESC.
    bool:IsPlayerPaused(playerid);
        - Return if, or not, a player is in pause.
    -------------------------------------------------------------------------------------
*/

// ===================================================================================================================================================

#tryinclude <a_samp>
#tryinclude <YSI\y_hooks>

#if defined _included_ji_afkdetect
    #endinput
#endif

#if !defined MAX_PLAYERS
    #error "You must have the lastest version of SAMP (0.3.7) or include it (a_samp) before this one."
#endif

#define _included_ji_afkdetect

#if !defined MAX_TIME_ALLOWED
    #define MAX_TIME_ALLOWED 3 // sec
#endif

#if !defined INTERVAL_AFK_DETECT
    #define INTERVAL_AFK_DETECT 800 // ms
#endif

// ===================================================================================================================================================

forward OnPlayerUnPause(playerid, time);
forward OnPlayerPause(playerid);
//bool:IsPlayerPaused(playerid);

// ===================================================================================================================================================

static
    PlayerAFK[MAX_PLAYERS],
    AFKDetect[MAX_PLAYERS],
    v_Ji_TAFK;

// ===================================================================================================================================================

#if defined FILTERSCRIPT

    public OnFilterScriptInit()
    {
        v_Ji_TAFK = SetTimer("Ji_TAFK", INTERVAL_AFK_DETECT, true);
        #if defined Ji_OnFilterScriptInit
            return Ji_OnFilterScriptInit();
        #else
            return 1;
        #endif
    }

    #if defined _ALS_OnFilterScriptInit
        #undef OnFilterScriptInit
    #else
        #define _ALS_OnFilterScriptInit
    #endif
    #define OnFilterScriptInit Ji_OnFilterScriptInit

    #if defined Ji_OnFilterScriptInit
        forward Ji_OnFilterScriptInit();
    #endif


    public OnFilterScriptExit()
    {
        KillTimer(v_Ji_TAFK);
        #if defined Ji_OnFilterScriptExit
            return Ji_OnFilterScriptExit();
        #else
            return 1;
        #endif
    }

    #if defined _ALS_OnFilterScriptExit
        #undef OnFilterScriptExit
    #else
        #define _ALS_OnFilterScriptExit
    #endif
    #define OnFilterScriptExit Ji_OnFilterScriptExit

    #if defined Ji_OnFilterScriptExit
        forward Ji_OnFilterScriptExit();
    #endif

#else

    public OnGameModeInit()
    {
        v_Ji_TAFK = SetTimer("Ji_TAFK", INTERVAL_AFK_DETECT, true);
        #if defined Ji_OnGameModeInit
            return Ji_OnGameModeInit();
        #else
            return 1;
        #endif
    }

    #if defined _ALS_OnGameModeInit
        #undef OnGameModeInit
    #else
        #define _ALS_OnGameModeInit
    #endif
    #define OnGameModeInit Ji_OnGameModeInit

    #if defined Ji_OnGameModeInit
        forward Ji_OnGameModeInit();
    #endif

    public OnGameModeExit()
    {
        KillTimer(v_Ji_TAFK);
        #if defined Ji_OnGameModeExit
            return Ji_OnGameModeExit();
        #else
            return 1;
        #endif
    }

    #if defined _ALS_OnGameModeExit
        #undef OnGameModeExit
    #else
        #define _ALS_OnGameModeExit
    #endif
    #define OnGameModeExit Ji_OnGameModeExit

    #if defined Ji_OnPlayerUpdate
        forward Ji_OnPlayerUpdate(playerid);
    #endif

#endif

// ===================================================================================================================================================

public OnPlayerUpdate(playerid)
{
    AFKDetect[playerid] = gettime();

    #if defined Ji_OnPlayerUpdate
        return Ji_OnPlayerUpdate(playerid);
    #else
        return 1;
    #endif
}

#if defined _ALS_OnPlayerUpdate
    #undef OnPlayerUpdate
#else
    #define _ALS_OnPlayerUpdate
#endif

#define OnPlayerUpdate Ji_OnPlayerUpdate

#if defined Ji_OnPlayerUpdate
    forward Ji_OnPlayerUpdate(playerid);
#endif

// ===================================================================================================================================================

stock
    bool:IsPlayerPaused(playerid)
        return PlayerAFK[playerid] > 0 ? true : false;

forward Ji_TAFK();
public Ji_TAFK()
{
    for(new j = GetPlayerPoolSize(); j > 0; j--)
    {
        if(!IsPlayerConnected(j))
            continue;

        if(gettime() - AFKDetect[j] > MAX_TIME_ALLOWED && PlayerAFK[j] == 0)
        {
            PlayerAFK[j] = AFKDetect[j];
            CallRemoteFunction("OnPlayerPause", "i", j);
        }
        else if(gettime() - AFKDetect[j] < MAX_TIME_ALLOWED && PlayerAFK[j] > 0)
        {
            CallRemoteFunction("OnPlayerUnPause", "ii", j, (gettime() - PlayerAFK[j]) + MAX_TIME_ALLOWED);
            PlayerAFK[j] = 0;
        }
    }
    return 1;
}