Challenge 213 Cellular Automata

+++++++++++++++++++++++++>>>>>>
//read all input
,[>,] >+
//return pointer to (3)
<<[<] <<<<<
// loop for 25
[-
 >>>>>>
 //sliding loop to end of input
 [
  //check if first value is blank if so treat it as 0
  <<<[-]>[-]+>
  [
  	//if true code / not used
  <-]<
  [>
  	//if false code
  	//if true code / set to 0
	 ++++++++++++++++++++++++++++++++++++++++++++++++
  <-<]
  >>
  //check if third value is blank if so treat use first value
  <<[-]+>[-]>>>
  [
    <<
    <<[-]>>
    //Xor compare 3rd value to first
  	  [<+>-]+
  	  >>[<<<-<+>>>>-]
  	  <<<<[>>>>+<<<<-]
  	  >[>-<[-]]>
    //set value of next row based on if first value is true or false
  	<+>
  	[
  	  //if true code

  		<<<
  		++++++++++++++++++++++++++++++++++++++++++++++++
  		>>>
	  <-]<
    [>
  	  //if false code
   	    <<<
  	    +++++++++++++++++++++++++++++++++++++++++++++++++
  	    >>>
  	<-<]>>>>
   [<<<+>>>-]
  ]
   <<<[>>>+<<<-]
   // copy first value to next row
   <[>>[-<<<+>>>]<<
   -]>>>
  //move and repeat
 >]
 <[-]>

 //return carriage
 >>>>++++++++++.[-]<<<<
 //sliding loop to reposition input values back to original location
 <<<<<[[->>>>+<<<<]<]
 //read new values
 >>>>>[.>] <[<]<<<<<
]