wobble

int numElem = 30;
myArc[] myArcs = new myArc[numElem];

color bg = #000000;
color[] palette = {
  #322536, #8D2B38, #E53448, #FC6C63, #EFD79B
};
float org_x, org_y, diam;

void setup() {
  size(500, 500);
  background(bg);
  noFill();

  strokeCap(SQUARE);

  org_x = width/2;
  org_y = height/2;
  diam = width*.6;
  float end = 0;
  float start = 0;
  float theta = 0;

  for (int i=0; i<numElem; i++) {
    color s = palette[i% palette.length ];
    start = end;
    end = start + TAU/numElem;
    myArcs[i]= new myArc(s, start, end, theta);
    theta += TAU/numElem;
  }
}


void draw() {
  background(bg);
  for (int i=0; i<numElem; i++) {
    myArcs[i].run();
  }

  if (frameCount % 4 == 0 & frameCount<241) saveFrame("image-####.gif");

}

class myArc {
  float start, end, theta, sw;
  color s;

  myArc(color _s, float _start, float _end, float _theta) {
    s = _s;
    start = _start;
    end = _end + radians(.3);
    theta = _theta;
  }

  void run() {
    move();
    display();
  }

  void move() {
    sw = map(sin(theta*3), -1, 1, 20, 100);
    theta += 0.0523/2;
  }

  void display() {
    stroke(s);
    strokeWeight(sw);
    arc(org_x, org_y, diam, diam, start, end);
  }
}