Pangaea Jewelry Meditation

set %Delay 0
While #True
 {
  if %Delay < #SCNT
   {
    if #Mana = #MaxMana
     {
      GoSub UnEquipJewelry IJG HJG UJG SJG
      wait 3
      GoSub EquipJewelry IJG HJG UJG SJG
      wait 1
     }
    GoSub Meditate FMC
   }
 }

Sub EquipJewelry
for %i 1 %0
 {
  FindItem % . %i C_ , #BackPackID
  if #FindID <> X
   {
    ExEvent Drag #FindID #FindStack
    wait 1
    ExEvent Droppd
   }
 }
return

Sub UnEquipJewelry
for %i 1 %0
 {
  FindItem % . %i C_ , #CharID
  if #FindID <> X
   {
    ExEvent Drag #FindID #FindStack
    wait 1
    ExEvent Dropc #BackPackID
   }
 }
return

;GoSub Meditate
;Optional param to send, FMC will return from sub only when you are full mana, useful for if you
;are using in a macro where you need to be done with meditation before proceeding onto another
;action, inscription comes to mind, casting spells also would be another reason.
Sub Meditate
set !lpc #lpc
set #lpc 1000
event Macro 13 46
set %Delay #SCNT + 30

set %jrnl #jindex
while #true
 {
  if #jindex > %jrnl
   {
    set %jrnl %jrnl + 1
    scanjournal %jrnl
    if I_am_already_performing in #journal
     {
      Set %MedCD #SCNT + 5
      While %MedCD < #SCNT
       {
        if #Mana = #MaxMana
         {
          set #lpc !lpc
          return
         }
       }
      set %Delay #SCNT + 30
      event Macro 13 46
     }
    if You_are_at_peace. in #journal
     {
      Event Sysmessage Silly Mana User! You are at full mana
      set #lpc !lpc
      return
     }
    if to_concentrate in #journal
     {
      Set %MedCD #SCNT + 30
      While %MedCD < #SCNT
       {
        if #Mana = #MaxMana
         {
          set #lpc !lpc
          return
         }
       }
      set %Delay #SCNT + 30
      event Macro 13 46
     }
    if Meditating in #journal
     {
      Set #lpc !lpc
      if %1 = FMC
       {
        While #MANA <> #MAXMANA
         {
          onhotkey ESC
           {
            Event Sysmessage Stopping Mana Monitoring.
            set #lpc !lpc
            return MMStop
           }
         }
        set #lpc !lpc
        return
       }
      set #lpc !lpc
      return
     }
   }
 }