API tools faq
paste
Advertisement
mawen1250

Contra-Sharpen mod 3.3

mawen1250
Sep 19th, 2012
143
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 25.16 KB | None | 0 0
raw download clone embed print report
  1. ###### Contra-Sharpen mod 3.3 ###### by mawen1250 ###### 2012.09.19 ######
  2. ###### Requirements: masktools v2.0a48, mvtools v2.5.11.3/v2.6.0.5, RemoveGrain + Repair v1.0pre, RemoveGrainHD v0.5    ######
  3. ###### FluxSmooth v1.1a, nnedi3 v0.9.4, SangNom 2004.01.18(filter_ss="AA"), TEdgeMask v0.9, tcanny v1.0, MSharpen v1.10 ######
  4.  
  5. Function CSmod(clip filtered, clip "source", clip "pclip", bool "chroma",
  6. \ int "edgemode", val "edgemask", float "edgethr", float "tcannysigma", bool "mergesrc",
  7. \ float "ss_w", float "ss_h", bool "ss_hq", string "ssmethod", string "filter_ss", bool "ssrep", bool "ssout", bool "ssoutc",
  8. \ int "preblur", bool "prec", int "preR", bool "usepasf",
  9. \ int "Smethod", val "kernel", bool "secure", string "filter_nr",
  10. \ val "Smode", float "strength", float "divisor", float "index", float "Szrp", float "Spwr", float "SdmpLo", float "SdmpHi",
  11. \ bool "limit", int "Repmode", int "RepmodeU", int "thr", bool "choversh",
  12. \ bool "Slimit", bool "Tlimit", int "Sovershoot", int "Sundershoot", int "Tovershoot", int "Tundershoot",
  13. \ float "Soft", int "Soothe",
  14. \ bool "chromamv", int "blksize", int "overlap", int "thSAD", int "thSCD1", int "thSCD2",
  15. \ bool "truemotion", bool "MVglobal", int "pel", int "pelsearch", int "search", int "searchparam", int "MVsharp", int "DCT")
  16. {
  17.  
  18. defsrc   = Defined(source   )
  19. defpclp  = Defined(pclip    )
  20. deffss   = Defined(filter_ss)
  21. deffnr   = Defined(filter_nr)
  22. AA       = deffss ? filter_ss=="AA" : false
  23. sw       = filtered.width()
  24. sh       = filtered.height()
  25. HD       = (sw > 1024 || sh > 576) ? true : false
  26.  
  27. chroma   = Default(chroma,  false  )
  28.  
  29. edgemode    = Default(edgemode,    AA ? 1 : 0  )
  30. # 0 = Sharpening all, 1 = Sharpening only edge, 2 = Sharpening only non-edge.
  31. # By default, edgemode=2 is tuned for enhancing noise/small detail.
  32. # It will automatically set [edgemask=-2, ss_w=1, ss_h=1, preblur=0, kernel=5, Slimit=false, Tlimit=true(when limit=false)].
  33. edgemask    = Default(edgemask,    edgemode==2?-2:AA?7:2)
  34. # -1: Similar to 1 and tweaking for edgemode=2,   -2: Similar to 2 and tweaking for edgemode=2,
  35. #  1: Same as edgemaskHQ=false in LSFmod(min/max), 2: Same as edgemaskHQ=true in LSFmod,
  36. #  3: Same as sharpening mask in MCTD(prewitt),    4: Same as mtype=1 in TAA(sobel),
  37. #  5: Same as mtype=2 in TAA(roberts),             6: Same as mtype=3 in TAA(prewitt),
  38. #  7: Same as mtype=4 in TAA(TEdgeMask),           8: Same as mtype=5 in TAA(tcanny),
  39. #  9: Same as mtype=6 in TAA(MSharpen),           10: (or any other numbers) My own method of tcanny usage.
  40. #     Otherwise define a custom edge mask clip, only luma is taken to merge all planes.
  41. edgethr     = Default(edgethr,     32.0        )   #Tweak edge mask thr in edgemask mode -2/-1/1/2/6/7/8/9/10.
  42. tcannysigma = Default(tcannysigma, 1.2         )   #Tweak tcanny's sigma in edgemask mode 8/10.
  43. mergesrc    = Default(mergesrc,    false       )   #Whether to merge clip "source" instead of clip "filtered" at the end of processing.
  44.  
  45. ss_w     = Default(ss_w,    edgemode>=2?1.00:1.50)   #Super sampling multiplier of width.
  46. ss_h     = Default(ss_h,    edgemode>=2?1.00:1.50)   #Super sampling multiplier of height.
  47. ss_w     = max    (ss_w,    1.00   )
  48. ss_h     = max    (ss_h,    1.00   )
  49. ss_hq    = Default(ss_hq,   ss_w*ss_h>=3.0625)   #True using nnedi3_rpow2 in super sampling, false using non-ringing Spline64Resize.
  50. ssout    = Default(ssout,   false  )   #Output in super sampling resolution.
  51. ssoutc   = Default(ssoutc,  true   )   #Whether to output correct chroma when (chroma==false && ss_hq==false && ssout==true).
  52. ssrep    = Default(ssrep,   false  )   #When limiting sharpening to source clip, whether to Repair in super sampling resolution.
  53. ssout    = (ss_w > 1.0 || ss_h > 1.0) ? ssout : false
  54. ssrep    = (ss_w > 1.0 || ss_h > 1.0) ? ssrep : false
  55. ssoutc   = (!chroma && ssout) ? ssoutc : false
  56. ssrep    = ssout ? true : ssrep
  57. filter_ss= deffss ? AA ? "SangNom(aa=48).TurnRight().SangNom(aa=48).TurnLeft()" : filter_ss : NOP()
  58. # When defining filter_ss="AA", it will automatically use SangNom for anti-aliasing in super sampling clip, and it will automatically set [Repmode=13, edgemode=1, edgemask=7].
  59.  
  60. preblur  = Default(preblur, edgemode>=2?0:ss_w*ss_h>1&&edgemode==1?0:1)
  61. # Pre-filtering, 0 = disable, 1 = MinBlur, 2 = MinBlur(Uses SBR by default) mixed with MinBlur+FluxSmoothT,
  62. # 3 = MinBlur(Uses SBR by default)+FluxSmoothT, ignored when pclip is defined.
  63. prec     = Default(prec,    preblur>=1)   #Whether to process chroma plane in preblur.
  64. preR     = Default(preR,    preblur>=2?0:ss_w*ss_h>6.25?3:ss_w*ss_h>2.25?2:1)
  65. # MinBlur setting, 1-3 sets radius of MinBlur(Gaussian|Median), 0 uses SBR instead of normal Gaussian Blur in MinBlur.
  66. usepasf  = Default(usepasf, false  )
  67. # Whether to use pre-filtered clip as input(filtered) clip, which will reduce noise/halo/ring from input clip.
  68. usepasf  = (preblur<=0 && !defpclp) ? false : usepasf
  69.  
  70. Smethod  = Default(Smethod, ss_w*ss_h>1?3:1)   #Sharpen Method - 1: 3x3 kernel, 2: Min/Max, 3: Min/Max + 3x3 kernel.
  71. kernel   = Default(kernel,  edgemode>=2 ? 5 : Smethod>=3 ? ss_w*ss_h>=9?4:ss_w*ss_h>=4?3:ss_w*ss_h>=2.25?2:1
  72. \                                                        : ss_w*ss_h>=4?4:ss_w*ss_h>=2.25?3:ss_w*ss_h> 1?2:1)
  73. # 1: Gaussian Blur radius=1(RG11), 2: Average Blur(RG20), 3: Gaussian Blur radius=2(RG11+RG20),
  74. # 4: Gaussian Blur radius=3(RG11+RG20+RG20), 5: for noise/detail enhance(RG19+RG4), default for edgemode==2,
  75. # Otherwise define a custom kernel in string such as kernel="RemoveGrain(20, 11)".
  76. secure   = Default(secure,  true   )   #Mode to avoid banding & oil painting (or face wax) effect of sharpening.(from LSFmod)
  77. Smode    = Default(Smode,   3      )
  78. # Sharpen Mode - 0: None, 1: Linear, 2: Non-linear 1, 3:Non-linear 2(from LSFmod Smode=5), Otherwise define a custom Smode in string.
  79. divisor  = Default(divisor, 1.5    )
  80. index    = Default(index,   0.8    )
  81. #strength = Default(strength,120.0  )
  82. Szrp     = Default(Szrp,    16     )
  83. Spwr     = Default(Spwr,    4      )
  84. SdmpLo   = Default(SdmpLo,  4      )
  85. SdmpHi   = Default(SdmpHi,  48     )
  86. miSpwr   = 1.0/Spwr
  87.  
  88. limit    = Default(limit,   true   )
  89. # Whether to limit sharpening to source clip, only takes effect when (Defined(source) || Defined(filter_ss) || usepasf) == true.
  90. thr      = Default(thr,     0      )   #When limiting sharpening to source clip, allow sharpening more than the source in [thr].
  91. choversh = Default(choversh,true   )
  92. # When (chroma==true && limit==true && thr>=1 && choversh==false), luma will sharpen more than source, chroma will not.
  93. Repmode  = Default(Repmode, AA?13:1)
  94. RepmodeU = Default(RepmodeU,Repmode)
  95. limit    = defsrc || deffss || usepasf || deffnr ? limit : false
  96.  
  97. Slimit      = Default(Slimit,      edgemode>=2?false:!limit)
  98. # Spatial limit with overshoot and undershoot. Disabled when (limit==true && thr==0).
  99. Tlimit      = Default(Tlimit,      edgemode>=2&&!limit?true:false)
  100. # Use MC Temporal limit at the end of sharpening(only process luma).(from MCTD)
  101. strength    = Default(strength,    Tlimit?160:120)
  102. Sovershoot  = Default(Sovershoot,  Round(strength/160))
  103. Sundershoot = Default(Sundershoot, Sovershoot  )
  104. Tovershoot  = Default(Tovershoot,  edgemode>=2?Round(strength/80):Round(strength/40))
  105. Tundershoot = Default(Tundershoot, Tovershoot  )
  106. Soft        = Default(Soft,        limit?  0:-2)
  107. # Soft the sharpening effect (-1 = old autocalculate, -2 = new autocalculate, 0 = disable, (0, 100] = enable). Disabled when (limit==true && thr==0).(from LSFmod)
  108. Soothe      = Default(Soothe,      limit? -1:24)
  109. # Soothe temporal stabilization, 0-100 sets minimum percent of the original sharpening to keep, -1 disables Soothe. Disabled when (chroma==true && Tlimit=true).
  110. Sovershoot  = max(Sovershoot,  0)
  111. Sundershoot = max(Sundershoot, 0)
  112. Tovershoot  = max(Tovershoot,  0)
  113. Tundershoot = max(Tundershoot, 0)
  114.  
  115. chromamv    = Default(chromamv,    chroma      )
  116. blksize     = Default(blksize,     HD ? 16 : 8 )
  117. overlap     = Default(overlap,     blksize/2   )
  118. thSAD       = Default(thSAD,       300         )
  119. thSCD1      = Default(thSCD1,      300         )
  120. thSCD2      = Default(thSCD2,      100         )
  121. truemotion  = Default(truemotion,  false       )
  122. MVglobal    = Default(MVglobal,    true        )
  123. pel         = Default(pel,         2           )
  124. pelsearch   = Default(pelsearch,   2           )
  125. search      = Default(search,      2           )
  126. searchparam = Default(searchparam, 2           )
  127. MVsharp     = Default(MVsharp,     2           )
  128. DCT         = Default(DCT,         0           )
  129.  
  130.  
  131. wss      = Round(sw*ss_w/8)*8
  132. hss      = Round(sh*ss_h/8)*8
  133. rfactor  = max(Round(sqrt(ss_w*ss_h)/2)*2, 2)
  134. ssmethod = Defined(ssmethod) ? ssmethod
  135. \        : ss_hq ? """nnedi3_rpow2(rfactor=rfactor, qual=2, cshift="Spline64Resize", fwidth=wss, fheight=hss)"""
  136. \                : "CSmod_nrSpline64Resize(wss, hss, chroma=chroma||ssoutc)"
  137. # You can define your own super sampling method with ssmethod.
  138.  
  139. ch21     = chroma ? 2 : 1
  140. ch31     = chroma ? 3 : 1
  141. ch41     = chroma ? 4 : 1
  142. ch32     = chroma ? 3 : 2
  143. ch34     = chroma ? 3 : 4
  144. Slimit   = limit && thr==0 ? false : Slimit
  145. Soft     = limit && thr==0 ? 0
  146. \        : Soft <= -2  ? (1.0+(2.0/(ss_w+ss_h))) * sqrt(strength)
  147. \        : Soft == -1  ? sqrt( (((ss_w+ss_h)/2.0-1.0)*100.0) ) * 10
  148. \        : Soft <= 100 ? Soft : 100
  149. Soothe   = Tlimit ? -1 : Soothe
  150.  
  151.  
  152. # super sampling, filtering in ss clip
  153. source      = defsrc ? source : filtered
  154. filtered_os = filtered
  155. filtered_ss = (ss_w > 1.0 || ss_h > 1.0) ? Eval("filtered."+ssmethod) : filtered
  156. source_ss   = (ss_w > 1.0 || ss_h > 1.0) ? defsrc ? Eval("source."+ssmethod) : filtered_ss : source
  157. filtered    = deffss ? Eval("filtered_ss."+filter_ss) : filtered_ss
  158. filtered_ds = (ss_w > 1.0 || ss_h > 1.0) ? deffss ? filtered.CSmod_nrSpline64Resize(sw, sh, chroma=chroma) : filtered_os : filtered
  159.  
  160. Assert( (isFrameBased(filtered_os)),                            """CSmod: input clip "filtered" must be Frame Based!""" )
  161. Assert( (isFrameBased(source)),                                   """CSmod: input clip "source" must be Frame Based!""" )
  162. Assert( (source.width() == sw && source.height() == sh), """CSmod: resolution of "filtered" and "source" must match!""" )
  163.  
  164.  
  165. # pre-filtering before sharpening
  166. spatial     = filtered.MinBlur(preR, chroma||chromamv ? prec ? 3 : 2 : 1)
  167. temporal    = spatial .FluxsmoothT(7).Repair(spatial, 1, prec ? 1 : -1)
  168. temporal    = chroma||chromamv&&!prec ? temporal.MergeChroma(filtered) : temporal
  169. mixed       = temporal.merge(spatial,0.251)
  170. pre         = defpclp    ? pclip
  171. \           : preblur==1 ? spatial
  172. \           : preblur==2 ? mixed
  173. \           : preblur>=3 ? temporal
  174. \           : filtered
  175. # You can define your own pre-filter clip with pclip.
  176. pre_ds      = (pre.width() == sw && pre.height() == sh) ? pre : pre.CSmod_nrSpline64Resize(sw, sh, chroma=chroma||chromamv)
  177. pre         = (ss_w > 1.0 || ss_h > 1.0) ? (pre.width() == wss && pre.height() == hss) ? pre : Eval("pre."+ssmethod) : pre_ds
  178.  
  179. # whether to use pre-filtered clip as main clip
  180. filtered    = usepasf ? pre    : filtered
  181. filtered_ds = usepasf ? pre_ds : filtered_ds
  182.  
  183.  
  184. # generate edge mask
  185. prefinal  = ssout ? pre       : pre_ds
  186. srcfinal  = ssout ? source_ss : source
  187. edgemask  = IsClip(edgemask) ? edgemask
  188. \         : IsInt (edgemask) ?
  189. \           edgemask <= -2   ? mt_logic(prefinal.mt_edge(thY1=0, thY2=255, "8 16 8 0 0 0 -8 -16 -8 4", U=1, V=1),
  190. \                                       prefinal.mt_edge(thY1=0, thY2=255, "8 0 -8 16 0 -16 8 0 -8 4", U=1, V=1),
  191. \                                       "max", U=1, V=1).mt_lut("x " + string(edgethr*4) + " / 0.86 ^ 255 *", U=1, V=1)
  192. \                             .Removegrain(11, -1)
  193. \         : edgemask == -1   ? prefinal.mt_edge(thY1=0, thY2=255, mode="min/max", U=1, V=1)
  194. \                             .mt_lut("x " + string(edgethr) + " / 0.86 ^ 255 *", U=1, V=1)
  195. \                             .Removegrain(11, -1)
  196. \         : edgemask == 1    ? prefinal.mt_edge(thY1=0, thY2=255, mode="min/max", U=1, V=1)
  197. \                             .mt_lut("x " + string(edgethr) + " / 0.86 ^ 255 *", U=1, V=1)
  198. \                             .mt_inflate(U=1, V=1).mt_inflate(U=1, V=1).Removegrain(11, -1)
  199. \         : edgemask == 2    ? mt_logic(prefinal.mt_edge(thY1=0, thY2=255, "8 16 8 0 0 0 -8 -16 -8 4", U=1, V=1),
  200. \                                       prefinal.mt_edge(thY1=0, thY2=255, "8 0 -8 16 0 -16 8 0 -8 4", U=1, V=1),
  201. \                                       "max", U=1, V=1).mt_lut("x " + string(edgethr*4) + " / 0.86 ^ 255 *", U=1, V=1)
  202. \                             .mt_inflate(U=1, V=1).mt_inflate(U=1, V=1).RemoveGrain(11, -1)
  203. \         : edgemask == 3    ? mt_edge(prefinal, "prewitt", 0, 255, 0, 0, V=1, U=1)
  204. \                             .mt_lut("x 1.8 ^", U=1, V=1).RemoveGrain(4, -1).mt_inflate(U=1, V=1).RemoveGrain(20,-1)
  205. \         : edgemask == 4    ? mt_edge(prefinal, "sobel", 7, 7, 5, 5, U=1, V=1).mt_inflate(U=1, V=1)
  206. \         : edgemask == 5    ? mt_edge(prefinal, "roberts", 0, 4, 0, 4, U=1, V=1).mt_inflate(U=1, V=1)
  207. \         : edgemask == 6    ? mt_edge(prefinal, "prewitt", 0, 255, 0, 0, U=1, V=1)
  208. \                             .mt_lut("x " + string(edgethr) + " <= x 1 >> x 1.4 ^ ?", U=1, V=1)
  209. \                             .RemoveGrain(4, -1).mt_inflate(U=1, V=1)
  210. \         : edgemask == 7    ? TEdgeMask(prefinal, link=2, preblur=false, valon=-1, U=0, V=0)
  211. \                             .mt_lut("x " + string(edgethr/5) + " <= x 1 >> x 4 << ?", U=1, V=1)
  212. \                             .mt_deflate(U=1, V=1).RemoveGrain(HD ? 20 : 11, -1)
  213. \         : edgemask == 8    ? tcanny(srcfinal, sigma=tcannysigma, mode=1, plane=1)
  214. \                             .mt_lut("x " + string(edgethr) + " <= x 1 >> x 1 << ?", U=1, V=1)
  215. \                             .RemoveGrain(HD ? 20 : 11, -1).mt_inflate(U=1, V=1)
  216. \         : edgemask == 9    ? MSharpen(prefinal, threshold=Round(edgethr/5), strength=0, mask=true, highq=false)
  217. \         :                    tcanny(srcfinal, sigma=tcannysigma, mode=1, plane=1)
  218. \                             .mt_lut("x " + string(edgethr) + " <= 0 x " + string(edgethr) + " - 6 << ?", U=1, V=1)
  219. \                             .RemoveGrain(HD ? 20 : 11, -1).mt_inflate(U=1, V=1)
  220. \         :                    Assert(false, """CSmod: "edgemask" should be int or clip!""")
  221.  
  222.  
  223. # unsharp
  224. dark_limit   = pre.mt_inpand(U=ch31, V=ch31)
  225. bright_limit = pre.mt_expand(U=ch31, V=ch31)
  226. minmaxavg    = mt_average(dark_limit, bright_limit, U=ch31, V=ch31)
  227.  
  228. method     = Smethod <= 1     ? pre : minmaxavg
  229.  
  230. method     = Smethod == 2     ? method
  231. \          : IsString(kernel) ? Eval("method."+kernel)
  232. \          : IsInt   (kernel) ?
  233. \            kernel <= 1      ? method.RemoveGrain(11, chroma?11:-1)
  234. \          : kernel == 2      ? method.RemoveGrain(20, chroma?20:-1)
  235. \          : kernel == 3      ? method.RemoveGrain(11, chroma?11:-1).RemoveGrain(20, chroma?20:-1)
  236. \          : kernel == 4      ? method.RemoveGrain(11, chroma?11:-1).RemoveGrain(20, chroma?20:-1).RemoveGrain(20, chroma?20:-1)
  237. \          :                    method.RemoveGrain(19, chroma?19:-1).RemoveGrain(4 , chroma?4 :-1)
  238. \          :                    Assert(false, """CSmod: "kernel" should be int or string!""")
  239.  
  240. method     = secure           ? method.mt_lutxy(pre, "x y < x 1 + x y > x 1 - x ? ?", U=ch31, V=ch31) : method
  241.  
  242.  
  243. # making difference clip for sharpening
  244. sharpdiff  = mt_makediff(pre, method, U=ch31,V=ch31)
  245.  
  246.  
  247. # filtering in nr clip
  248. filtered   = deffnr ? Eval("method." + filter_nr).mt_adddiff(sharpdiff, U=ch31, V=ch31) : filtered
  249. filtered_ds= (ss_w > 1.0 || ss_h > 1.0) ? deffnr      ? filtered.CSmod_nrSpline64Resize(sw, sh, chroma=chroma)
  250. \                                       : filtered_ds : filtered
  251.  
  252.  
  253. # sharpening diff generate mode
  254. sharpdiff  = IsString(Smode)  ? sharpdiff.mt_lut(Smode, U=ch31, V=ch31)
  255. \          : IsInt   (Smode)  ?
  256. \            Smode <= 0       ? sharpdiff
  257. \          : Smode == 1       ? sharpdiff.mt_lut("x 128 == x x 128 - "+string(strength/50.0)+" * 128 + ?", U=ch31, V=ch31)
  258. \          : Smode == 2       ? sharpdiff.mt_lut("x 128 == x x 128 - "+String(divisor)+" / Abs "+String(index)+" ^ "+String(strength/20.0)+" * x 128 > 1 -1 ? * 128 + ?", U=ch31, V=ch31)
  259. \          :                    sharpdiff.mt_lut("x 128 == x x 128 - abs "+string(Szrp)+" / "+string(miSpwr)+" ^ "+string(Szrp)+" * "+string(strength/100.0)+" * x 128 > 1 -1 ? * x 128 - 2 ^ "+string(Szrp)+" 2 ^ "+string(SdmpLo)+" + * x 128 - 2 ^ "+string(SdmpLo)+" + "+string(Szrp)+" 2 ^ * / * 1 "+string(SdmpHi)+" 0 == 0 "+string(Szrp)+" "+string(SdmpHi)+" / 4 ^ ? + 1 "+string(SdmpHi)+" 0 == 0 x 128 - abs "+string(SdmpHi)+" / 4 ^ ? + / * 128 + ?", U=ch31, V=ch31)
  260. \          :                    Assert(false,  """CSmod: "Smode" should be int or string!""")
  261.  
  262. # x==128 ? x : (abs(x-128)/Szrp)^(miSpwr)*Szrp*(strength/100.0)*(x>128 ? 1 : -1) * ((x-128)^2*(Szrp^2+SdmpLo) / ((x-128)^2+SdmpLo)*Szrp^2) * ((1+ SdmpHi==0 ? 0 : (Szrp/SdmpHi)^4) / (1+ SdmpHi==0 ? 0 : (abs(x-128)/SdmpHi)^4)) + 128
  263.  
  264.  
  265. # spatial limit
  266. DlimitF    = usepasf || (preblur<=0 && !defpclp) ?   dark_limit : filtered.mt_inpand(U=ch31, V=ch31)
  267. BlimitF    = usepasf || (preblur<=0 && !defpclp) ? bright_limit : filtered.mt_expand(U=ch31, V=ch31)
  268. sclp       = Slimit ? mt_adddiff(filtered, sharpdiff, U=ch31, V=ch31) : NOP()
  269. sclp       = Slimit ? sclp.mt_clamp(BlimitF, DlimitF, Sovershoot, Sundershoot, U=ch31, V=ch31) : NOP()
  270.  
  271.  
  272. # Soft
  273. sharpdiff  = Slimit ? mt_makediff(sclp, filtered, U=ch31, V=ch31) : sharpdiff
  274. sharpdiff  = Soft == 0 ? sharpdiff : mt_lutxy(sharpdiff, sharpdiff.RemoveGrain(19, chroma ? 19 : -1), "x 128 - abs y 128 - abs > y "+string(Soft)+" * x "+string(100-Soft)+" * + 100 / x ?", U=ch31, V=ch31)
  275.  
  276.  
  277. # Soothe
  278. sharpdiff2 = (Soothe >= 0 && Soothe <= 100) ? sharpdiff.temporalsoften(1,255,chroma ? 255 : 0,32,2) : NOP()
  279. sharpdiff  = (Soothe >= 0 && Soothe <= 100) ? mt_lutxy(sharpdiff, sharpdiff2, "x 128 - y 128 - * 0 < x 128 - 100 / "+string(Soothe)+" * 128 + x 128 - abs y 128 - abs > x "+string(Soothe)+" * y 100 "+string(Soothe)+" - * + 100 / x ? ?", U=ch31, V=ch31) : sharpdiff
  280.  
  281.  
  282. # the difference achieved by filtering
  283. allD       = limit  ? ssrep && (ss_w > 1.0 || ss_h > 1.0) ? mt_makediff(source_ss, filtered, U=ch31, V=ch31)
  284. \                                                         : mt_makediff(source, filtered_ds, U=ch31, V=ch31) : NOP()
  285.  
  286. # limiting sharpening to source clip
  287. sharpdiff  = !ssrep && (ss_w > 1.0 || ss_h > 1.0) ? sharpdiff.CSmod_nrSpline64Resize(sw, sh, chroma=chroma) : sharpdiff
  288. ssDD       = limit  ? sharpdiff.Repair(allD, mode=Repmode, modeU=chroma ? RepmodeU : -1) : sharpdiff
  289. ssDD       = limit && thr >= 1 ? sharpdiff.mt_lutxy(ssDD,"x 128 - abs y 128 - abs " + string(thr) + " + <= x y 128 < y " + string(thr) + " - y " + string(thr) + " + ? ?", U=choversh?ch31:ch41, V=choversh?ch31:ch41) : ssDD
  290. ssDD       = limit && thr == 0 || (limit && !choversh) ? ssDD.mt_lutxy(sharpdiff, "x 128 - abs y 128 - abs < x y ?", Y=(limit && thr >= 1 && !choversh)?2:3, U=ch31, V=ch31) : ssDD
  291. ssDD       = ssrep && (ss_w > 1.0 || ss_h > 1.0) && !ssout ? ssDD.CSmod_nrSpline64Resize(sw, sh, chroma=chroma) : ssDD
  292.  
  293. # add difference clip to clip "filtered" of ss/original resolution
  294. sclp       = ssout ? mt_adddiff(filtered, ssDD, U=ch31, V=ch31) : mt_adddiff(filtered_ds, ssDD, U=ch31, V=ch31)
  295.  
  296.  
  297. # temporal limit
  298.  
  299. sMVS       = prefinal.MSuper(hpad=0, vpad=0, pel=pel, levels=0, sharp=MVsharp, chroma=chromamv)
  300. rMVS       = usepasf || (preblur<=0 && !defpclp) ? sMVS
  301. \                                                : srcfinal.MSuper(hpad=0, vpad=0, pel=pel, levels=1, sharp=MVsharp, chroma=chroma)
  302. f1v        = MAnalyse(sMVS, isb=false, delta=1, truemotion=truemotion, blksize=blksize, overlap=overlap, pelsearch=pelsearch, search=search, searchparam=searchparam, DCT=DCT, global=MVglobal, chroma=chromamv)
  303. b1v        = MAnalyse(sMVS, isb=true,  delta=1, truemotion=truemotion, blksize=blksize, overlap=overlap, pelsearch=pelsearch, search=search, searchparam=searchparam, DCT=DCT, global=MVglobal, chroma=chromamv)
  304. f1c        = MCompensate(srcfinal, rMVS, f1v, thSAD=thSAD, thSCD1=thSCD1, thSCD2=thSCD2)
  305. b1c        = MCompensate(srcfinal, rMVS, b1v, thSAD=thSAD, thSCD1=thSCD1, thSCD2=thSCD2)
  306. Tmax       = srcfinal.mt_logic(f1c, "max", U=ch31, V=ch31).mt_logic(b1c, "max", U=ch31, V=ch31)
  307. Tmin       = srcfinal.mt_logic(f1c, "min", U=ch31, V=ch31).mt_logic(b1c, "min", U=ch31, V=ch31)
  308. sclp       = Tlimit ? sclp.mt_clamp(Tmax, Tmin, Tovershoot, Tundershoot, U=ch32, V=ch32) : sclp
  309.  
  310.  
  311. # merge with edge mask and output correct chroma
  312. merged_ss  = mergesrc ? source_ss : filtered_ss
  313. merged_os  = mergesrc ? source    : filtered_os
  314.  
  315. end        = edgemode <= 0 ? chroma ? sclp
  316. \                                   : ssout ? ssoutc ? sclp.MergeChroma(merged_ss)
  317. \                                                    : sclp
  318. \                                           : sclp.MergeChroma(merged_os)
  319. \          : edgemode == 1 ? ssout ? mt_merge(merged_ss, sclp, edgemask, luma=chroma, Y=3, U=ssoutc?ch32:ch31, V=ssoutc?ch32:ch31)
  320. \                                  : mt_merge(merged_os, sclp, edgemask, luma=chroma, Y=3, U=ch32,             V=ch32            )
  321. \                          : ssout ? mt_merge(sclp, merged_ss, edgemask, luma=chroma, Y=3, U=ssoutc?ch34:ch31, V=ssoutc?ch34:ch31)
  322. \                                  : mt_merge(sclp, merged_os, edgemask, luma=chroma, Y=3, U=ch34,             V=ch34            )
  323.  
  324. return end
  325. }
  326.  
  327.  
  328. Function MinBlur(clip clp, int "r", int "uv"){
  329.  
  330. r     = Default(r,  1)
  331. uv    = Default(uv, 3)
  332.  
  333. uv2   = (uv==2) ? 1  : uv
  334. rg4   = (uv==3) ? 4  : -1
  335. rg11  = (uv==3) ? 11 : -1
  336. rg20  = (uv==3) ? 20 : -1
  337. medf  = (uv==3) ? 1  : -200
  338. uvm2  = (r==2)  ? (uv==3?3:uv==2?0:-1) : nop()
  339. uvm3  = (r==3)  ? (uv==3?3:uv==2?0:-1) : nop()
  340.  
  341. RG11D = (r<=0) ? mt_makediff(clp, clp.sbr(uv=uv2), U=uv2, V=uv2)
  342. \     : (r==1) ? mt_makediff(clp, clp.RemoveGrain(11, rg11), U=uv2, V=uv2)
  343. \     : (r==2) ? mt_makediff(clp, clp.RemoveGrain(11, rg11).RemoveGrain(20, rg20), U=uv2, V=uv2)
  344. \     :          mt_makediff(clp, clp.RemoveGrain(11, rg11).RemoveGrain(20, rg20).RemoveGrain(20, rg20), U=uv2, V=uv2)
  345. RG4D  = (r<=1) ? mt_makediff(clp, clp.RemoveGrain(4,  rg4 ), U=uv2, V=uv2)
  346. \     : (r==2) ? mt_makediff(clp, clp.Quantile(radius_y=2, radius_u=uvm2, radius_v=uvm2), U=uv2, V=uv2)
  347. \     :          mt_makediff(clp, clp.Quantile(radius_y=3, radius_u=uvm3, radius_v=uvm3), U=uv2, V=uv2)
  348.  
  349. DD    = mt_lutxy(RG11D, RG4D, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=uv2, V=uv2)
  350.  
  351. return clp.mt_makediff(DD, U=uv, V=uv)
  352. }
  353.  
  354.  
  355. Function sbr(clip c, int "uv") {
  356. uv     = Default(uv, 1)
  357. uv2    = (uv==2) ? 1  : uv
  358. rg11   = (uv==3) ? 11 : -1
  359. rg11D  = mt_makediff(c, c.RemoveGrain(11, rg11), U=uv2, V=uv2)
  360. rg11DD = mt_lutxy(rg11D, rg11D.RemoveGrain(11, rg11), "x y - x 128 - * 0 < 128 x y - abs x 128 - abs < x y - 128 + x ? ?", U=uv2, V=uv2)
  361.  
  362. return c.mt_makediff(rg11DD, U=uv, V=uv)
  363. }
  364.  
  365.  
  366. Function CSmod_nrSpline64Resize(clip input, int "target_width", int "target_height", float "src_left", float "src_top", float "src_width", float "src_height", bool "chroma", val "nr") {
  367.  
  368.   w             = input.Width
  369.   h             = input.Height
  370.  
  371.   target_width  = Default(target_width,      w)
  372.   target_height = Default(target_height,     h)
  373.   src_left      = Default(src_left,          0)
  374.   src_top       = Default(src_top,           0)
  375.   src_width     = Default(src_width,         w)
  376.   src_height    = Default(src_height,        h)
  377.   chroma        = Default(chroma,         true)
  378.   nr            = Default(nr,             true)
  379.  
  380.   Assert( IsFloat(nr) || IsBool(nr), """CSmod_nrSpline64Resize: "nr" should be either bool or float!""" )
  381.  
  382.   res_mul   = Float( target_width * target_height ) / Float( w * h )
  383.   res_mul   = min( max( res_mul, 1 ), 2.25 )
  384.   nr_weight = IsFloat(nr)       ? nr
  385.   \         : nr /* == True  */ ? Spline( res_mul, 1, 0, 2.25, 1, 3.5, 0, true )
  386.   \         :    /* == False */   0
  387.   nr_weight = min( max( nr_weight, 0 ), 1 )
  388.  
  389.   forceYV12 = input.IsYV12 == false && nr_weight != 0
  390.  
  391.   try {
  392.     inputp = chroma ? forceYV12 ? input .ConvertToYV12
  393.     \                           : input
  394.     \               : input.ConvertToY8
  395.   } catch ( error_msg ) {
  396.     inputp = forceYV12 ? input.ConvertToYV12
  397.     \                  : input
  398.   }
  399.  
  400.   resize = inputp.Spline64Resize(target_width, target_height, src_left, src_top, src_width, src_height)
  401.   nrres  = inputp.GaussResize(target_width, target_height, src_left, src_top, src_width, src_height, p=100)
  402.   resize = resize.CSmod_GetCSP == "Y8" ? resize.ConvertToYV12 : resize
  403.   nrres  = nrres .CSmod_GetCSP == "Y8" ? nrres .ConvertToYV12 : nrres
  404.  
  405.   resize = nr_weight == 0 ? resize
  406.   \      : nr_weight == 1 ? resize.Repair(nrres, 1, chroma ? 1 : -1)
  407.   \      : chroma         ? Merge    (resize, resize.Repair(nrres, 1,  1), nr_weight)
  408.   \                       : MergeLuma(resize, resize.Repair(nrres, 1, -1), nr_weight)
  409.  
  410.   return resize
  411. }
  412.  
  413.  
  414. Function CSmod_GetCSP(clip c) {
  415.   return c.IsPlanar ? c.IsYV12 ? "YV12" :
  416.   \                   c.IsYV16 ? "YV16" :
  417.   \                   c.IsYV24 ? "YV24" : c.CSmod_Y8_YV411 :
  418.   \      c.IsYUY2   ? "YUY2"   :
  419.   \      c.IsRGB32  ? "RGB32"  :
  420.   \      c.IsRGB24  ? "RGB24"  : "Unknown"
  421. }
  422.  
  423.  
  424. Function CSmod_Y8_YV411(clip c) {
  425.   try {
  426.     c.UtoY
  427.     csp = "YV411"
  428.   } catch ( error_msg ) {
  429.     csp = "Y8"
  430.   }
  431.   return csp
  432. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!