//purchase menu
spriteset (spriteset_EMU_SM7_purchase_v1, "gfx/emu/emu_sm7.png")	{ template_purchase(0) }
spriteset (spriteset_EMU_SM7_purchase_v2, "gfx/emu/emu_sm7.png")	{ template_purchase(120) }
//locomotive
spriteset (spriteset_EMU_SM7_front_v1, "gfx/emu/emu_sm7.png")		{ template_8_8(0) }
spriteset (spriteset_EMU_SM7_coach_v1, "gfx/emu/emu_sm7.png")		{ template_8_8(40) }
spriteset (spriteset_EMU_SM7_end_v1, "gfx/emu/emu_sm7.png")			{ template_8_8(80) }
spriteset (spriteset_EMU_SM7_front_v2, "gfx/emu/emu_sm7.png")		{ template_8_8(120) }
spriteset (spriteset_EMU_SM7_coach_v2, "gfx/emu/emu_sm7.png")		{ template_8_8(160) }
spriteset (spriteset_EMU_SM7_end_v2, "gfx/emu/emu_sm7.png")			{ template_8_8(200) }

switch(FEAT_TRAINS, SELF, switch_EMU_SM7_position_v1, (position_in_vehid_chain % 3)) {
	1: return spriteset_EMU_SM7_coach_v1;
	2: return spriteset_EMU_SM7_end_v1;
	return spriteset_EMU_SM7_front_v1;
}
switch(FEAT_TRAINS, SELF, switch_EMU_SM7_position_v2, (position_in_vehid_chain % 3)) {
	1: return spriteset_EMU_SM7_coach_v2;
	2: return spriteset_EMU_SM7_end_v2;
	return spriteset_EMU_SM7_front_v2;
}
switch(FEAT_TRAINS, SELF, switch_EMU_SM7_articulated, extra_callback_info1) {
    1..2: return item_EMU_SM7;
    return CB_RESULT_NO_MORE_ARTICULATED_PARTS;
}
//switch for livery choice
//defaul green, v2
switch (FEAT_TRAINS, SELF, switch_EMU_SM7_liverychoice, cargo_subtype) {
	1: return switch_EMU_SM7_position_v1;
	return switch_EMU_SM7_position_v2;
}
switch (FEAT_TRAINS, SELF, switch_EMU_SM7_subtypetext, cargo_subtype) {
	1: return string(STR_SUBTYPE_BLUE, "");
	return string(STR_SUBTYPE_GREEN, "");
}
//power switch depending on railtype
switch (FEAT_TRAINS, SELF, switch_EMU_SM7_power, current_railtype) {
	RAIL: return 1776;
	ELRL: return 2500;
}
switch(FEAT_TRAINS, SELF, switch_EMU_SM7_visual_effect_diesel, (position_in_vehid_chain % 3)) {
	1: return visual_effect_and_powered(VISUAL_EFFECT_DIESEL, 0, DISABLE_WAGON_POWER);
	return visual_effect_and_powered(VISUAL_EFFECT_DISABLE, 0, DISABLE_WAGON_POWER);
}
switch(FEAT_TRAINS, SELF, switch_EMU_SM7_visual_effect_electric, (position_in_vehid_chain % 3)) {
	1: return visual_effect_and_powered(VISUAL_EFFECT_ELECTRIC, 0, DISABLE_WAGON_POWER);
	return visual_effect_and_powered(VISUAL_EFFECT_DISABLE, 0, DISABLE_WAGON_POWER);
}
switch(FEAT_TRAINS, SELF, switch_EMU_SM7_visual_effect_railtype, current_railtype) {
	RAIL: return switch_EMU_SM7_visual_effect_diesel;
	ELRL: return switch_EMU_SM7_visual_effect_electric;
}

item (FEAT_TRAINS, item_EMU_SM7) {
	property {
		//common properties
		name:								string(STR_NAME_EMU_SM7);
		climates_available:					ALL_CLIMATES;
		introduction_date:					date(2015,01,01);
		model_life:							35;
		vehicle_life:						35;
		reliability_decay:					20;
		loading_speed:						10;
		cost_factor:						120;
		running_cost_factor:				80;
		cargo_age_period:					185;

		//train properties
		sprite_id:							SPRITE_ID_NEW_TRAIN;
		speed:								160 km/h;
		misc_flags:							0;
		refit_cost:							0;
		track_type:							sm7;
		ai_special_flag:					0;
		power:								1776 hpM;
		running_cost_base:					RUNNING_COST_ELECTRIC;
		dual_headed:						0;
		default_cargo_type:					PASS;
		cargo_capacity:						70;
		weight:								135 ton;
		engine_class:						ENGINE_CLASS_DIESEL;
		extra_power_per_wagon:				0;
		tractive_effort_coefficient:		0.2;
		air_drag_coefficient:				0;
		length:								8;
		visual_effect_and_powered:			visual_effect_and_powered(VISUAL_EFFECT_DIESEL, 0, DISABLE_WAGON_POWER);
		bitmask_vehicle_info:				0;
		CARGODEF_PASSENGER_VAN
	}
	graphics {
		cargo_capacity:				70;
		cargo_subtype_text:			switch_EMU_SM7_subtypetext;
		purchase:					spriteset_EMU_SM7_purchase_v2;
		articulated_part:			switch_EMU_SM7_articulated;
		visual_effect_and_powered:	switch_EMU_SM7_visual_effect_railtype;
		power:						switch_EMU_SM7_power;
		default:					switch_EMU_SM7_liverychoice;
	}
}