#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Icon=favicon.ico
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****
#cs ----------------------------------------------------------------------------

 AutoIt Version: 3.3.12.0
 Author:         Neon


#ce ----------------------------------------------------------------------------

#include <Array.au3>
#include <String.au3>
#include <File.au3>

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$path_steam = IniRead("data.ini", "settings", "counterstrike", "Please select a folder!")
$path_winrar = IniRead("data.ini", "settings", "winrar", "Please select a folder!")
$url = "http://fastdl.unloze.com/css_ze/maps/"

$found = True
$running = False


Opt("GUIOnEventMode", 1)
$Form1 = GUICreate("Unloze Mappack by Neon", 491, 163, 197, 130)
GUISetFont(10, 400, 0, "Segoe UI")
$Group1 = GUICtrlCreateGroup("Paths", 8, 8, 369, 89)
$Input1 = GUICtrlCreateInput($path_steam, 16, 32, 241, 25)
GUICtrlSetState(-1, $GUI_DISABLE)
$Button1 = GUICtrlCreateButton("CS:S Path", 272, 32, 91, 25)
$Input2 = GUICtrlCreateInput($path_winrar, 16, 64, 241, 25)
GUICtrlSetState(-1, $GUI_DISABLE)
$Button2 = GUICtrlCreateButton("WinRar Path", 272, 64, 91, 25)
GUICtrlCreateGroup("", -99, -99, 1, 1)
$Button3 = GUICtrlCreateButton("Start", 384, 56, 99, 41)
GUICtrlSetFont(-1, 12, 800, 0, "Segoe UI")
$Button4 = GUICtrlCreateButton("Unloze.com", 384, 16, 99, 33)
$Progress1 = GUICtrlCreateProgress(8, 112, 478, 17)
$Label2 = GUICtrlCreateLabel("...", 8, 136, 477, 21)
GUISetState(@SW_SHOW)

GUISetOnEvent($GUI_EVENT_CLOSE, "_exit")
GUICtrlSetOnEvent($Button1, "_Steam")
GUICtrlSetOnEvent($Button2, "_WinRar")
GUICtrlSetOnEvent($Button3, "_Start")
GUICtrlSetOnEvent($Button4, "_Unloze")

While 1

    If $running Then

        _Main()

    ElseIf Not $running Then

        Sleep(300)

    EndIf

WEnd

Func _Steam()

    $path_steam = FileSelectFolder("Select your Counterstrike folder (The folder with hl2.exe in it)", "C:") & "\cstrike\download\maps"

    If $path_steam = "\cstrike\download\maps" Then
        MsgBox(0,"Error", "Please select a folder!")
        $path_steam = "Please select a folder!"
    EndIf

    GUICtrlSetData($Input1, $path_steam)

EndFunc   ;==>_Steam

Func _WinRar()

    $path_winrar = FileSelectFolder("Select your WinRar folder (The folder with WinRar.exe in it)", "C:") & "\WinRar.exe"

    If $path_winrar = "\WinRar.exe" Then
        MsgBox(0,"Error", "Please select a folder!")
        $path_winrar = "Please select a folder!"
    EndIf

    GUICtrlSetData($Input2, $path_winrar)
EndFunc   ;==>_WinRar

Func _Start()

    If $path_steam = "Please select a folder!" or $path_winrar = "Please select a folder!" Then
        MsgBox(0,"Error!", "You did not select a valid path!")
        _exit()
    EndIf


    IniWrite("data.ini", "settings", "counterstrike", $path_steam)
    IniWrite("data.ini", "settings", "winrar", $path_winrar)

    $running = True

EndFunc   ;==>_Start

Func _Main()

    $raw_code_hex = InetRead($url)
    $raw_code = _HexToString($raw_code_hex)
    $array_online = _StringBetween(StringTrimLeft($raw_code, StringInStr($raw_code, 'disabled/</a>')), '<a href="', '.bz2">')
    $length_online = Ubound($array_online) - 1
    $array_local = _FileListToArray($path_steam)
    $length_local = Ubound($array_local) - 1

    For $i = 0 To $length_online

        $found = False

        For $j = 0 To $length_local

            If StringCompare($array_online[$i], $array_local[$j]) = 0 Then
                $found = True
            EndIf

        Next

            If Not $found Then
                _Download($array_online[$i])
            EndIf

    Next

    $running = False

    MsgBox(64,"Finished","All Missing maps got downloaded and extracted!")

EndFunc   ;==>_Main

Func _Download($name)

    GUICtrlSetData($Label2, "Downloading:  " & $name & ".bz2")

    $FileSize_online = InetGetSize($url & $name & ".bz2")
    InetGet($url & $name & ".bz2" , $name & ".bz2", 0, 1)

    While 1

    $FileSize_local = FileGetSize($name & ".bz2")

    $Percent = $FileSize_local / $FileSize_online * 100
    Sleep(100)
    GUICtrlSetData($Progress1, $Percent)

    If $FileSize_local = $FileSize_online Then  ExitLoop

    WEnd

    Sleep(500)


    GUICtrlSetData($Label2, "Extracting:  " & $name & ".bz2")

    RunWait('"' & $path_winrar & '"' & ' e ' & $name & '.bz2 ' & '"' & $path_steam & '"')

    Sleep(300)

    FileDelete($name & ".bz2")
    GUICtrlSetData($Progress1, 0)

EndFunc   ;==>_Main

Func _exit()
    Exit
EndFunc   ;==>_exit

Func _Unloze()
    ShellExecute("https://unloze.com/")
EndFunc   ;==>_Unloze