class puppet_master::puppet_36 {
  include apache2

  apt::source { 'puppetlabs':
    location   => 'http://apt.puppetlabs.com',
    repos      => 'main dependencies',
    key        => '4BD6EC30',
    key_server => 'pgp.mit.edu',
  }

  package { 'puppetmaster-passenger':
    ensure      => present,
    configfiles => 'keep',
    require     => Apt::Source['puppetlabs'],
  }

  vcsrepo { 'puppet':
    ensure   => present,
    provider => 'git',
    revision => 'puppet36',
    owner    => puppet,
    group    => puppet,
    source   => 'ssh://git@git.foo.com/home/git/repo/puppet',
    path     => '/etc/puppetmaster',
    require  => Package['puppetmaster-passenger'],
  }

  file { '/etc/apache2/sites-available/puppetmaster':
    ensure  => file,
    owner   => root,
    group   => root,
    mode    => '0644',
    source  => 'puppet:///modules/puppet_master/puppetmaster',
    require => Package['puppetmaster-passenger'],
    notify  => Service['apache2'],
  }

  file { '/etc/apache2/sites-enabled/puppetmaster':
    ensure  => link,
    target  => '../sites-available/puppetmaster',
    require => File['/etc/apache2/sites-available/puppetmaster'],
    notify  => Service['apache2'],
  }
}