libretro-mupen64plus-git

# Maintainer: Thomas Schneider <maxmusterm@gmail.com>
# Contributor: Arkranur

pkgname=libretro-mupen64plus-git
_gitname=mupen64plus-libretro
pkgver=663.6f1f3e9
pkgrel=1
pkgdesc="libretro implementation of mupen64plus with dynarec (even for rpi)"
arch=('i686' 'x86_64' 'arm' 'armv6h')
url="https://github.com/libretro/mupen64plus-libretro"
license=('custom' 'GPL' 'LGPL')
makedepends=('git')
source=("${_gitname}::git://github.com/libretro/${_gitname}.git"
	"https://raw.github.com/libretro/libretro-super/master/dist/info/mupen64plus_libretro.info")

md5sums=('SKIP'
	 '2920c345f26fdcaab821e1aaa2681834')

pkgver() {
  cd "${_gitname}"
  echo $(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}

build() {
  cd "${_gitname}"
  if [ $CARCH == "armv6h" ]; then
  platform=rpi make WITH_DYNAREC=arm #Build for the Raspberry Pi
  elif [ $CARCH == "i686" ]; then
  make WITH_DYNAREC=x86 #Build for the i686 architecture
  else
  make WITH_DYNAREC=$CARCH #Build for the x86_64 or other Arm architectures
  fi
}

package() {
  install -Dm644 "${srcdir}/mupen64plus_libretro.info" "${pkgdir}/usr/lib/libretro/libretro-mupen64plus.info"
  install -Dm644 "${_gitname}/mupen64plus_libretro.so" "${pkgdir}/usr/lib/libretro/libretro-mupen64plus.so"
}