$puts(COLOR1,$if($or(%el_isplaying%,%el_selected%),
    %LIGHT.COLOR.1%,
    %DARK.COLOR.1%
))
$puts(COLOR2,$if($or(%el_isplaying%,%el_selected%),
    %LIGHT.COLOR.2%,
    %DARK.COLOR.2%
))
$puts(COLOR3,$if($or(%el_isplaying%,%el_selected%),
    %LIGHT.COLOR.3%,
    %DARK.COLOR.3%
))

//-------------- selected bg
$if(%el_selected%,
    $drawroundrect($sub(%TRACK.MARGIN%,$div(%ART.MARGIN%,2)),-1,%el_width%,$sub(%el_height%,1),3,3,%LINE.COLOR.1%-100,,)
,)

//--------------track ind
$drawtext($if(%ispaused%,||,$if(%isplaying%,>>,$if2(+%queue_index%,$if2($ifgreater(%discnumber%,1,[%discnumber%.],)[%tracknumber%],$add(%el_item_index%,1))))),$add(%TRACK.MARGIN%,4),0,24,%el_height%,$get(COLOR1),right vcenter mempos)

//-------------- track information
$drawtextex(%title%,$add(%TRACK.MARGIN%,38),0,
 $sub(%el_width%,$add(%TRACK.MARGIN%,114)),%el_height%,$get(COLOR2),vcenter end_ellipsis)

//Non Grouped Views
$if($strstr(%el_preset_name%,'/')
,,
$drawtextex(%album_format%,$add(%TRACK.MARGIN%,$gettextwidth([%title%]%feat_format%),38),0,
    $sub(%el_width%,$add(%TRACK.MARGIN%,$gettextwidth([%title%]%feat_format%),114)),%el_height%,$get(COLOR1),vcenter end_ellipsis)
)

//Title + feat artist
$drawtextex(%feat_format%,$add(%TRACK.MARGIN%,$gettextwidth([%title%]),38),0,
    $sub(%el_width%,$add(%TRACK.MARGIN%,$gettextwidth([%title%]),114)),%el_height%,$get(COLOR3),vcenter end_ellipsis)

//-------------- play count
$if(%HTTP.CHECK%,,
    $ifgreater(%LASTFM_PLAYCOUNT_DB%,0,
        $drawtext(%LASTFM_PLAYCOUNT_DB%,-45,0,,%el_height%,$get(COLOR1),vcenter right)
    ,)
)

//-------------- track length
$if(%el_isplaying%,,
    $drawtext(%length%,0,0,,%el_height%,$get(COLOR3),vcenter right)
)

$font(ProfontWindows,10,)
//-------------- rating
$ifequal(%rating%,5,
    $drawtextex(♪,-65,-1,,%el_height%,$get(COLOR2),vcenter right)
,)

//-------------- album art
$if($strstr(%el_preset_name%,'/'),
$ifequal(%ALBUM.ART%,0,,
    $enabledraw(1)
    $setworldtransform(2)

    $imageabs(%ART.MARGIN%,0,%ART.SIZE%,%ART.SIZE%,%el_group_first_path%,
        artreader $ifgreater(%ART.KEEPASPECTRATIO%,0,,nokeepaspect),,%ART.OPACITY%)

    $ifequal(%ART.REFLECTION%,0,,
        $imageabs(%ART.MARGIN%,%ART.SIZE%,%ART.SIZE%,%ART.SIZE%,%el_group_first_path%,
            artreader $ifgreater(%ART.KEEPASPECTRATIO%,0,,nokeepaspect),6,%ART.OPACITY%)
        $gradientrect(%ART.MARGIN%,%ART.SIZE%,%ART.SIZE%,$div(%ART.SIZE%,2),27-27-27-144,27-27-27)
        $drawrect(%ART.MARGIN%,$add(%ART.SIZE%,$div(%ART.SIZE%,2)),%ART.SIZE%,$div(%ART.SIZE%,2),27-27-27,,)
    )
))