Respaldo diario OpenERP

@echo off
@mode CON: COLS=170 LINES=65
@color 0A

echo #####################################################
echo # COPIA LOS ERRORES, WARNINGS DEL DIA Y LO EXPORTA  #
echo # COPIA EL LOG DIARIO                               #
echo # RESETEA EL SERVIDOR DE OPENERP                    #
echo #####################################################

echo #
echo # Definimos las variables

SET RUTARESPALDODB="C:\Gestion\RespaldoDB.bat"
SET RUTALOGERP="C:\Gestion\Server\Logs\openerp-server.log"
SET RUTAERROR=C:\Gestion\Logs\Errors\
SET RUTARULESERROR=C:\Gestion\Logs\RulesErrors\
SET RUTALOGS=C:\Gestion\Logs\Diary\
SET RUTAUSRS=C:\Gestion\Logs\Users\

SET FECHA=%date:~-4,4%_%date:~-7,2%_%date:~0,2%
SET LOGERROR="%RUTAERROR%errors_openERP_%FECHA%.log"
SET LOGRULES="%RUTARULESERROR%rules_error_openERP_%FECHA%.log"
SET LOGUSR="%RUTAUSRS%users_login_openERP_%FECHA%.log"
SET LOGINFO=openerp-server-%FECHA%.log
SET LOGCOPIED=%RUTALOGS%openerp-server.log

@ping -n 3 127.0.0.1 > nul
echo # OK. Variables definidas.
echo #

@ping -n 3 127.0.0.1 > nul
echo # Exportando warnings y errores del log...

qgrep -X -O "WARNING ERROR" %RUTALOGERP% > %LOGERROR%

@ping -n 3 127.0.0.1 > nul
echo # OK. Errores exportados.
echo #

@ping -n 3 127.0.0.1 > nul
echo # Exportando usuarios que han hecho login en ERP...

qgrep -X -z "login" %RUTALOGERP% > %LOGUSR%

@ping -n 3 127.0.0.1 > nul
echo # OK. Usuarios logueados exportados.
echo #

@ping -n 3 127.0.0.1 > nul
echo # Exportando errores de reglas desde el log

qgrep -X -z -e "[Alca] Rule Operation" %RUTALOGERP% > %LOGRULES%

@ping -n 3 127.0.0.1 > nul
echo # OK. Reglas erroneas exportadas.
echo #

@ping -n 3 127.0.0.1 > nul
echo # Copiando el fichero de log de hoy...

copy /Y /A %RUTALOGERP% %RUTALOGS%

IF EXIST %RUTALOGS%%LOGINFO% (
@DEL /Q %RUTALOGS%%LOGINFO%
rename %LOGCOPIED% %LOGINFO%
) ELSE (
rename %LOGCOPIED% %LOGINFO%
)


@ping -n 3 127.0.0.1 > nul
echo # OK. El fichero ha sido copiado y renombrado por openerp-server-%FECHA%.log
echo #

@ping -n 3 127.0.0.1 > nul
echo # Reiniciando el servidor de OpenERP y limpiando el log...

echo # Deteniendo el servicio...
@sc stop OpenERP-Service

@ping -n 3 127.0.0.1 > nul
echo # Limpiando el log...

@echo off > %RUTALOGERP%

@ping -n 3 127.0.0.1 > nul
echo # Realizando copia de seguridad de la base de datos
@call %RUTARESPALDODB%
@ping -n 3 127.0.0.1 > nul

@ping -n 3 127.0.0.1 > nul
echo # Iniciando el servicio...

@sc start OpenERP-Service

@ping -n 3 127.0.0.1 > nul
echo # OK. Log limpio y servidor arrancado.
echo #

echo # Esta ventana se cerrara en breves momentos...
@ping -n 6 127.0.0.1 > nul

exit