# Maintainer: Thiago Kenji Okada <thiago DOT mast3r AT gmail DOT com>
# Based on ppsspp-git PKGBUILD from  Clement Guerin <geecko.dev@free.fr>
# and with Qt build instructions from here:
# https://github.com/hrydgard/ppsspp/issues/4449

pkgname=ppsspp-qt-git
pkgver=v0.9.5.r584.g16509ba
pkgrel=1
pkgdesc="A PSP emulator for Android, Windows, Mac, and Linux, written in C++ \
    with Qt UI."
arch=('i686' 'x86_64')
url="http://www.ppsspp.org/"
license=('GPL2')
depends=('qt4' 'sdl')
makedepends=('git' 'gcc')
optdepends=()
provides=('ppsspp')
source=('ppsspp::git://github.com/hrydgard/ppsspp.git#branch=master'
'ppsspp.desktop')
md5sums=('SKIP'
'7639cf40707503cfab0c51e566e92ad1')

pkgver() {
    cd "$srcdir/ppsspp"
    git describe --long | sed -E 's/([^-]*-g)/r\1/;s/-/./g'
}

build() {
    cd $srcdir/ppsspp

    git submodule update --init

    export LDFLAGS="-lavutil -lavformat -lavcodec -lswscale -lswresample"

    mkdir build
    pushd build
    qmake-qt4 ../Qt/PPSSPPQt.pro
    make
    popd
}

package() {
    cd $pkgdir

    install -Dm755 $srcdir/ppsspp/build/PPSSPPQt \
        $pkgdir/usr/bin/PPSSPPQt
    install -Dm644 $srcdir/ppsspp/assets/icon.svg \
        $pkgdir/usr/share/pixmaps/ppsspp.svg
    install -Dm644 $srcdir/ppsspp.desktop \
        $pkgdir/usr/share/applications/ppsspp.desktop
}

# vim: tabstop=8 expandtab shiftwidth=4 softtabstop=4