svg2tikz-git PKGBUILD

# Maintainer: Stefan Husmann <stefan-husmann@t-online.de>
# Contributor: max_meyer <dev@fedux.org>

pkgname=svg2tikz-git
pkgver=r197.e8a16de
pkgrel=1
pkgdesc="An Inkscape extension for exporting SVG paths as TikZ/PGF paths."
arch=('any')
url="https://github.com/kjellmf/svg2tikz"
license=('GPL')
depends=('python2-lxml')
optdepends=('inkscape: for using the inksape extension files')
makedepends=('git')
provides=('inkscape-tikz')
conflicts=('inkscape-tikz')
source=('svg2tikz::git+https://github.com/kjellmf/svg2tikz.git')
md5sums=('SKIP')

pkgver() {
  cd "$srcdir/svg2tikz"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

prepare() {
  cd "$srcdir/svg2tikz"

  for _i in inkexlib/inkex.py inkexlib/simplepath.py inkexlib/simplestyle.py \
    extensions/tikz_export.py extensions/tikz_export.py
  do
    sed -i '1s+python+python2+' svg2tikz/${_i}
  done
}

package() {
  cd "$srcdir/svg2tikz"
  python2 setup.py install --root="$pkgdir/" --optimize=1

  _inkscape_ext="$pkgdir/usr/share/inkscape/extensions"
  install -d "$_inkscape_ext"
  cp ./svg2tikz/extensions/tikz_export* "$_inkscape_ext"
}