@echo off

REM *************************
REM *Contador de Directorios*
REM *************************
set contador=1
dir E:\ /B > C:\Users\%USERNAME%\dirs.txt
for /F %%i IN (C:\Users\%USERNAME%\dirs.txt) DO (
 set /A contador+=1
 )

REM ************************
REM *Creador de Directorios*
REM ************************
set dd=%Date:~0,2%
set mm=%Date:~3,2%
set yyyy=%Date:~6,4%
set fecha=%dd%-%mm%-%yyyy%
md E:\[0%contador%]_[%fecha%]_[Incremental]

REM ********************
REM *Copia de Seguridad*
REM ********************
xcopy C:\DATOS\* E:\[0%contador%]_[%fecha%]_[Incremental]\*.* /M /E /Q /H /K

IF ERRORLEVEL 5 goto error
IF ERRORLEVEL 4 goto memoria
IF ERRORLEVEL 2 goto pausado
IF ERRORLEVEL 1 goto vacio
IF ERRORLEVEL 0 goto correcto


:error
echo [Incremental] A %DATE%, a las %TIME%, hubo un error de escritura en disco. >> C:\copia_seguridad.log
goto fin

:memoria
echo [Incremental] A %DATE%, a las %TIME%, No había suficiente memoria o espacio de disco. >> C:\copia_seguridad.log
goto fin

:pausado
echo [Incremental] A %DATE%, a las %TIME%, alguien pauso la copia pulsando CTRL+C >> C:\copia_seguridad.log
goto fin

:vacio
echo [Incremental] A %DATE%, a las %TIME%, no habia nada que copiar. >> C:\copia_seguridad.log
goto fin

:correcto
echo [Incremental] A %DATE%, a las %TIME%, la copia se realizo correctamente. >> C:\copia_seguridad.log

:fin