nsis_build_src.cmd

@echo off
setlocal ENABLEEXTENSIONS DISABLEDELAYEDEXPANSION
if "%ZLIB_W32%"=="" set ZLIB_W32=C:\Temp\zlib-1.2.4
if "%scons%"=="" set scons=scons
if not defined BNSIS_PREFIX for %%A in (".\..\nsis-locinst") DO set BNSIS_PREFIX=%%~fA

set SkipP_VP=VPatch/Source/Plugin
set SkipU_VP=VPatch/Source/GenPat
set SkipU_LibLoc=Library/LibraryLocal
set SkipM_Langs="Language files"

if "%~1"=="/?" (
    echo.
    echo.Variables:
    echo.set BNSIS_VER=maj.min.rev.bld
    echo.
    echo.Parameters:
    echo.   [UNICODE=yes] [SKIPDOC=all ^| CHMDOCS=yes] [SKIPPLUGINS=...] [SKIPMISC=...] [NSIS_CONFIG_LOG=yes]
    @GOTO:EOF
)

if "%BNSIS_VER%"=="" (set "BNSIS_VER="&goto _BNSIS_VERCFGEND)
FOR /F "tokens=1-4 delims=." %%A in ("%BNSIS_VER%") DO (
    set VER_MAJOR=%%~A
    set VER_MINOR=%%~B
    set VER_REVISION=%%~C
    set VER_BUILD=%%~D
)
REM set /A _BNSIS_PV=(%VER_MAJOR% * 1000) + %VER_MINOR%
set "BNSIS_VER="
set BNSIS_VERSTR=%VER_MAJOR%.%VER_MINOR%
if "%VER_REVISION%"=="" set VER_REVISION=0
if "%VER_BUILD%"=="" set VER_BUILD=0
if not "%VER_REVISION%%VER_BUILD%"=="00" (
    set BNSIS_VERSTR=%BNSIS_VERSTR%.%VER_REVISION%
    set BNSIS_VER=%BNSIS_VER% VER_REVISION=%VER_REVISION%
)
if not "%VER_BUILD%"=="0" (
    set BNSIS_VERSTR=%BNSIS_VERSTR%.%VER_BUILD%
    set BNSIS_VER=%BNSIS_VER% VER_BUILD=%VER_BUILD%
)
set BNSIS_VER=VER_MAJOR=%VER_MAJOR% VER_MINOR=%VER_MINOR% %BNSIS_VER%VERSION=%BNSIS_VERSTR%
echo.Version: %BNSIS_VER%
:_BNSIS_VERCFGEND

call "%scons%" %BNSIS_VER% PREFIX="%BNSIS_PREFIX%" %* install

@GOTO:EOF