@echo off
:begin
cd %appdata%\Spotify\Apps
cls
echo --------------------------------------------
echo Spotify Color Changer
echo --------------------------------------------
echo 1. Extract
echo 2. Replace Color
echo 3. Repack and Replace Skin
echo 9. Exit
echo --------------------------------------------
set /P choice="Enter a choice: "
for %%I in (1 2 3 9 ) do if #%choice%==#%%I goto c%%I
goto begin


:c1
ren *.spa *.zip
FOR %%X in (*.zip) DO (
            "C:\Program Files\7-zip\7z.exe" x -o"%%~dpnX" "%%~fX" -y
        )
ren *.zip *.spa
goto begin

:c2
echo.
echo Type module(s) you want to change. Example: artist, profile, radio, share
echo Type * to select all modules.
set /p folder="Input: "
echo.
echo Enter color you want to change. Example: #1122ff
set /P oldcolor="Old color: "
set /P newcolor="New color: "
echo.

FOR /D %%f IN (%folder%) do (
	cd %%f
	echo --- %%f
	FOR /R %%g IN (*.css) do (
		echo Replacing %%g
		type %%g |..\repl "%oldcolor%" "%newcolor%" LI > "%%g.new"
		move /y "%%g.new" "%%g" >nul
	)
	cd ..
)
goto begin

:c3
del *.spa
for /d %%X in (*) do "c:\Program Files\7-Zip\7z.exe" a "%%X.zip" "%%X\."
ren *.zip *.spa
goto begin

:c9
goto :EOF