set RAVAROR;
set PRODUKTER;
set KEMIKALIER;

param T;

param Tillgang{RAVAROR};
param FPris{PRODUKTER};
param LKost{PRODUKTER};
param CentrifugTid{PRODUKTER};
param InitLager{PRODUKTER};
param TotalCentrifugTid{1..T};
param MinEfterfragan{PRODUKTER, 1..T};
param IKost{RAVAROR, 1..T};
param Konc{RAVAROR, KEMIKALIER};
param KoncKrav{PRODUKTER, KEMIKALIER};


#Variabler

var x{RAVAROR, PRODUKTER, 1..T} >=0;
var y{PRODUKTER, 1..T} >=0;
var w{PRODUKTER, 1..T} >=0;
var l{PRODUKTER, 0..T} >=0;

#Målfuktion

maximize z: sum{j in PRODUKTER} (sum{t in 1..T} (FPris[j]*y[j,t] - LKost[j]*l[j,t] - sum{i in RAVAROR} IKost[i,t]*x[i,j,t]));

#Bivillkor

subject to 	Koncentrationsvillkor{t in 1..T, k in KEMIKALIER,j in PRODUKTER}: 	sum{i in RAVAROR} Konc[i,k]*x[i,j,t] >= KoncKrav[j,k]*w[j,t];
		Tillgangsvillor{i in RAVAROR}:		 				sum{j in PRODUKTER, t in 1..T} x[i,j,t] <= Tillgang[i];
		Centrifugeringsvillkor{t in 1..T}: 					sum{j in PRODUKTER} w[j,t]*CentrifugTid[j] <= TotalCentrifugTid[t];
		Efterfragansvillkor{j in PRODUKTER, t in 1..T}: 			MinEfterfragan[j,t] <= y[j,t];
		InitLagervillkor{j in PRODUKTER}: 					InitLager[j] = l[j,0];
		Lagervillkor{j in PRODUKTER, t in 1..T}: 				l[j,t-1] + w[j,t] - y[j,t] = l[j,t];
		Produktionsvillor{j in PRODUKTER, t in 1..T}:				sum{i in RAVAROR} x[i,j,t] = w[j,t];