scn ALBCovertActionScript

float CourierDay
float DecisionDay
float fQuestDelayTime

ref Adventurer

short DoOnce
short IgnoredCourier
short IgnoredShaman

Begin GameMode
	if( GetGameLoaded || GetGameRestarted )
		if( GetStage ALBCovertAction < 15 )
			SetModelPath "Arthmoor\null.nif" Broadsheet01Assassination
		endif
	endif

	if( (GetPCFame + GetPCInfamy) >= 10 && GetStage ALBCovertAction < 5 )
		setstage ALBCovertAction 5
	endif

	if( GetStage ALBCovertAction == 13 && DoOnce == 0 )
		set DoOnce to 1
		set fQuestDelayTime to 0
		;ALBShamanRef.cast spell on player
		Player.RemoveAllItems ALBPCChestRef
		Player.AddItemNS LowerPants05 1
		Player.AddItemNS LowerShirt05 1
		Player.AddItemNS LowerShoes05 1
		Player.AddItemNS WristIrons 1
		Player.EquipItemNS LowerPants05
		Player.EquipItemNS LowerShirt05
		Player.EquipItemNS LowerShoes05
		Player.EquipItemNS WristIrons
		ALBPCChestRef.additem ALBPrisonDoorKey 1

		Player.MoveTo CGPlayerStartMarker
	endif

	;Ignored the courier dispatch.
	if( CourierDay > 0 && GameDaysPassed >= CourierDay )
		if( Player.GetInCell Kvatch == 0 && Player.GetInCell KR == 0 && Player.GetDistance KvatchEncampmentMarker >= 15000 )
			set Adventurer to ALBBedrollRef.AdvCorpse
			Adventurer.enable
			set IgnoredCourier to 1
			SetStage Charactergen 88
		endif
	endif

	;Blew off the crazy old man.
	if( DecisionDay > 0 && GameDaysPassed >= DecisionDay )
		if( Player.GetInCell Kvatch == 0 && Player.GetInCell KR == 0 && Player.GetDistance KvatchEncampmentMarker >= 15000 )
			set Adventurer to ALBBedrollRef.AdvCorpse
			Adventurer.enable
			set IgnoredShaman to 1
			SetStage Charactergen 88
		endif
	endif

	if( GetStage Charactergen >= 88 ) ;Look at all this junk to set up!
		KRCountsRoomArenar.disable
		KRCountsRoomDummyDoor.enable
		ALBCountGoldwineRef.disable
		KRCampMaster.Enable
		KRKvatchGateOriginal.Enable
		KRKvatchGate05FINAL.Disable
		KRP5FrontChapelDoor.Disable
		KRGuardGateExt1DayRef.Disable
		KRMainExtEnableMaster.disable
		KRMainExtDisableMaster.enable
		MS48GateSpawnMark.enable
		HirtelRef.enable
		HirtelRef.moveto KvatchEncampmentMarker
		MerandilRef.enable
		MerandilRef.moveto MS48IlendBarricadeMarker
		JesanRilianRef.enable
		JesanRilianRef.moveto MS48IlendBarricadeMarker
		SavlianMatiusRef.moveto MS48IlendBarricadeMarker
		TierraRef.enable
		TierraRef.moveto MS48SavlianChapelMark
		BerichInianRef.enable
		BErichInianRef.moveto MS48SavlianChapelMark
		ALBShamanRef.disable
		ALBEmperorRef.disable
		set KRPhaseSwitcher.phasenumber to 0
		stopquest KRWolfsHeadInfo
		SetModelPath "Clutter\Books\Broadsheet01.NIF" Broadsheet01Assassination
		ICPalaceElderCouncilMainDoor.lock 80
		ALBKvatchMapMarker.disable
		ALBKvatchEncampmentMarker.enable
		KRMisc01SavlianStatueRef.enable
		ALBDragonfires.disable

		SetStage ALBCovertAction 30
		StopQuest ALBCovertAction
	endif
End






[[There's also the following:]]
scn ALBCovertActionTriggerScript

Begin OnTrigger Player
	if( Getstage ALBCovertAction == 13 )
		SetStage ALBCovertAction 15
	endif
End