OnPlayerDriveBy

/*
 *
 * KoczkaHUN's OnPlayerDriveBy for SA:MP 0.3d R2 (and newer)
 *
 */

#if defined _KOPDB_included
    #endinput
#endif
#define _KOPDB_included

// --------------------------------------[Defines]---------------------------------------------

forward OnPlayerDriveBy(playerid, victimid, iskill);

#define KOPDB_CallOPTD() \
    CallLocalFunction("KOPDB_OnPlayerTakeDamage", "ddfd", playerid, issuerid, amount, weaponid)

#define KOPDB_CallOPD() \
    CallLocalFunction("KOPDB_OnPlayerDeath", "ddd", playerid, killerid, reason)

// ---------------------------------[Coding from here]-----------------------------------------

new KOPDB_hasOPDB = 0,
    KOPDB_hasOPTD = 0,
    KOPDB_hasOPD = 0;

public OnFilterScriptInit()
{
    KOPDB_hasOPDB = (funcidx("OnPlayerDriveBy") != -1);
    KOPDB_hasOPTD = (funcidx("KOPDB_OnPlayerTakeDamage") != -1);
    KOPDB_hasOPD = (funcidx("KOPDB_OnPlayerDeath") != -1);

    if (funcidx("KOPDB_OnFilterScriptInit") != -1)
        CallLocalFunction("KOPDB_OnFilterScriptInit", "");
}

public OnGameModeInit()
{
    KOPDB_hasOPDB = (funcidx("OnPlayerDriveBy") != -1);
    KOPDB_hasOPTD = (funcidx("KOPDB_OnPlayerTakeDamage") != -1);
    KOPDB_hasOPD = (funcidx("KOPDB_OnPlayerDeath") != -1);

    if (funcidx("KOPDB_OnGameModeInit") != -1)
        CallLocalFunction("KOPDB_OnGameModeInit", "");
}

public OnPlayerTakeDamage(playerid, issuerid, Float:amount, weaponid)
{
    if (issuerid != INVALID_PLAYER_ID && weaponid == WEAPON_VEHICLE && KOPDB_hasOPDB)
        CallLocalFunction("OnPlayerDriveBy", "ddd", issuerid, playerid, 0);

    return (KOPDB_hasOPTD) ? KOPDB_CallOPTD() : 0;
}

public OnPlayerDeath(playerid, killerid, reason)
{
    if (killerid != INVALID_PLAYER_ID && reason == WEAPON_VEHICLE && KOPDB_hasOPDB)
        CallLocalFunction("OnPlayerDriveBy", "ddd", killerid, playerid, 1);

    return (KOPDB_hasOPD) ? KOPDB_CallOPD() : 0;
}

#if defined _ALS_OnPlayerTakeDamage
    #undef OnPlayerTakeDamage
#else
    #define _ALS_OnPlayerTakeDamage
#endif
#define OnPlayerTakeDamage KOPDB_OnPlayerTakeDamage

#if defined _ALS_OnFilterScriptInit
    #undef OnFilterScriptInit
#else
    #define _ALS_OnFilterScriptInit
#endif
#define OnFilterScriptInit KOPDB_OnFilterScriptInit

#if defined _ALS_OnGameModeInit
    #undef OnGameModeInit
#else
    #define _ALS_OnGameModeInit
#endif
#define OnGameModeInit KOPDB_OnGameModeInit

#if defined _ALS_OnPlayerDeath
    #undef OnPlayerDeath
#else
    #define _ALS_OnPlayerDeath
#endif
#define OnPlayerDeath KOPDB_OnPlayerDeath

forward KOPDB_OnPlayerTakeDamage(playerid, issuerid, Float:amount, weaponid);
forward KOPDB_OnFilterScriptInit();
forward KOPDB_OnGameModeInit();
forward KOPDB_OnPlayerDeath(playerid, killerid, reason);