; Nazwa: Glod_v-2.0.4.txt
; Autor: Janusz [Fris] na bazie skryptu Glod Autorstwa: odzi
;---------------------------------------------
; UWAGA !!
; Aby skrypt dzialal musisz miec w jakims otwartym plecaku
; surowke z salaty, ciasteczka, chleb i sok kokosowy
; produkty te MUSZA byc kupione od piekarza miastowego
; --------------------------------------------
; Dodac:
;
; Bledy:
;
;---------------------------------------------
set %klawisz Esc  ;klawisz odpalajacy karmienie postaci
set %AutoJedzenie tak ; nie = jedzenie pod klawiszem;  tak = jedzenie automatyczne
;---------------------------------------------
set %BrakZapisanegoPlecaka 0  ;tego nie zmieniac
set %Motylek 0
;==============================================================
; W nazwie ponizszego katalogu nie moze byc spacji!!!
set *STOP 0
set *WAIT 1
set %Raz 0
set %Katalog C:\  ; miejsce w ktorym beda zapisywane ustawienia plecaka, domyslnie jest to glowny katalog partycji C w indows.
gosub UstalPlecak
event macro 1 0 .glod
wait 5
repeat
    set #lpc 100
    scanjournal 1
    if Czujesz_sie_dobrze in #journal || Moglbys_czuc in #journal || Moglabys_czuc in #journal
       {
        set *STOP 1
        ;1= jesli zostal wlaczony jakis skrypt wspolpracujacy z z tym na glod
        ; skrypt na glod poczeka 6 sekund na zakonczenie akcji innego skryptu.
        set #sysmsgcol 53
        event sysmessage Wcisnij klawisz Esc by nakarmic postac.
        event sysmessage Lub poczekaj na Automatyczne jedzenie.
        set %RepeatTime #scnt + 9
        repeat
           if %RepeatTime < #scnt
           {
              set #sysmsgcol 53
              event sysmessage Wcisnij klawisz Esc by nakarmic postac.
              event sysmessage Lub poczekaj na Automatyczne jedzenie.
              set %RepeatTime #scnt + 9
           }
           onhotkey %klawisz
           {
           set *WAIT 0
           break
           }
           if #backpackid notin %PlecakNaJedzenie
           {
              gosub UkladaniePotraw glodny
           }
        until *WAIT = 0
        set #lpc 10
        gosub SprawdzPotrawy MGG ZBM JGI SLI
        if #RESULT = BrakJedzenia
           halt
        gosub Wcinaj
        if #RESULT = UstawNormalnaPotrawe
        {
            set %Jestem_Wilkolak nie
            gosub Wcinaj
            set %Jestem_Wilkolak tak
        }
        gosub WywalNaczynia
        set *STOP 0
        set *WAIT 1
       }
    set %Raz 0
    if #backpackid notin %PlecakNaJedzenie
    {
       gosub UkladaniePotraw
    }
until #false
;==============================================
sub Wcinaj
  finditem YIP C
  if #findkind <> -1
     {
     set %PotrawaGlod YIP
     set %PotrawaBialko YIP
     set %PotrawaWitaminy YIP
     set %PotrawaWeglowodany YIP
     set %Motylek 1
     }
  else
     {
     set %PotrawaGlod MGG
     set %PotrawaBialko ZBM
     set %PotrawaWitaminy JGI
     set %PotrawaWeglowodany SLI
     set %Motylek 0
     }
  if tak in %Jestem_Wilkolak && %Motylek <> 1
    {
    set %PotrawaGlod VRD
    set %PotrawaBialko VRD
    set %PotrawaWitaminy VRD
    set %PotrawaWeglowodany VRD
    }
  if tak in %Jestem_Wampir && %Motylek <> 1
    {
    set %PotrawaGlod DUF
    set %PotrawaBialko DUF
    set %PotrawaWitaminy DUF
    set %PotrawaWeglowodany DUF
    }
  set %ji #jindex
  event macro 1 0 .glod wszystko
  wait 15
  set %glod 0
  set %bialka 0
  set %witaminy 0
  set %wegle 0
  repeat
     if %ji < #jindex
       {
       set %ji %ji + 1
       scanjournal %ji
       if Glod:_Norma in #journal || Glod:_Niewiele in #journal
          {
          gosub Ugryz %PotrawaGlod ;Chleba
          if Nie_uda_Ci_sie_tego_zjesc in #sysmsg
             return UstawNormalnaPotrawe
          set %ji #jindex
          event macro 1 0 .glod wszystko
          wait 2s
          continue
          }
       if Bialka:_Norma in #journal || Bialka:_Niewiele in #journal
          {
          gosub Ugryz %PotrawaBialko ;Soku Kokosowego
          set %ji #jindex
          event macro 1 0 .glod wszystko
          wait 2s
          continue
          }
       if Witaminy:_Norma in #journal || Witaminy:_Niewiele in #journal
          {
          gosub Ugryz %PotrawaWitaminy ;Surowka z salaty
          set %ji #jindex
          event macro 1 0 .glod wszystko
          wait 2s
          continue
          }
       if Weglowodany:_Norma in #journal || Weglowodany:_Niewiele in #journal
          {
          gosub Ugryz %PotrawaWeglowodany ;Ciasteczek
          set %ji #jindex
          event macro 1 0 .glod wszystko
          wait 2s
          continue
          }
     if Glod:_Optymalne_zaspokojenie in #journal
        set %glod 1
     if Bialka:_Optymalne_Zaspokojenie in #journal
        set %bialko 1
     if Witaminy:_Optymalne_Zaspokojenie in #journal
        set %witaminka 1
     if Weglowodany:_Optymalne_zaspokojenie in #journal
        set %wegle 1
     }
  until %glod = 1 && %bialko = 1 && %witaminka = 1 && %wegle = 1
  gosub WywalNaczynia
  set #sysmsgcol 53
  event sysmessage Postac Najedzona.
return
;-------------------------------------------------------------------
sub Ugryz
  finditem %1 C
  if #findcnt < 1
     {
      event sysmessage Zabraklo jedzenia. Skrypt zatrzymany.
      halt
     }
  set #lobjectid #findid
  event macro 17
  wait 3
return
;-------------------------------------------------------------------
sub SprawdzPotrawy
  finditem YIP C_ , #backpackid
  if #findkind <> -1
  {
     return
  }
  if tak in %Jestem_Wilkolak ;VRD
     {
      finditem VRD C
      if #findcnt = 0 || #findstack < 6
         {
          set #sysmsgcol 1080
          event sysmessage Masz za malo Surowych Zeber w glownym plecaku.
          event sysmessage Skrypt Zatrzymany.
          halt
         }
     }
  if tak in %Jestem_Wampir ;DUF
     {
      finditem DUF C
      if #findstack < 5
         {
          set #sysmsgcol 1080
          event sysmessage Masz za malo Krwi w glownym plecaku.
          event sysmessage Skrypt Zatrzymany.
          halt
         }
      else
         return
     }
  set %CzegosBrakuje 0
  gosub OtworzPlecak %PlecakNaJedzenie
  set #sysmsgcol 1080
  for %i 1 %0
    {
     set %item % . %i
     finditem %item C
     if #findcnt = 0
        {
         if MGG in %item
            event sysmessage Brakuje: Chleba
         if ZBM in %item
            event sysmessage Brakuje: Soku Kokosowego
         if JGI in %item
            event sysmessage Brakuje: Surowki z Salaty
         if SLI in %item
            event sysmessage Brakuje: Ciasteczek
         set %CzegosBrakuje 1
        }
    }
  if %CzegosBrakuje = 1
     return BrakJedzenia
return
;-------------------------------------------------------------------
sub Motylek
  set %JestMotylek 0
  finditem YIP C
  for #findindex 1 #findcnt
    {
    if #findtype = YIP
       {
       set #lobjectid #findid
       set %JestMotylek 1
       event macro 17
       wait 2s
       event macro 1 0 .glod wszystko
       }
    }
  if %JestMotylek = 1
     return UzytoMotylka
return
;-------------------------------------------------------------------
sub WywalNaczynia
  finditem IGI_NQD_WYF C
  for #findindex 1 #findcnt
     {
     exevent drag #findid 1
     wait 5
     exevent dropg #charposx #charposy #charposz
     wait 5
     }
  set %Px %Plecak_X + 100
  set %Py %Plecak_Y + 50
  if #backpackid notin %PlecakNaJedzenie
  {
     click %Px %Py r ;zamknie plecak na potrawy
  }
return
;---------------------------------------------
sub UkladaniePotraw
  if glodny in %1 && %Raz = 0
  {
     set %Komunikat 1
     set %Raz 1
  }
  else
  {
     set %Komunikat 0
  }
  finditem SLI_ZBM_JGI_MGG C_ , #backpackid
  if #findcnt > 0
     {
      set %TypCiasteczka SLI
      set %TypSokKokosowy ZBM
      set %TypSurowka JGI
      set %TypChleb MGG
      ;----
      gosub OtworzPlecak %PlecakNaJedzenie
      gosub PrzezucPrzedmioty %PlecakNaJedzenie %TypCiasteczka 20 20
      gosub PrzezucPrzedmioty %PlecakNaJedzenie %TypSurowka 200 20
      gosub PrzezucPrzedmioty %PlecakNaJedzenie %TypChleb 200 200
      gosub PrzezucPrzedmioty %PlecakNaJedzenie %TypSokKokosowy 20 200
      event sysmessage JEDZENIE PRZEZUCONE.
     }
  else
  {
      return
  }
  if %Komunikat = 1 && %Raz = 1
  {
      set %Raz %Raz + 1
      set #sysmsgcol 53
      event sysmessage Wcisnij klawisz Esc by nakarmic postac.
      event sysmessage Lub poczekaj na Automatyczne jedzenie.
  }
return
;---------------------------------------------
sub OtworzPlecak ; ( id plecaka )
  set %czasPlecaka #scnt2 + 20
  set #lobjectid %1
  event macro 17
  set %PlecakaBrak #scnt + 5
  repeat
    if %czasPlecaka < #scnt2
       {
       set %czasPlecaka #scnt2 + 20
       set #lobjectid %1
       event macro 17
       }
    if %PlecakaBrak < #scnt ; minelo 5 sek i plecak nie zostal otwarty
       {
       set %BrakZapisanegoPlecaka 1
       gosub UstalPlecak
       }
  until %1 in #CONTID
  set %Plecak_X #CONTPOSX
  set %Plecak_Y #CONTPOSY
  wait 3
return
;---------------------------------------------
sub PrzezucPrzedmioty ; ( gdzie przezucac, typ potrawy, x, y )
  finditem %2 C_ , #backpackid
  for #findindex 1 #findcnt
     {
     exevent drag #findid #findstack
     wait 5
     exevent dropc %1 %3 %4
     wait 5
     }
return
;---------------------------------------------
sub UstalPlecak
  set %NazwaPliku Glod_
  set %Plik %Katalog , %NazwaPliku , #charid , .txt
  call %Plik
  ; id plecaka istnieje ale nie udalo sie otworzyc plecaka
  if %BrakZapisanegoPlecaka = 1 || N/A in %PlecakNaJedzenie
     {
     set %BrakZapisanegoPlecaka 1
     gosub Config
     }
  ; id plecaka istnieje i udalo sie otworzyc plecak
  if N/A notin %PlecakNaJedzenie && %BrakZapisanegoPlecaka = 0
     return

  display yesno $-- Ustawianie plecaka na potrawy. -- $Okienkto to pojawiac sie bedzie za kazdym razem, gdy bedziesz mial inny "Plecak na Potrawy" niz ostatnio zapisany. $Wcisniej "Tak" jesli masz plecak lub worek na potrawy w glownym plecaku. $Wcisnij "Nie" jesli chcesz aby "Plecakiem na Potrawy" byl glowny plecak postaci. $Po wcisnieciu Tak pojawi sie celownik, ktory nalezy wycelowac w Plecak na Potrawy.
  if #DISPRES = Yes
     {
      set #targcurs 1
      repeat
         onhotkey Esc
         {
          set #targcurs 1
         }
      until #targcurs = 0
      set %PlecakNaJedzenie #ltargetid
     }
  else
     {
      event sysmessage Potrawy zostana w glownym plecaku.
      set %PlecakNaJedzenie #backpackid
     }
  event sysmessage UWAGA!! NASTAPI ZAPIS DANYCH PLECAKA NA POTRAWY.
  event sysmessage WYSKOCZY OKIENKO.
  wait 2s
  execute cmd.exe /c "del %Plik && echo s , et , #spc , % , PlecakNaJedzenie , #spc , %PlecakNaJedzenie >> %Plik && echo s , et , #spc , % , Jestem_Wilkolak , #spc , %Jestem_Wilkolak >> %Plik && echo s , et , #spc , % , Jestem_Wampir , #spc , %Jestem_Wampir >> %Plik && echo exi , t >> %Plik "
  set %BrakZapisanegoPlecaka 0
return
;---------------------------------------------
sub Config
  set #lpc 2000
  menu clear
  menu window color btnface
  menu window size 210 100
  menu window title Config
  menu font size 8
  menu text mtmiasto 10 1 Wybierz rodzaj postaci.
  menu font size 10
  menu font bgcolor white
  menu combo create mcRodzajPostaci 10 20 190
  menu combo add mcRodzajPostaci Normalna
  menu combo add mcRodzajPostaci Wilkolak
  menu combo add mcRodzajPostaci Wampir
  menu combo select mcRodzajPostaci 1
  menu font style b
  menu font bgcolor btnface
  menu button mbzapisz 70 60 60 24 Zapisz
  menu show
  ;===============================================
  set #lpc 10
  set #menubutton N/A
  repeat
      if #menubutton = mbzapisz
         {
         set #menubutton N/A
         menu get mcRodzajPostaci
         if #menures = 1
            {
            set %Jestem_Wilkolak nie
            set %Jestem_Wampir nie
            }
         if #menures = 2
            {
            set %Jestem_Wilkolak tak
            set %Jestem_Wampir nie
            }
         if #menures = 3
            {
            set %Jestem_Wilkolak nie
            set %Jestem_Wampir tak
            }
         menu hide
         break
         }
      if #menubutton = CLOSED ;wcisnieto przycisk X
        {
        menu hide
        set #menubutton N/A
        Display ok $Informacje o postaci i plecaku na potrawy nie zostaly wprowadzone. $Skrypt wylaczony.
        halt
        }
  until #false
return