kOS Single-Launch Geosynchronous Satellite Network

//kOS Script for Single-Launch Multi-Satellite Geostationary Constellation by kickpuncher (blorgon on KSP forum).

parameter num.      //to run, type 'run scriptName(x)' into terminal. 'x' is number of satellites carried by rocket.
set sats to max(2,num).     //limits *minimum* number of satellites you can launch with this script to two.
set topd to (21549.4 - (21549.4 / sats)).   //takes number of satellites you're launching and figures out how to space them evenly.
set tgain to ((1/topd)^(1/18))^18.  //determines the orbital period that when reached will turn the throttle off. See line 37.
clearscreen.
when stage:liquidfuel < 0.1 then {
    stage.
    wait 3.
    stage.
    return true.
}
when ship:altitude > 70000 then {
    toggle AG10.    //I usually set my payload fairing to action group 10. This will deploy the fairing once out of atmo.
}
set pitch to 90.
lock steering to heading(-90,pitch).
set m to ship:mass.     //lines 19-24 force the rocket to launch at 1.45 TWR, if the rocket is capable of matching or exceeding it.
set w to m * 9.81.
stage.
set t to ship:availablethrust.
set throt to (1.45 * w) / t.
lock throttle to throt.
wait until ship:altitude > 147.     //see 'pfunc' below.
until ship:apoapsis >= 2863330 {
    set pfunc to sqrt(0.170283 * ship:altitude) - 5.    //pitch @ altitude function. Starts at 147m above sea level.
    set pitch to min(180,(90 + pfunc)).     //'min' makes sure that once the rocket is horizontal, it will stay that way.
    set throt to max(0.00005,(-(3.49243713e-7 * ship:apoapsis)^18+1)).  //full throttle til approaching target apo. Graph it to see!
    wait 0.
}
set throt to 0.
wait 1.
warpto(time:seconds + (eta:apoapsis - 40)).     //easy enough, time warps to 40 seconds before apoapsis.
wait 10.        //craft needs to repoint after warping. May have to tweak to work for your craft!
until ship:orbit:period >= topd {       //'topd' is 'target orbital period', and is the GTO period that will space sats evenly.
    set throt to max(0.00005,(-(tgain * ship:orbit:period)^18+1)).      //just another throttle function.
    wait 0.
}
set throt to 0.
toggle AG1.
warpto(time:seconds + 120).     //warps past apoapsis. This is necessary so that you can jettison your first satellite, and run the script that will circularize it into GSO. If you try to run the circularization script right after reaching the transfer orbit, the satellite might not have enough time to reach GSO while still keeping the eccentricity low. Let the satellite carrier warp past apoapsis, and take a full orbit before starting the satellite scripts. See circularization script for more details.
print "Program Ended.".
wait until false.