@echo off
chcp 65001>nul
setlocal enabledelayedexpansion

:defaultconfig
set SVCUTIL="C:\Program Files (x86)\Microsoft SDKs\Windows\v10.0A\bin\NETFX 4.6.1 Tools\SvcUtil.exe"
set OUTDIR=_GISAPI
set LIBDIR=lib


if not exist %OUTDIR% (
    echo Создание каталога %OUTDIR%
    mkdir %OUTDIR%
)

if exist %OUTDIR%\*.* (
    echo Очистка каталога %OUTDIR%
    del /S /Q %OUTDIR%\*.*
)

call :genFile Bills bills
call :genFile CapitalRepair capital-repair
call :genFile DeviceMetering device-metering
::call :genFile Disclosure disclosure
call :genFile Fas fas
call :genFile HouseManagement house-management
call :genFile Infrastructure infrastructure
call :genFile Inspection inspection
call :genFile Licenses licenses
call :genFile Nsi nsi
call :genFile NsiCommon nsi-common
call :genFile OrganizationsRegistry organizations-registry
call :genFile OrganizationsRegistryCommon organizations-registry-common
call :genFile Payment payment
call :genFile Services services
::call :genFile SignatureTest signature-test

:exit
exit /b 0


:genFile
::%1 - ServiceName
::%2 - Service file part name

if exist %2\hcs-%2-service.wsdl (
    %SVCUTIL% %2\hcs-%2-service.wsdl %2\*.xsd %LIBDIR%\*.xsd  /mc /syncOnly /wrapped /directory:%OUTDIR% /noConfig /noLogo /n:*,Gis.%1Service /out:%1Service.cs
)

if exist %2\hcs-%2-service-async.wsdl (
    %SVCUTIL% %2\hcs-%2-service-async.wsdl %2\*.xsd %LIBDIR%\*.xsd  /mc /syncOnly /wrapped /directory:%OUTDIR%\Async /noConfig /noLogo /n:*,Gis.%1Service /out:%1Service.cs
)


exit /b 0




:genFile_old
::%1 - ServiceName
::%2 - Service file part name

if exist hcs-%2-service-?.?.?.?.wsdl (
    %SVCUTIL% hcs-%2-service-?.?.?.?.wsdl *.xsd /mc /syncOnly /wrapped /directory:%OUTDIR% /noConfig /noLogo /n:*,Gis.%1Service /out:%1Service.cs
)

if exist hcs-%2-service-async-?.?.?.?.wsdl (
   %SVCUTIL% hcs-%2-service-async-?.?.?.?.wsdl *.xsd /mc /syncOnly  /wrapped /directory:%OUTDIR%\Async /noConfig /noLogo /n:*,Gis.%1Service.Async /out:%1ServiceAsync.cs
)

if exist hcs-%2-service-??.?.?.?.wsdl (
    %SVCUTIL% hcs-%2-service-??.?.?.?.wsdl *.xsd /mc /syncOnly /wrapped /directory:%OUTDIR% /noConfig /noLogo /n:*,Gis.%1Service /out:%1Service.cs
)

if exist hcs-%2-service-async-??.?.?.?.wsdl (
   %SVCUTIL% hcs-%2-service-async-??.?.?.?.wsdl *.xsd /mc /syncOnly  /wrapped /directory:%OUTDIR%\Async /noConfig /noLogo /n:*,Gis.%1Service.Async /out:%1ServiceAsync.cs
)

exit /b 0