ThiefPop (thief box popping script)

     if_1 goto start
echo Run as .thiefpop CONTAINER WITH BOXES
echo Example : .thiefpop backpack
     exit
start:
     var otherloot scroll|tablet|vellum|sheiska leaf|ostracon|hhr'lav'geluhh bark|papyrus roll|smudged parchment|map|kertig ingot|kertig bar|kertig tear|kertig fist|glaes fragment|glaes shard|glaes ingot|damite lump|damite ingot|damite bar|glaes bar|haralun lump|haralum ingot|haralun bar|animite bar|animite nugget|animite bar|tyrium bar|tyrium nugget|tyrium fragment|tyrium shard|tyrium ingot|silversteel bar|silversteel ingot|silversteel nugget|icesteel bar|icesteel nugget|icesteel ingot
set-triggers:
     action instant setvariable traptype Sleeper;setvariable AOE 0 when Two sets of six pinholes on either side of the
     action instant setvariable traptype Bouncer;setvariable AOE 0 when Connected to the pin is a small shaft that runs downward into a shadow.
     action instant setvariable traptype Curse;setvariable AOE 0 when you notice a small glowing rune hidden
     action instant setvariable traptype Frog;setvariable AOE 0 when with a careful eye, you notice a lumpy green rune hidden inside the
     action instant setvariable traptype Laughing Gass;setvariable AOE 0 when tiny glass tube filled with a black gaseous substance of some sort and a tiny hammer|^That tiny vial filled with a black liquid
     action instant setvariable traptype Mana Drain;setvariable AOE 0 when The seal is covered in strange runes and a glass sphere is embedded within it.
     action instant setvariable traptype Mime;setvariable AOE 0 when A tiny bronze face, Fae in appearance, grins ridiculously from its place on the
     action instant setvariable traptype Shadowling;setvariable AOE 0 when with a careful eye, you notice a small black crystal deep in the shadows of the
     action instant setvariable traptype Acid;setvariable AOE 0 when you notice a tiny hole right next to the lock which looks to be a trap
     action instant setvariable traptype Focused Explosion;setvariable AOE 0 when glistening black square, surrounded by a tight ring
     action instant setvariable traptype Reaper;setvariable AOE 0 when crust-covered black scarab of some unidentifiable substance
     action instant setvariable traptype Crossbow Bolt;setvariable AOE 0 when concealing the points of several wickedly barbed crossbow
     action instant setvariable traptype Poisoned Crossbow Bolt;setvariable AOE 0 when concealing the points of several crossbow bolts glistening
     action instant setvariable traptype Room Explosion;setvariable AOE 1 when Right above the lock inside the keyhole, you see a tiny metal tube just poking out of a small wad of brown clay.
     action instant setvariable traptype Cyanide Dart;setvariable AOE 0 when The glint of silver from the tip of a dart
     action instant setvariable traptype Disease;setvariable AOE 0 when you see what appears to be a small, swollen animal bladder recessed inside
     action instant setvariable traptype Fire Ants;setvariable AOE 0 when bag twitches on occasion, leading you to believe the blade's presence likely to be a very bad
     action instant setvariable traptype Fleas;setvariable AOE 0 when black dots bounce inside, though the lack of transparency makes it impossible
     action instant setvariable traptype Poison Gas;setvariable AOE 1 when notice a vial of lime green liquid just under the
     action instant setvariable traptype Ball Lightning;setvariable AOE 0 when spy what appears to be a pulsating ball with some sort of metal lacing
     action instant setvariable traptype Naphtha Soaker;setvariable AOE 0 when also appears to be a liquid-filled bladder inside
     action instant setvariable traptype Naphtha Fireball;setvariable AOE 1 when to ignite a frighteningly large vial of
     action instant setvariable traptype Body Poison;setvariable AOE 0 when tiny needle with a greenish discoloration on its tip hidden next
     action instant setvariable traptype Nerve Poison;setvariable AOE 0 when tiny needle with a rust colored discoloration on its tip
     action instant setvariable traptype Hand Chopper;setvariable AOE 0 when you notice a glint of razor sharp steel hidden within a suspicious looking seam
     action instant setvariable traptype Shocker;setvariable AOE 0 when two silver studs right below the keyhole which look dangerously out of place
     action instant setvariable traptype Shrapnel;setvariable AOE 1 when packed tightly with a powder around the insides of the
     action instant setvariable traptype Katamba Teleporter;setvariable AOE 0 when thin metal circle that has been lacquered with a shade .* deep ebony
     action instant setvariable traptype Xibar Teleporter;setvariable AOE 0 when thin metal circle that has been lacquered with a shade .* bluish azure
     action instant setvariable traptype Yavash Teleporter;setvariable AOE 0 when thin metal circle that has been lacquered with a shade .* bright crimson
     action instant setvariable danger 1 when manipulation caused something to shift
     action instant setvariable moretraps 1 when not yet fully disarmed
     var glancetrap 0
     action instant setvariable coins 1 when In the .* you see.*(copper|bronze|silver|platinum|gold) coin
     var box-array chest|box|strongbox|caddy|crate|trunk|skippet|casket|coffer
     eval BoxCount count("%box-array","|")
     math BoxCount add 1
     var boxtrack 0
     goto get-box

difficulty-triggers:
     action instant setvariable difficulty 1 when aged grandmother could defeat this trap
     action instant setvariable difficulty 2 when you could do it blindfolded
     action instant setvariable difficulty 3 when trivially constructed gadget which you can take down
     action instant setvariable difficulty 4 when will be a simple matter for you to
     action instant setvariable difficulty 5 when should not take long with your skills
     action instant setvariable difficulty 6 when with only minor troubles
     action instant setvariable difficulty 7 when think this .* is precisely at your skill level
     action instant setvariable difficulty 8 when you've got a good shot at
     action instant setvariable difficulty 9 when odds are against you
     action instant setvariable difficulty 10 when have some chance of being able to
     action instant setvariable difficulty 11 when would be a longshot
     action instant setvariable difficulty 12 when Prayer would be a good start for any attempt of yours at
     action instant setvariable difficulty 13 when have an amazingly minimal chance at
     action instant setvariable difficulty 14 when really don't have any chance at
     action instant setvariable difficulty 15 when probably have the same shot as a snowball does crossing
     action instant setvariable difficulty 16 when just jump off a cliff and save yourself the frustration
     action instant setvariable difficulty 17 when pitiful snowball
     return
remove-difficulty:
     action remove aged grandmother could defeat this trap
     action remove you could do it blindfolded
     action remove trivially constructed gadget which you can take down
     action remove will be a simple matter for you to
     action remove should not take long with your skills
     action remove with only minor troubles
     action remove think this trap is precisely at your skill level
     action remove you've got a good shot at
     action remove odds are against you
     action remove have some chance of being able to
     action remove would be a longshot
     action remove Prayer would be a good start for any attempt of yours at
     action remove have an amazingly minimal chance at
     action remove really don't have any chance at
     action remove probably have the same shot as a snowball does crossing
     action remove just jump off a cliff and save yourself the frustration
     action remove pitiful snowball
     return

get-box:
     eval NextBox element("%box-array", %boxtrack)
getem.p:
     pause 0.5
getem:
put get %NextBox in my %0
     match getem.p type ahead
     match getem.p ...wait
     match next-box could not find
     match next-box What were you
     match Didentify You get
     matchwait
next-box:
     math boxtrack add 1
     if %boxtrack = %BoxCount then goto done
     goto get-box

Didentify.p:
     pause 0.5
Didentify:
     var AOE 0
     var moon 0
     var difficulty 0
     var traptype Unknown
     gosub glance-box
     if %glancetrap = 0 then goto Pidentify
put #statusbar Box Type : $righthandnoun - Trap Type : %traptype
     gosub difficulty-triggers
put disarm my $righthandnoun id
     matchre Didentify.p (type ahead|\.\.\.wait)
     match disarm Somebody has already located and identified the current trap
     match disarm Roundtime
     matchwait

disarm.p:
     pause 0.5
disarm:
     gosub remove-difficulty
     if %AOE = 1 then put #statusbar Box Type : $righthandnoun - Trap Type : %traptype [ AOE TRAP! ] - Difficulty : %difficulty
     if %AOE = 0 then put #statusbar Box Type : $righthandnoun - Trap Type : %traptype - Difficulty : %difficulty
     if %AOE = 1 then setvariable difficulty 11
     if "%traptype" = "Yavash Teleporter" then setvariable difficulty 11
     if "%traptype" = "Xibar Teleporter" then setvariable difficulty 11
     if "%traptype" = "Katamba Teleporter" then setvariable difficulty 11
     if %danger = 1 then var difficulty 17
     var danger 0
     if %difficulty < 4 then put disarm my $righthandnoun blind
     if %difficulty < 7 then if %difficulty > 3 then put disarm my $righthandnoun quick
     if %difficulty > 6 then if %difficulty < 11 then put disarm my $righthandnoun
     if %difficulty > 10 then put disarm my $righthandnoun careful
     var moretraps 0
     matchre disarm.p (type ahead|\.\.\.wait)
     match disarm-fail work with the trap for a while but are unable to make any progress
     match analyze Roundtime
     matchwait

disarm-fail:
     math difficulty add 1
     goto disarm


analyze.p:
     pause 0.5
analyze:
put disarm my $righthandnoun analyze
     matchre analyze.p (type ahead|\.\.\.wait)
     match analyze.p unable to determine a proper method of extracting
     match pick-check previous trap have already been completely harvested
     match pick-check possibly analyze
     matchre harvest (already analyzed this trap in preparation for harvesting|Roundtime)
     matchwait

harvest.p:
     pause 0.5
harvest:
put disarm my $righthandnoun harvest
     matchre harvest.p (type ahead|\.\.\.wait)
     match harvest.p You fumble
     matchre pick-check (Your inept fumbling|It appears that|mangled remnants|remnants of this|previous trap have already been completely harvested|will need to analyze)
     match pick-check Roundtime
     matchwait


pick-check:
     gosub verb stow left
     if %moretraps = 1 then goto Didentify
     goto Pidentify
glance-box.p:
     pause 0.5
glance-box:
put glance my $righthandnoun
     matchre glance-box.p (type ahead|\.\.\.wait)
     matchre glance-trap looks like there are (\d+) trap
     matchre glance-trap looks like there is (\d+) trap
     match glance-notrap there are no traps left
     matchwait
glance-trap:
     var glancetrap 1
     return
glance-notrap:
     var glancetrap 0
     return

Pidentify.p:
     pause 0.5
Pidentify:
     var difficulty 0
     if "%guild" = "Thief" then gosub glance-box
     gosub difficulty-triggers
put pick my $righthandnoun id
     matchre Pidentify.p (type ahead|\.\.\.wait)
     match pick Roundtime
     match pick Somebody has already inspected the current
     matchwait

pick.p:
     pause 0.5
pick:
     gosub remove-difficulty
     if %difficulty < 4 then put pick my $righthandnoun blind
     if %difficulty < 7 then if %difficulty > 3 then put pick my $righthandnoun quick
     if %difficulty > 6 then if %difficulty < 11 then put pick my $righthandnoun
     if %difficulty > 10 then put pick my $righthandnoun careful
     var moretraps 0
     matchre disarm.p (type ahead|\.\.\.wait)
     match pick-fail unable to make any progress
     match Pidentify discover another lock protecting
     match check-open Roundtime
     matchwait
pick-fail:
     math difficulty add 1
     goto pick
check-open:
     var coins 0
     gosub verb open my $righthandnoun
     gosub verb fill my gem pouch with my $righthandnoun
     if %coins = 1 then gosub coins
     gosub verb dismantle my $righthandnoun thump
     pause 0.1
     if matchre("$roomobjs","%otherloot") then gosub verb stow $1
     if matchre("$roomobjs","%otherloot") then gosub verb stow $1
     if matchre("$roomobjs","%otherloot") then gosub verb stow $1
     gosub verb fix my lockpick ring
     goto get-box

coins.p:
     pause 0.5
coins:
put get coin in my $righthandnoun
     match coins.p type ahead
     match coins.p ...wait
     match coins You pick up
     match coins.d could not find
     match coins.d What were you
     matchwait
coins.d:
     return

verb:
     setvariable verb $0
     goto verb.a
verb.p:
     pause 0.5
verb.a:
     pause 0.1
put %verb
     match verb.p type ahead
     match verb.p ...wait
     match verb.p can't do that while entangled in a web
     match verb.p perhaps try doing that again
     matchre verb.p You can not dismantle .* while there is something inside it
     matchre verb.d (There aren't any|You open|You sit|You already have|You coil|You uncoil|You're already using|inherently stealthy endeavor|transaction that small isn't worth|You don't have that many|You hand your|You burst from hiding|DANCE|You untie and pull|You carefully thread|You see no thread|You are already|You drop|Swan|Human boy|You find a hole|You slide|You work|You loosen|You strap|You slip|You pull|That area is not bleeding|You take|could not find what|You strain, but cannot focus your mind|You attempt to relax your mind|You get|You put|STOW HELP|You push|think pushing that would have any effect|You move|You're already using the Sight|You have not recovered from your previous use|careful focus, you adjust your eyes to see in shadow as they|You close your eyes, drawing all your thoughts inward|You're not ready to do that again|was just recently mined by someone else|Roundtime|area has already been tended to|work carefully at tending your wound|The spell pattern collapses|You are unable to control|not damaged enough to warrant repair|cannot figure out how to do that|You're not ready to do that|Drink what|What were you referring|You eat|You drink|You stand|Your analysis has revealed no additional resources|You look around, but can't see any place to hide yourself|already hidden|You pick up|You cannot do that while|You turn|already stalking|You attach|You remove)
     matchwait
verb.d:
     return

done:
echo All Popped!
     exit