Jedi Academy Custom Launcher

@ECHO off
TITLE Jedi Academy Launcher

:main
    SETLOCAL
        CALL :getModList
        CALL :displayMenu
        CALL :startGame
    ENDLOCAL
    GOTO main
GOTO :eof

:displayMenu
    ECHO ###################################################
    ECHO #######
    ECHO #######    Jedi Academy  Custom Launcher
    ECHO #######
    ECHO ###################################################
    ECHO #######
    ECHO #######    First thing's first.
    ECHO #######    Which mod would you like to use?
    ECHO #######
    CALL :displayMods
    ECHO #######
    CALL :selectMod
    ECHO #######
    ECHO ###################################################

GOTO :eof

:startGame
    CALL :archiveLogfile
    ECHO #######
    ECHO #######    Game running...
    JAMP +set fs_game %modName%
    ECHO #######
    ECHO #######    Game closed. Hit enter to restart
    PAUSE
    CLS
GOTO :eof

:selectMod
    SET /p selectedId=#######    I want to run the mod with this ID:
    SET modId=-1
    SETLOCAL ENABLEDELAYEDEXPANSION
    FOR %%m IN (%modList%) DO (
        SET /a modId=modId+1
        CALL :setMod !modId! %selectedId% %%m
    )
    ENDLOCAL&SET modName=%selectedMod%
GOTO :eof

:setMod
    IF "%1"=="%2" (
        SET selectedMod=%3
    )
GOTO :eof

:displayMods
    SET modId=-1
    SETLOCAL ENABLEDELAYEDEXPANSION
        FOR %%m IN (%modList%) DO (
            SET /a modId=modId+1
            ECHO ####### !modId! %%m
        )
    ENDLOCAL
GOTO :eof

:getModList
    FOR /D %%D IN (*) DO (
        CALL :addModToList %%D
    )
GOTO :eof

:addModToList
    IF "%1" NEQ "console_logs" (
        SET modList=%modList%%1
    )
GOTO :eof

:archiveLogfile
    SET day=%Date:~0,2%
    SET month=%Date:~3,2%
    SET year=%Date:~8,2%
    SET hour=%time:~0,2%
    SET minute=%time:~3,2%
    SETLOCAL
    IF EXIST %modName%\qconsole.log (
        ECHO Attempting to make a folder to contain today's logfiles...
        MKDIR console_logs\%modName%\%year%\%month%\%day%
        ECHO Renaming your logfile to this precise moment in time...
        RENAME %modName%\qconsole.log %hour%_%minute%.log
        PUSHD %modName%
        ECHO Moving your logfile to GameData\console_logs\%modName%\%year%\%month%\%day%
        MOVE %hour%_%minute%.log ..\console_logs\%modName%\%year%\%month%\%day%
        POPD
    )
    ENDLOCAL
GOTO :eof