Circle Volume Indicator with loop without writes

-- new version at http://pastebin.com/FjTKv05t

-- original & other project files at https://midnighttokerkate.deviantart.com/art/circle-volume-update-257250247
-- how to set it up: http://dl.dropbox.com/u/5812026/VolumeSetup.mov
property previousVolume : -1
property previouslyMuted : false
on run
    tell application "GeekTool Helper"
        set volImageGeeklet to first item of (geeklets whose name is "VolImage")
        set volImageGroup to group "Image"
        set volImageVisible to volImageGroup's visible
    end tell
    set pathName to "/Users/PATH/Documents/Geektool/Circle_VolumeIndicator"
    repeat while volImageVisible
        set rawVolume to output volume of (get volume settings) as integer
        if previousVolume is not equal to rawVolume then
            set previousVolume to rawVolume
            set finalVolume to rawVolume * 16 / 100 + 1 as integer
            updateGeeklet(pathName, finalVolume, volImageGeeklet)
        end if
        set outputMuted to output muted of (get volume settings) as boolean
        if outputMuted then
            if previouslyMuted is not equal to outputMuted then
                set previouslyMuted to outputMuted as boolean
                set finalVolume to 1 as integer
                updateGeeklet(pathName, finalVolume, volImageGeeklet)
            end if
        else
            if previouslyMuted is not equal to outputMuted then
                set previouslyMuted to outputMuted as boolean
                set finalVolume to rawVolume * 16 / 100 + 1 as integer
                updateGeeklet(pathName, finalVolume, volImageGeeklet)
            end if
        end if
        tell application "GeekTool Helper"
            set volImageVisible to volImageGroup's visible
        end tell
        delay 2
    end repeat
end run

on updateGeeklet(pathName, finalVolume, volImageGeeklet)
    set finalVolumeImage to "file://localhost" & pathName & "/Images_White/" & finalVolume & ".png" as text
    tell application "GeekTool Helper"
        set volImageGeeklet's image url to finalVolumeImage
        refresh volImageGeeklet
    end tell
end updateGeeklet