Checkpoint Firewall Rules to HTML

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml"/>


<xsl:variable name="network_objects" select="document('xml/network_objects.xml')/network_objects"/>
<xsl:variable name="services" select="document('xml/services.xml')/services"/>
<xsl:variable name="communities" select="document('xml/communities.xml')/communities"/>

<xsl:key name="x" match="fw_policies/fw_policie/rule/rule/src/members/reference/Name | fw_policies/fw_policie/rule/rule/dst/members/reference/Name" use="."/>


<xsl:template match="/fw_policies/fw_policie">
<style>tr {vertical-align:baseline;} ol{margin-bottom:3px;}</style>
<table cell_padding="3" style="font:menu;border-collapse:collapse;border:1px solid grey;" rules="rows" border="1" width="1600">


<xsl:for-each select="rule/rule">
<tr>
<xsl:if test="disabled='true'">
<xsl:attribute name="style">color:dimgray;font-style:italic;</xsl:attribute>
</xsl:if>

<xsl:choose>
<xsl:when test="Rule_Number">

    <td><xsl:value-of select="Rule_Number"/></td>

    <td>
    <xsl:if test="action/action/Name='drop' or action/action/Name='reject'">
    <xsl:attribute name="style">color:red;</xsl:attribute>
    </xsl:if>
    <xsl:value-of select="action/action/Name"/></td>

    <td>
    <xsl:if test="src/members/reference">
        <ol><xsl:for-each select="src/members/reference"><li><xsl:value-of select="Name"/></li></xsl:for-each></ol>
    </xsl:if>
    <xsl:if test="src/compound/compound">
        <ol><xsl:for-each select="src/compound/compound"><li style="color:blue"><xsl:value-of select="Name"/></li></xsl:for-each></ol>
    </xsl:if>
    </td>

    <td><ol><xsl:for-each select="dst/members/reference"><li><xsl:value-of select="Name"/></li></xsl:for-each></ol></td>

    <td><ol><xsl:for-each select="services/members/reference"><li><xsl:value-of select="Name"/></li></xsl:for-each></ol></td>

    <td><ol><xsl:for-each select="through/members/reference"><li><xsl:value-of select="Name"/></li></xsl:for-each></ol></td>

    <td><ol><xsl:for-each select="install/members/reference"><li><xsl:value-of select="Name"/></li></xsl:for-each></ol></td>

    <td><xsl:value-of select="track/track/Name"/></td>

    <td style="padding-left:10px;border-left:1px solid lightgrey;"><xsl:value-of select="name"/></td>
    <td><small><xsl:value-of select="comments"/></small></td>

</xsl:when>
<xsl:when test="header_text">
        <td colspan="8" style="background-color:#efefef"/>
        <td colspan="2" style="padding-left:10px;background-color:#e0e0e0;border-left:1px solid lightgrey;"><xsl:value-of select="header_text"/></td>

</xsl:when>

<xsl:otherwise></xsl:otherwise>
</xsl:choose>
</tr>
</xsl:for-each>
</table>




<ol style="font:menu">
<xsl:for-each select="rule/rule/src/members/reference/Name | rule/rule/dst/members/reference/Name">

<xsl:sort case-order="upper-first" select="."/>
<xsl:if test="generate-id(.) = generate-id(key('x', .)[1])">
<li>
<xsl:value-of select="."/>
<xsl:text> (</xsl:text>
<xsl:value-of select="count(key('x', .))"/>
<xsl:text>)</xsl:text>

</li>
</xsl:if>

</xsl:for-each>
</ol>






<div style="font:menu;margin-top:100px;border-top:1px solid dimgray;color:dimgray;">Copyright (c) 2011 R. G., Ing. - Advanceded Stylesheets for <a target="_blank" style="text-decoration:underline;color:dimgray;" href="http://www.google.at/search?q=sk30765">Checkpoint Web Visualization Tool (sk30765)</a>.</div>

</xsl:template>


</xsl:stylesheet>