alsa-plugins-1.1.0-2/PKGBUILD

# $Id: PKGBUILD 260280 2016-02-27 14:09:19Z alucryd $
# Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: Daniel Ehlers <danielehlers@mindeye.net>

pkgname=alsa-plugins
pkgver=1.1.0
pkgrel=2
pkgdesc="Extra alsa plugins"
arch=(i686 x86_64)
url="http://www.alsa-project.org"
license=(GPL)
depends=(alsa-lib)
makedepends=(libpulse jack ffmpeg)
optdepends=('libpulse: PulseAudio plugin'
            'jack: Jack plugin'
            'ffmpeg: libavcodec resampling plugin, a52 plugin'
            'libsamplerate: libsamplerate resampling plugin'
            'speex: libspeexdsp resampling plugin')
source=("ftp://ftp.alsa-project.org/pub/plugins/$pkgname-$pkgver.tar.bz2"
        0001-Do-not-use-deprecated-FFmpeg-API.patch)
sha1sums=('1436db17989468d082691b817b338e44ba932c4b'
          '6b032eb20ea1222e78dc862e61e5dad70a8ef2bb')

prepare() {
  cd $pkgname-$pkgver
  patch -p1 < ../0001-Do-not-use-deprecated-FFmpeg-API.patch
  wget 'https://bugs.archlinux.org/index.php?getfile=13911' -O 0002-replace-avcodec_alloc_free_frame.patch
  patch -p1 < 0002-replace-avcodec_alloc_free_frame.patch
}

build() {
  cd $pkgname-$pkgver
  CFLAGS+=' -DHAVE_STDINT_H' # We have issue similar to this one https://code.google.com/p/cantata/issues/detail?id=627
  ./configure --prefix=/usr
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  install -d "$pkgdir/usr/share/doc/$pkgname"
  install -m644 doc/README* doc/*.txt "$pkgdir/usr/share/doc/$pkgname/"
}