Hotfix for UBC.

import minetweaker.item.IItemStack;
var rockTypes = [
    <UndergroundBiomes:igneousStone>,
    <UndergroundBiomes:igneousCobblestone>,
    <UndergroundBiomes:igneousStoneBrick>,
    <UndergroundBiomes:metamorphicStone>,
    <UndergroundBiomes:metamorphicCobblestone>,
    <UndergroundBiomes:metamorphicStoneBrick>,
    <UndergroundBiomes:sedimentaryStone>
] as IItemStack[];
var stairsTypes = [
    <UndergroundBiomes:stairs.tile.igneousStone0>,
    <UndergroundBiomes:stairs.tile.igneousStone1>,
    <UndergroundBiomes:stairs.tile.igneousStone2>,
    <UndergroundBiomes:stairs.tile.igneousStone3>,
    <UndergroundBiomes:stairs.tile.igneousCobblestone0>,
    <UndergroundBiomes:stairs.tile.igneousCobblestone1>,
    <UndergroundBiomes:stairs.tile.igneousCobblestone2>,
    <UndergroundBiomes:stairs.tile.igneousCobblestone3>,
    <UndergroundBiomes:stairs.tile.igneousStoneBrick0>,
    <UndergroundBiomes:stairs.tile.igneousStoneBrick1>,
    <UndergroundBiomes:stairs.tile.igneousStoneBrick2>,
    <UndergroundBiomes:stairs.tile.igneousStoneBrick3>,
    <UndergroundBiomes:stairs.tile.metamorphicStone0>,
    <UndergroundBiomes:stairs.tile.metamorphicStone1>,
    <UndergroundBiomes:stairs.tile.metamorphicStone2>,
    <UndergroundBiomes:stairs.tile.metamorphicStone3>,
    <UndergroundBiomes:stairs.tile.metamorphicCobblestone0>,
    <UndergroundBiomes:stairs.tile.metamorphicCobblestone1>,
    <UndergroundBiomes:stairs.tile.metamorphicCobblestone2>,
    <UndergroundBiomes:stairs.tile.metamorphicCobblestone3>,
    <UndergroundBiomes:stairs.tile.metamorphicStoneBrick0>,
    <UndergroundBiomes:stairs.tile.metamorphicStoneBrick1>,
    <UndergroundBiomes:stairs.tile.metamorphicStoneBrick2>,
    <UndergroundBiomes:stairs.tile.metamorphicStoneBrick3>,
    <UndergroundBiomes:stairs.tile.sedimentaryStone0>,
    <UndergroundBiomes:stairs.tile.sedimentaryStone1>,
    <UndergroundBiomes:stairs.tile.sedimentaryStone2>,
    <UndergroundBiomes:stairs.tile.sedimentaryStone3>
] as IItemStack[];
var buttonTypes = [
    <UndergroundBiomes:button.tile.igneousStone0>,
    <UndergroundBiomes:button.tile.igneousStone1>,
    <UndergroundBiomes:button.tile.igneousStone2>,
    <UndergroundBiomes:button.tile.igneousStone3>,
    <UndergroundBiomes:button.tile.igneousCobblestone0>,
    <UndergroundBiomes:button.tile.igneousCobblestone1>,
    <UndergroundBiomes:button.tile.igneousCobblestone2>,
    <UndergroundBiomes:button.tile.igneousCobblestone3>,
    <UndergroundBiomes:button.tile.igneousStoneBrick0>,
    <UndergroundBiomes:button.tile.igneousStoneBrick1>,
    <UndergroundBiomes:button.tile.igneousStoneBrick2>,
    <UndergroundBiomes:button.tile.igneousStoneBrick3>,
    <UndergroundBiomes:button.tile.metamorphicStone0>,
    <UndergroundBiomes:button.tile.metamorphicStone1>,
    <UndergroundBiomes:button.tile.metamorphicStone2>,
    <UndergroundBiomes:button.tile.metamorphicStone3>,
    <UndergroundBiomes:button.tile.metamorphicCobblestone0>,
    <UndergroundBiomes:button.tile.metamorphicCobblestone1>,
    <UndergroundBiomes:button.tile.metamorphicCobblestone2>,
    <UndergroundBiomes:button.tile.metamorphicCobblestone3>,
    <UndergroundBiomes:button.tile.metamorphicStoneBrick0>,
    <UndergroundBiomes:button.tile.metamorphicStoneBrick1>,
    <UndergroundBiomes:button.tile.metamorphicStoneBrick2>,
    <UndergroundBiomes:button.tile.metamorphicStoneBrick3>,
    <UndergroundBiomes:button.tile.sedimentaryStone0>,
    <UndergroundBiomes:button.tile.sedimentaryStone1>,
    <UndergroundBiomes:button.tile.sedimentaryStone2>,
    <UndergroundBiomes:button.tile.sedimentaryStone3>
] as IItemStack[];
var metadata = [0, 1, 2, 3, 4, 5, 6, 7] as int[];
var prefixes = [0, 0, 1, 1, 2, 2, 3, 3] as int[];
var postfixes = [0, 8, 0, 8, 0, 8, 0, 8] as int[];
for i in metadata
{
    for j, rockType in rockTypes
    {
        var rock = rockType.definition.makeStack(i);
        var prefix = prefixes[i] + j * 4;
        var postfix = postfixes[i];
        var stairs = stairsTypes[prefix].definition.makeStack(postfix);
        var button = buttonTypes[prefix].definition.makeStack(postfix);
        recipes.remove(stairs);
        recipes.addShapedMirrored(stairs * 4, [
            [rock, null, null],
            [rock, rock, null],
            [rock, rock, rock]
        ]);
        recipes.remove(button);
        recipes.removeShapeless(<minecraft:stone_button>, [rock]);
        recipes.addShapeless(button, [rock]);
        recipes.addShapeless(<minecraft:stone_button>, [button]);
    }
}
recipes.addShapeless(<minecraft:stone_button>, [<ore:stone>]);