sflphone-kde-1.2.2.PKGBUILD

# Maintainer: Christoph Wiechert <wio@psitrax.de>
pkgname=sflphone-kde
pkgver=1.2.2
pkgrel=1
pkgdesc="SIP/IAX2 softphone"
url="http://www.sflphone.org"
arch=('x86_64' 'i686')
license=('GPL3')
depends=('kdelibs' 'libpulse' 'gsm>=0.9.7' 'libzrtpcpp' 'log4c' 'check' 'libyaml' 'celt' 'dbus-c++' 'speex' 'libsamplerate' 'kdepimlibs')
makedepends=('autoconf' 'cmake' 'boost' 'automoc4')
conflicts=('sflphone')
source=("https://projects.savoirfairelinux.com/attachments/download/5064/sflphone-${pkgver}.tar.gz")
md5sums=('e9554423e562c168838366974f07acc0')
install="generateStarter.install"
build() {

## pjsip
  cd ${srcdir}/sflphone-${pkgver}/daemon/libs/pjproject-2.0.1
  ./configure --disable-ilbc-codec
  make dep
  make


## daemon
  cd "${srcdir}/sflphone-${pkgver}/daemon"
  ./autogen.sh
  ./configure --prefix="/usr" --disable-ilbc
   make

## KDE client
  cd "${srcdir}/sflphone-${pkgver}/kde"
  sed -i -re 's/^add_subdirectory.*test.*/#\0/' src/CMakeLists.txt
  ./config.sh --prefix="/usr"
   cd build
   make
}

package() {

## daemon
  cd "${srcdir}/sflphone-${pkgver}/daemon"
  make DESTDIR="${pkgdir}" install

## KDE client
  cd "${srcdir}/sflphone-${pkgver}/kde/build"
  make DESTDIR="${pkgdir}" install
}

# vim:set ts=2 sw=2 et: