API tools faq
paste
Advertisement
Guest User

QTGMC 3.33s for avs 2.60

a guest
Jan 18th, 2016
489
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 87.00 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #                    QTGMC 3.33, by Vit, 2012                       #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.33s (mod) 2016 01 19
  16. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  17. #
  18. # v3.33s (mod) 2015 10 23
  19. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  20. #
  21. # v3.33s (mod) 2015 9 10
  22. # - fix Multiple QTGMC Calls
  23. # - others fix
  24. #
  25. # v3.33s (mod) 2015 8 6
  26. # - some changes in bob to speed up
  27. #
  28. # v3.33s (mod) 2015 8 4
  29. # - fix bug in YUY2 with SourceMatch
  30. # - add slice=false to ditherpost to avoid artefacts
  31. #
  32. # v3.33s (mod)
  33. # - fix bob chroma
  34. # - work with new masktool2 for avs 2.60 in YUY2
  35. #
  36. # v3.33d (mod)
  37. # - Added 32 bit precision option through the lsbd (for dfttest) and lsb (mdegrain) options.
  38. # - optimized some mask handling a bit as originally suggested by Vit
  39. # - others
  40. #
  41. # v3.33
  42. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  43. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  44. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  45. # - Minor change to denoising
  46. #
  47. # v3.32
  48. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  49. # - Tweaked vector recalculation for shutter motion blur
  50. # - Changed defaults for TR2 when using source-match
  51. # - Minor bugfix with SLMode/SLRad on pass-through settings
  52. #
  53. # --- REQUIREMENTS ---
  54. #
  55. # Input colorspaces: YV12, YUY2
  56. #
  57. # Core plugins:
  58. #   MVTools2 (2.6.0.5 or above)
  59. #   MaskTools v2 (recommend 2.0a48 or above)
  60. #   NNEDI3 (recommend 0.9.4 or above for speed)
  61. #   RemoveGrain + Repair (several versions of this plugin, use the SSE2 dlls from the file called "RemoveGrain-1.0.rar". Don't use the SSE3 versions )
  62. #   SSE2Tools for YUY2 support (from the earlier 0.9 version of RemoveGrain, use only SSE2Tools.dll from this version. Don't use the SSE3 version)
  63. #
  64. # Additional plugins:
  65. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  66. #   Yadif - for Preset="Ultra Fast" or if selected directly (cannot be autoloaded, must be loaded in the calling script)
  67. #   VerticalCleaner - for SVThin or Lossless modes
  68. #   FFT3DFilter - if selected for noise processing
  69. #   dfttest - if selected for noise processing
  70. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  71. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  72. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  73.  
  74.  
  75. # --- GETTING STARTED ---
  76. #
  77. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  78. # To use QTGMC write a script like this:
  79. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  80. #   QTGMC( Preset="Slow" )
  81. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  82. #
  83. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  84. #
  85. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  86. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  87. # The default preset is "Slower"
  88. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  89. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  90. #
  91. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  92. #   QTGMC( Preset="Slow", ShowSettings=true )
  93.  
  94.  
  95. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  96.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  97.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  98.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  99.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  100.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  101.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  102.                     int "DftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  103.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  104.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  105.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  106.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", bool "lsbd", bool "lsb" )
  107. {
  108.     # The preset "Ultra Fast" & EdiMode="RepYadif"/"Yadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  109.     # To have this script load Yadif put it's full path in string below (e.g. "C:\Plugins\Yadif.dll"). Use empty string ("") if calling script will load Yadif
  110.     YadifPath = "" # Or just enter "yadif.dll" if Yadif is placed in the system path (e.g. windows\system32)
  111.  
  112.     # Temporary Warnings
  113.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  114.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  115.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  116.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  117.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  118.  
  119.     #---------------------------------------
  120.     # Presets
  121. lsbd=default(lsbd, false)
  122. lsb=default(lsb, false)
  123.     # Select presets / tuning
  124.     Preset = default( Preset, "Slower" )
  125.     pNum = (Preset == "Placebo"   ) ? 0 : \
  126.            (Preset == "Very Slow" ) ? 1 : \
  127.            (Preset == "Slower"    ) ? 2 : \
  128.            (Preset == "Slow"      ) ? 3 : \
  129.            (Preset == "Medium"    ) ? 4 : \
  130.            (Preset == "Fast"      ) ? 5 : \
  131.            (Preset == "Faster"    ) ? 6 : \
  132.            (Preset == "Very Fast" ) ? 7 : \
  133.            (Preset == "Super Fast") ? 8 : \
  134.            (Preset == "Ultra Fast") ? 9 : \
  135.            (Preset == "Draft"     ) ? 10 : 11
  136.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  137.  
  138.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  139.              (MatchPreset == "Placebo"   ) ? 0 : \
  140.              (MatchPreset == "Very Slow" ) ? 1 : \
  141.              (MatchPreset == "Slower"    ) ? 2 : \
  142.              (MatchPreset == "Slow"      ) ? 3 : \
  143.              (MatchPreset == "Medium"    ) ? 4 : \
  144.              (MatchPreset == "Fast"      ) ? 5 : \
  145.              (MatchPreset == "Faster"    ) ? 6 : \
  146.              (MatchPreset == "Very Fast" ) ? 7 : \
  147.              (MatchPreset == "Super Fast") ? 8 : \
  148.              (MatchPreset == "Ultra Fast") ? 9 : \
  149.              (MatchPreset == "Draft"     ) ? 10 : 11
  150.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  151.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  152.  
  153.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  154.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  155.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  156.              (MatchPreset2 == "Slower"    ) ? 2 : \
  157.              (MatchPreset2 == "Slow"      ) ? 3 : \
  158.              (MatchPreset2 == "Medium"    ) ? 4 : \
  159.              (MatchPreset2 == "Fast"      ) ? 5 : \
  160.              (MatchPreset2 == "Faster"    ) ? 6 : \
  161.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  162.              (MatchPreset2 == "Super Fast") ? 8 : \
  163.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  164.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  165.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  166.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  167.  
  168.     NoisePreset = default( NoisePreset, "Fast" )
  169.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  170.             (NoisePreset == "Slow"   ) ? 1 : \
  171.             (NoisePreset == "Medium" ) ? 2 : \
  172.             (NoisePreset == "Fast"   ) ? 3 : \
  173.             (NoisePreset == "Faster" ) ? 4 : 5
  174.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  175.  
  176.     Tuning = default( Tuning, "None" )
  177.     tNum = (Tuning == "None"  ) ? 0 : \
  178.            (Tuning == "DV-SD" ) ? 1 : \
  179.            (Tuning == "DV-HD" ) ? 2 : 3
  180.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  181.  
  182.     # Tunings only affect blocksize in this version
  183.     bs = Select( tNum,  16, 16, 32 )
  184.     bs2 = (bs >= 16) ? 32 : bs * 2
  185.  
  186.     #                                                               Very                                                        Very      Super      Ultra
  187.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  188.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         1      ) )
  189.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  190.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  191.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  192.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  193.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  194.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  195.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  196.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  197.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  198.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  199.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  200.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  201.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  202.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  203.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  204.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  205.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  206.     bs = Blocksize
  207.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  208.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  209.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  210.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  211.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  212.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  213.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  214.  
  215.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  216.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  217.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  218.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  219.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  220.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  221.  
  222.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  223.     SourceMatch   = default( SourceMatch, 0 )
  224.     MatchNNSize   = NNSize
  225.     MatchNNeurons = NNeurons
  226.     MatchEdiMaxD  = EdiMaxD
  227.     MatchEdiQual  = EdiQual
  228.  
  229.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  230.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  231.     #                                                                    Very                                                        Very      Super     Ultra
  232.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  233.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  234.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  235.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  236.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  237.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  238.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  239.     MatchEdi = TempEdi
  240.  
  241.     #                                                          Very                                                        Very      Super     Ultra
  242.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  243.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  244.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  245.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  246.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  247.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  248.  
  249.  
  250.     #---------------------------------------
  251.     # Settings
  252.  
  253.     # Core and Interpolation defaults
  254.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  255.     RepChroma  = default( RepChroma,  true )
  256.     EdiThreads = default( EdiThreads, 0    )
  257.     ChromaEdi  = default( ChromaEdi,  ""   )
  258.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  259.     EdiQual    = (EdiMode == "NNEDI3" && EdiQual > 2 ) ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  260.     ((FindStr( EdiMode, "Yadif" ) != 0 || FindStr( MatchEdi, "Yadif" ) != 0 || FindStr( MatchEdi2, "Yadif" ) != 0  ) && YadifPath != "") ? \
  261.         Load_Stdcall_Plugin( YadifPath ) : NOP() # Load Yadif as required
  262.  
  263.     # Source-match / lossless defaults
  264.     MatchTR1     = TR1
  265.     MatchTR2     = default( MatchTR2,     1   )
  266.     MatchEnhance = default( MatchEnhance, 0.5 )
  267.     Lossless     = default( Lossless,     0   )
  268.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  269.  
  270.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  271.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  272.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  273.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  274.     spatialSL  = (SLMode == 1 || SLMode == 3)
  275.     temporalSL = (SLMode == 2 || SLMode == 4)
  276.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  277.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  278.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  279.     Sbb        = (SMode == 0) ? 0 : Sbb
  280.     SOvs       = default( SOvs,   0   )
  281.     SVThin     = default( SVThin, 0.0 )
  282.  
  283.     # Noise processing settings
  284.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  285.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  286.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  287.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  288.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  289.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  290.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  291.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  292.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  293.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  294.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  295.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  296.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  297.     Sigma        = defined(Sigma)       ? Sigma : \
  298.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  299.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  300.     DftThreads   = default( DftThreads, EdiThreads )
  301.     ChromaNoise  = default( ChromaNoise, false )
  302.     ShowNoise    = default( ShowNoise, 0.0 )
  303.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  304.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  305.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  306.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  307.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  308.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  309.     totalRestore = GrainRestore + NoiseRestore
  310.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  311.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  312.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  313.  
  314.     # MVTools settings
  315.     SubPelInterp = default( SubPelInterp, 2     )
  316.     TrueMotion   = default( TrueMotion,   false )
  317.     GlobalMotion = default( GlobalMotion, true  )
  318.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  319.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  320.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  321.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  322.     DCT          = default( DCT,     0          )
  323.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  324.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  325.     ThSCD1       = default( ThSCD1,  180        )
  326.     ThSCD2       = default( ThSCD2,  98         )
  327.  
  328.     # Motion blur settings
  329.     FPSDivisor  = default( FPSDivisor, 1 )
  330.     ShutterBlur = default( ShutterBlur, 0 )
  331.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  332.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  333.     SBlurLimit  = default( SBlurLimit, 4 )
  334.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  335.  
  336.     # Miscellaneous
  337.     InputType      = default( InputType,     0        )
  338.     Border         = default( Border,        false    )
  339.     ShowSettings   = default( ShowSettings,  false    )
  340.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  341.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  342.     ForceTR        = default( ForceTR,       0        )
  343.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  344.     ReuseGlobals   = (PrevGlobals == "Reuse")
  345.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  346.     rgBlur         = (Precise) ? 11 : 12
  347.  
  348.     # Get maximum temporal radius needed
  349.     maxTR = (temporalSL)       ? SLRad : 0
  350.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  351.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  352.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  353.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  354.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  355.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  356.  
  357.  
  358.     #---------------------------------------
  359.     # Pre-Processing
  360.  
  361.     w = Input.Width()
  362.     h = Input.Height()
  363.     yuy2 = Input.IsYUY2()
  364.     epsilon = 0.0001
  365.  
  366.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  367.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  368.  
  369.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  370.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  371.     h = (Border) ? h+8 : h
  372.  
  373.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  374.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  375.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  376.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  377.     vpad = (vpad > 8) ? vpad : 8
  378.  
  379.  
  380.     #---------------------------------------
  381.     # Motion Analysis
  382.  
  383.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  384.     planarClip = yuy2 ? clip.interleaved2planar() : clip
  385.  
  386.     # Bob the input as a starting point for motion search clip
  387.     bobbed = (InputType == 0) ? planarClip.QTGMC_Bob( 0,0.5 ) : \
  388.              (InputType == 1) ? planarClip : \
  389.                                 planarClip.Blur( 0,1 )
  390.  
  391.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  392.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  393.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  394.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  395.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  396.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  397.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  398.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  399.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  400.  
  401.     CMmt = ChromaMotion ? 3   :  1
  402.     CMts = ChromaMotion ? 255 :  0
  403.     CMrg = ChromaMotion ? 12  : -1
  404.  
  405.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  406.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  407.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  408.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  409.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? !yuy2 ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : \
  410.      bobbed.planar2interleaved().TemporalSoften( 1, 255,CMts, 28, 2 ).interleaved2planar() : NOP()  # 0.00  0.33  0.33  0.33  0.00
  411.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? !yuy2 ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : \
  412.      bobbed.planar2interleaved().TemporalSoften( 2, 255,CMts, 28, 2 ).interleaved2planar() : NOP()  # 0.20  0.20  0.20  0.20  0.20
  413.  
  414.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  415.     binomial0 = IsClip(srchClip) ? NOP() : \
  416.                 (TR0 == 0)       ? bobbed : \
  417.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : !yuy2 ? ts1.MergeLuma( bobbed, 0.25 ) : \
  418.                                    ts1.planar2interleaved().MergeLuma( bobbed.planar2interleaved(), 0.25 ).interleaved2planar()) : \
  419.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : !yuy2 ? ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ) : \
  420.                                    ts1.planar2interleaved().MergeLuma( ts2.planar2interleaved(), 0.357 ).MergeLuma( bobbed.planar2interleaved(), 0.125 ).interleaved2planar())
  421.  
  422.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  423.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  424.  
  425.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  426.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  427.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  428.                   (!yuy2 && SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg, planar=true ).BilinearResize( w, h ) : \
  429.                   (!yuy2)                    ? repair0.RemoveGrain( 12,CMrg, planar=true ).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 ) : \
  430.                                                repair0.RemoveGrain( 12,CMrg, planar=true ).planar2interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 ).interleaved2planar()
  431.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  432.     tweluin26 = (!IsClip(srchClip) && SrchClipPP > 1) ? yuy2 ? mt_lutxy( repair0.planar2interleaved().ConvertToYV16(), bobbed.planar2interleaved().ConvertToYV16(), "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ).ConvertToYUY2().interleaved2planar() : nop() : nop()
  433.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? !yuy2 ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : tweluin26 : NOP()
  434.     srchClip    = IsClip(srchClip)  ? srchClip : \
  435.                   (SrchClipPP == 0) ? repair0 : \
  436.                   (SrchClipPP < 3)  ? spatialBlur : \
  437.                                       yuy2 ? spatialBlur.planar2interleaved().ConvertToYV16().mt_lutxy( tweaked.planar2interleaved().ConvertToYV16(), \
  438.     "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt ).ConvertToYUY2().interleaved2planar() : \
  439.     spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  440.     # Calculate forward and backward motion vectors from motion search clip
  441.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  442.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion, planar=true ) : NOP()
  443.     bVec3 = IsClip(bVec3) ? bVec3 : \
  444.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  445.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  446.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  447.     bVec2 = IsClip(bVec2) ? bVec2 : \
  448.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  449.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  450.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  451.     bVec1 = IsClip(bVec1) ? bVec1 : \
  452.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  453.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  454.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  455.     fVec1 = IsClip(fVec1) ? fVec1 : \
  456.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  457.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  458.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  459.     fVec2 = IsClip(fVec2) ? fVec2 : \
  460.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  461.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  462.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  463.     fVec3 = IsClip(fVec3) ? fVec3 : \
  464.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  465.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  466.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  467.  
  468.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  469.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  470.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  471.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  472.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  473.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  474.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  475.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  476.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  477.  
  478.  
  479.     #---------------------------------------
  480.     # Noise Processing
  481.  
  482.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  483.  
  484.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  485.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  486.                 (InputType > 0)     ? clip : \
  487.                                       clip.QTGMC_Bob( 0,1.0 )
  488.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.interleaved2planar() : fullClip
  489.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise, planar=true ) : NOP() #TEST chroma OK?
  490.  
  491.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  492.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  493.                   (!DenoiseMC)        ? fullClip : \
  494.                   (NoiseTR == 0)      ? fullClip : \
  495.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  496.                                                     fullClip, \
  497.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) ) : \
  498.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  499.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  500.                                                     fullClip, \
  501.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ), \
  502.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) )
  503.     noiseWindow = (yuy2 && NoiseTR > 0) ? noiseWindow.planar2interleaved() : noiseWindow
  504.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  505.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=DftThreads, lsb=lsbd ) : \
  506.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD )
  507.     dnwindow = (Denoiser == "dfttest") && lsbd ? yuy2 ? dnWindow.ConvertToYV16().ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false).ConvertToYUY2() : dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  508.  
  509.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  510.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  511.     denoised = (NoiseProcess == 0) ? NOP() : \
  512.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  513.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  514.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  515.  
  516.     # >>>> Switch to planar YUY2 for noise bypass
  517.  
  518.     CNmt1   = ChromaNoise ? 3 : 1
  519.     CNmt2   = ChromaNoise ? 3 : 2
  520.     CNmt128 = ChromaNoise ? 3 : -128
  521.  
  522.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  523.     noise = (totalRestore > 0.0)  ? yuy2 ? mt_makediff( clip.ConvertToYV16(), denoised.ConvertToYV16(), U=CNmt1,V=CNmt1 ).ConvertToYUY2().interleaved2planar() : \
  524.     mt_makediff( Clip, denoised, U=CNmt1,V=CNmt1 ) : NOP()
  525.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  526.                  (InputType != 0)                           ? noise : \
  527.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  528.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  529.                                                               noise.DoubleWeave()
  530.     # Motion-compensated stabilization of generated noise
  531.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise, planar=true ) : NOP()
  532.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  533.     finalNoise = (StabilizeNoise) ? yuy2 ? mt_lutxy( deintNoise.planar2interleaved().ConvertToYV16(), mcNoise.planar2interleaved().ConvertToYV16(), \
  534.                             "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ).ConvertToYUY2().interleaved2planar() : \
  535.                            mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  536.  
  537.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  538.     innerClip = (NoiseProcess == 1) ? denoised : clip
  539.  
  540.  
  541.     #---------------------------------------
  542.     # Interpolation
  543.  
  544.     # >>>> Interleaved YUY2 for interpolation
  545.  
  546.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  547.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  548.  
  549.     # Create interpolated image as starting point for output
  550.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  551.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, \
  552.                                                 yuy2 ? bobbed.planar2interleaved() : bobbed, ChromaEdi )
  553.  
  554.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  555.  
  556.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  557.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask, planar=true ) : NOP()
  558.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.interleaved2planar()) :\
  559.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).interleaved2planar()) : \
  560.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  561.                                                         mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend.planar2interleaved().ConvertToYV16(), U=2,V=2 ).ConvertToYUY2().interleaved2planar())
  562.  
  563.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  564.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  565.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  566.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  567.     tMax     = (temporalSL)              ? yuy2 ? edi.planar2interleaved().ConvertToYV16().mt_logic( fComp1.planar2interleaved().ConvertToYV16(), "max", \
  568.     U=3,V=3 ).mt_logic( bComp1.planar2interleaved().ConvertToYV16(), "max", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  569.     tMin     = (temporalSL)              ? yuy2 ? edi.planar2interleaved().ConvertToYV16().mt_logic( fComp1.planar2interleaved().ConvertToYV16(), "min", \
  570.     U=3,V=3 ).mt_logic( bComp1.planar2interleaved().ConvertToYV16(), "min", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  571.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  572.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  573.     tMax     = (SLRad > 1 && temporalSL) ? yuy2 ? tMax.planar2interleaved().ConvertToYV16().mt_logic( fComp3.planar2interleaved().ConvertToYV16(), "max", \
  574.     U=3,V=3 ).mt_logic( bComp3.planar2interleaved().ConvertToYV16(), "max", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  575.     tMin     = (SLRad > 1 && temporalSL) ? yuy2 ? tMin.planar2interleaved().ConvertToYV16().mt_logic( fComp3.planar2interleaved().ConvertToYV16(), "min", \
  576.     U=3,V=3 ).mt_logic( bComp3.planar2interleaved().ConvertToYV16(), "min", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  577.  
  578.  
  579.     #---------------------------------------
  580.     # Create basic output
  581.  
  582.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  583.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  584.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  585.     # Create linear weightings of neighbors first                                                                                             -2    -1     0    1     2
  586.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  587.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  588.     degrain1 = (TR1 > 0) && lsb ? yuy2 ? degrain1.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : degrain1.ditherpost(mode=6, slice=false) : degrain1
  589.     degrain2 = (TR1 > 1) && lsb ? yuy2 ? degrain2.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : degrain2.ditherpost(mode=6, slice=false) : degrain2
  590.  
  591.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  592.     binomial1 = (TR1 == 0) ? edi : \
  593.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  594.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  595.  
  596.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  597.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  598.  
  599.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  600.     match = (SourceMatch == 0) ? repair1 : \
  601.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  602.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  603.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  604.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  605.  
  606.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  607.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  608.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  609.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  610.  
  611.  
  612.     #---------------------------------------
  613.     # Resharpen / retouch output
  614.  
  615.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  616.     vresharp1 = (SMode == 2) ? yuy2 ? Merge( lossed1.planar2interleaved().ConvertToYV16().mt_expand( mode="vertical", U=3,V=3 ), \
  617.     lossed1.planar2interleaved().ConvertToYV16().mt_inpand( mode="vertical", U=3,V=3 ) ).ConvertToYUY2().interleaved2planar() : \
  618.     Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  619.     vresharp  = (Precise && SMode == 2) ? yuy2 ? vresharp1.planar2interleaved().ConvertToYV16().mt_lutxy( lossed1.planar2interleaved().ConvertToYV16(), \
  620.     "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  621.     resharp   = (SMode == 0) ? lossed1 : \
  622.                 (SMode == 1) ? yuy2 ? lossed1.planar2interleaved().ConvertToYV16().mt_lutxy( lossed1.RemoveGrain( rgBlur, planar=true ).planar2interleaved().ConvertToYV16(),  \
  623.     "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur, planar=true ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  624.                                yuy2 ? lossed1.planar2interleaved().ConvertToYV16().mt_lutxy( vresharp.RemoveGrain( rgBlur, planar=true ).planar2interleaved().ConvertToYV16(), \
  625.     "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur, planar=true ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  626.  
  627.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  628.     SVThinSc = SVThin * 6.0
  629.     vertMedD = (SVthin > 0.0) ? yuy2 ? mt_lutxy( lossed1.planar2interleaved().ConvertToYV16(), lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1, planar=true ).planar2interleaved().ConvertToYV16(), \
  630.     "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ).ConvertToYUY2().interleaved2planar() : mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1, planar=true ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  631.     vertMedD = (SVthin > 0.0) ? (!yuy2 ? vertMedD.Blur( 1,0 ) : vertMedD.planar2interleaved().Blur( 1,0 ).interleaved2planar()) : NOP()
  632.     neighborD = (SVthin > 0.0) ? yuy2 ? mt_lutxy( vertMedD.planar2interleaved().ConvertToYV16(), vertMedD.RemoveGrain( rgBlur,-1, planar=true ).planar2interleaved().ConvertToYV16(), \
  633.     "y 128 - abs x 128 - abs > y 128 ?" ).ConvertToYUY2().interleaved2planar() : mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1, planar=true ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  634.     thin      = (SVthin > 0.0) ? yuy2 ? resharp.planar2interleaved().ConvertToYV16().mt_adddiff( neighborD.planar2interleaved().ConvertToYV16(), U=2,V=2 ).ConvertToYUY2().interleaved2planar() : resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  635.  
  636.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  637.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  638.                  !yuy2 ? thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1, planar=true ) \
  639.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 ) : \
  640.                          thin.planar2interleaved().ConvertToYV16().mt_makediff( mt_makediff( thin.planar2interleaved().ConvertToYV16(), lossed1.planar2interleaved().ConvertToYV16(), U=1,V=1 ).ConvertToYUY2().interleaved2planar().RemoveGrain( 12, -1, planar=true ) \
  641.                              .planar2interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ).ConvertToYV16(), U=2,V=2 ).ConvertToYUY2().interleaved2planar()
  642.  
  643.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  644.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  645.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12, planar=true )), 1, planar=true ) : \
  646.                   (SLMode == 2) ? yuy2 ? backBlend1.planar2interleaved().ConvertToYV16().mt_clamp( tMax.planar2interleaved().ConvertToYV16(),tMin.planar2interleaved().ConvertToYV16(), Sovs,Sovs, U=3,V=3 ).ConvertToYUY2().interleaved2planar() : backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  647.                                   backBlend1
  648.  
  649.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  650.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  651.                  !yuy2     ? sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1, planar=true ) \
  652.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 ) : \
  653.                              sharpLimit1.planar2interleaved().ConvertToYV16().mt_makediff( mt_makediff( sharpLimit1.planar2interleaved().ConvertToYV16(), lossed1.planar2interleaved().ConvertToYV16(), U=1,V=1 ).ConvertToYUY2().interleaved2planar().RemoveGrain( 12, -1, planar=true ) \
  654.                                         .planar2interleaved().GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ).ConvertToYV16(), U=2,V=2 ).ConvertToYUY2().interleaved2planar()
  655.  
  656.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  657.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  658.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  659.         yuy2 ? backBlend2.planar2interleaved().ConvertToYV16().mt_adddiff( finalNoise.planar2interleaved().ConvertToYV16().mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 ).ConvertToYUY2().interleaved2planar() : \
  660.         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  661.  
  662.     # Final light linear temporal smooth for denoising
  663.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  664.     stable  = (TR2 == 0) ? addNoise1 : \
  665.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : \
  666.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : \
  667.                            addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb )
  668.     stable  = (TR2 > 0) && lsb ? yuy2 ? stable.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : stable.ditherpost(mode=6, slice=false) : stable
  669.  
  670.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  671.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  672.  
  673.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  674.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  675.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12, planar=true )), 1, planar=true ) : \
  676.                   (SLMode == 4) ? yuy2 ? repair2.planar2interleaved().ConvertToYV16().mt_clamp( tMax.planar2interleaved().ConvertToYV16(),tMin.planar2interleaved().ConvertToYV16(), Sovs,Sovs, U=3,V=3 ).ConvertToYUY2().interleaved2planar() : repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  677.                                   repair2
  678.  
  679.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  680.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  681.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  682.  
  683.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  684.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  685.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  686.         yuy2 ? lossed2.planar2interleaved().ConvertToYV16().mt_adddiff( finalNoise.planar2interleaved().ConvertToYV16().mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 ).ConvertToYUY2().interleaved2planar() : \
  687.         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  688.  
  689.  
  690.     #---------------------------------------
  691.     # Post-Processing
  692.  
  693.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  694.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  695.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  696.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  697.  
  698.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  699.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  700.     rBlockSize = BlockSize / rBlockDivide
  701.     rOverlap   = Overlap   / rBlockDivide
  702.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  703.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  704.     rBlockDivide = BlockSize / rBlockSize
  705.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  706.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  707.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  708.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  709.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  710.  
  711.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  712.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  713.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true ) : NOP()
  714.  
  715.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  716.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit, planar=true ) : NOP()
  717.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  718.                    (SBlurLimit == 0)  ? sblur : \
  719.                                         yuy2 ? mt_merge( addNoise2.planar2interleaved().ConvertToYV16(), sblur.planar2interleaved().ConvertToYV16(), sbMotionMask.planar2interleaved().ConvertToYV16(), U=3,V=3 ).ConvertToYUY2().interleaved2planar() : \
  720.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  721.     # Reduce frame rate
  722.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  723.  
  724.     # Crop off temporary vertical padding
  725.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  726.     h = Border ? h-8 : h
  727.  
  728.     # Show output of choice + settings
  729.     # >>>> Restore YUY2 to interleaved
  730.     output = (ShowNoise == 0.0) ? cropped : yuy2 ? finalNoise.planar2interleaved().ConvertToYV16().mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 ).ConvertToYUY2().interleaved2planar() : \
  731.     finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  732.     output = yuy2 ? output.planar2interleaved() : output
  733.     return (ShowSettings == false) ? output : \
  734.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  735.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  736.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  737.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  738.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  739.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  740.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  741.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  742.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  743.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  744.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  745.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  746.         Denoiser + "' | DftThreads=" + string(DftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  747.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  748.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  749.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  750.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  751.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  752.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  753.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  754. }
  755.  
  756.  
  757. #---------------------------------------
  758. # Helpers
  759.  
  760. # Same as Bob, but keeps the field order the same.
  761. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  762. {
  763.   h = Default(height, cp.Height)
  764.   w = cp.Width
  765.   shift = GetParity(cp) ? 0.25 : -0.25
  766.  
  767.   yv12c = IsYV12(cp) ? true : false
  768.  
  769.   yv12c ? cp.SeparateFields() : nop()
  770.  
  771.   oeven=yv12c ? SelectEven() : nop()
  772.   oodd=yv12c ? SelectOdd() : nop()
  773.  
  774.   even=yv12c ? oeven.ConvertToY8.BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  775.   odd=yv12c ? oodd.ConvertToY8.BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  776.  
  777.   evenChr=yv12c ? Interleave(oeven.UToY8, oeven.VToY8).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  778.   oddChr=yv12c ? Interleave(oodd.UToY8, oodd.VToY8).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  779.  
  780.   yv12c ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  781.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  782. }
  783.  
  784.  
  785. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  786. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  787. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  788.                             string "ChromaEdi" )
  789. {
  790.     # >>>> YUY2 is interleaved here
  791.  
  792.     ChromaEdi = default( ChromaEdi, "" )
  793.     CEed = (ChromaEdi == "")
  794.  
  795.     interp = (InputType == 1)            ? Input : \
  796.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  797.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  798.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  799.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  800.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  801.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  802.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  803.              (EdiMode == "Yadif")        ? Input.Yadif( mode=3 ) : \
  804.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  805.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).interleaved2planar(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).interleaved2planar(), 2, 0, Planar=true ).planar2interleaved() : \
  806.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  807.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  808.  
  809.     interpuv = (InputType == 1)        ? NOP() : \
  810.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  811.                (ChromaEdi == "Yadif")  ? Input.Yadif( mode=3 ) : \
  812.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  813.                                          NOP()
  814.  
  815.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  816. }
  817.  
  818.  
  819. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  820. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  821. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  822. {
  823.     # >>>> YUY2 is planar here
  824.     mtY =default( Y, 3 )
  825.     mtU =default( U, 1 )
  826.     mtV =default( V, 1 )
  827.     rgY = (mtY == 3) ? 20 : -1
  828.     rgU = (mtU == 3) ? 20 : -1
  829.     rgV = (mtV == 3) ? 20 : -1
  830.     yuy2=Isyuy2(c)
  831.     rg  = c.RemoveGrain( rgY, rgU, rgV, planar=true )
  832.     c   = yuy2 ?  c.planar2interleaved().ConvertToYV16() : c
  833.     rg  = yuy2 ? rg.planar2interleaved().ConvertToYV16() : rg
  834.     yuy2 ? mt_logic( c, rg, "max", Y=mtY,U=mtU,V=mtV ).ConvertToYUY2().interleaved2planar() : mt_logic( c, rg, "max", Y=mtY,U=mtU,V=mtV )
  835. }
  836.  
  837. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  838. {
  839.     # >>>> YUY2 is planar here
  840.     mtY =default( Y, 3 )
  841.     mtU =default( U, 1 )
  842.     mtV =default( V, 1 )
  843.     rgY = (mtY == 3) ? 20 : -1
  844.     rgU = (mtU == 3) ? 20 : -1
  845.     rgV = (mtV == 3) ? 20 : -1
  846.     yuy2=Isyuy2(c)
  847.     rg  = c.RemoveGrain( rgY, rgU, rgV, planar=true )
  848.     c   = yuy2 ?  c.planar2interleaved().ConvertToYV16() : c
  849.     rg  = yuy2 ? rg.planar2interleaved().ConvertToYV16() : rg
  850.     yuy2 ? mt_logic( c, rg, "min", Y=mtY,U=mtU,V=mtV ).ConvertToYUY2().interleaved2planar() : mt_logic( c, rg, "min", Y=mtY,U=mtU,V=mtV )
  851. }
  852.  
  853. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  854. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  855. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  856. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  857. {
  858.     # >>>> YUY2 is planar here
  859.  
  860.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  861.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  862.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  863.     Rep    = default( Rep,    1    )
  864.     Chroma = default( Chroma, true )
  865.     ed = (Rep < 10) ? Rep : Rep / 10
  866.     od = (Rep < 10) ? 0   : Rep % 10
  867.     RCrg  = Chroma ? 3 : 1
  868.     RCrgo = Chroma ? 3 : 2
  869.  
  870.     diff = mt_makediff(Isyuy2(Input) ? Ref.planar2interleaved().ConvertToYV16() : Ref, Isyuy2(Input) ? Input.planar2interleaved().ConvertToYV16() : Input, U=3,V=3 )
  871.  
  872.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  873.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  874.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  875.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  876.     choke1 = Isyv16(choke1) && Isyuy2(Input) ? choke1.ConvertToYUY2().interleaved2planar() : choke1
  877.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  878.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4, planar=true )               : choke1   #      . . x . . x . .    Local median
  879.                                                                                                                      
  880.     choke1 = Isyuy2(choke1) ? choke1.planar2interleaved().ConvertToYV16() : choke1
  881.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  882.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  883.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  884.  
  885.     # Over-dilation - extra reflation up to about 1 pixel
  886.     choke1 = (od == 0)            ? choke1 : \
  887.              (od == 1)            ? Isyv16(choke1) && Isyuy2(Input) ? choke1.ConvertToYUY2().interleaved2planar().QTGMC_inflate( U=RCrg,V=RCrg ).planar2interleaved().ConvertToYV16() : choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  888.              (od == 2)            ? Isyv16(choke1) && Isyuy2(Input) ? choke1.ConvertToYUY2().interleaved2planar().QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ).planar2interleaved().ConvertToYV16() : choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  889.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  890.  
  891.     # Areas of negative difference (similar to above)
  892.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  893.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  894.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  895.     choke2 = Isyv16(choke2) && Isyuy2(Input) ? choke2.ConvertToYUY2().interleaved2planar() : choke2
  896.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  897.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4, planar=true )               : choke2
  898.     choke2 = Isyuy2(choke2) ? choke2.planar2interleaved().ConvertToYV16() : choke2
  899.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  900.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  901.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  902.     choke2 = (od == 0)            ? choke2 : \
  903.              (od == 1)            ? Isyv16(choke2) && Isyuy2(Input) ? choke2.ConvertToYUY2().interleaved2planar().QTGMC_deflate( U=RCrg,V=RCrg ).planar2interleaved().ConvertToYV16() : choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  904.              (od == 2)            ? Isyv16(choke2) && Isyuy2(Input) ? choke2.ConvertToYUY2().interleaved2planar().QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ).planar2interleaved().ConvertToYV16() : choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  905.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  906.  
  907.     # Combine above areas to find those areas of difference to restore
  908.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  909.     fin4ret = Isyuy2(Input) ? Input.planar2interleaved().ConvertToYV16().mt_adddiff( restore, U=RCrgo,V=RCrgo ) : Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  910.     return Isyuy2(Input) ? fin4ret.ConvertToYUY2().interleaved2planar() : fin4ret
  911. }
  912.  
  913.  
  914. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  915. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  916. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  917. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  918. {
  919.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  920.     ChromaNoise = default( ChromaNoise, false )
  921.     CNmt1 = ChromaNoise ? 3 : 1
  922.     origNoise = Input.SeparateFields()
  923.     origNoise = Isyuy2(Input) ? origNoise.planar2interleaved().ConvertToYV16() : origNoise
  924.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  925.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  926.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  927.     random    = InterleavedClip.IsYUY2() ? random.ConvertToYV16() : random
  928.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  929.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  930.     return Isyuy2(Input) ? Interleave( origNoise, newNoise ).ConvertToYUY2().interleaved2planar().Weave() : Interleave( origNoise, newNoise ).Weave()
  931. }
  932.  
  933.  
  934. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  935. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  936. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  937. {
  938.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  939.  
  940.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  941.  
  942.     # Weave the source fields and the "new" fields that have generated in the input
  943.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  944.     srcFields  = Source.IsYUY2() ? srcFields1.interleaved2planar() : srcFields1
  945.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  946.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  947.  
  948.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  949.     vertMedian  = processed.VerticalCleaner( mode=1, planar=true )
  950.     vertMedDiff = mt_makediff( Isyuy2(Source) ? processed.planar2interleaved().ConvertToYV16() : \
  951.     processed, Isyuy2(Source) ? vertMedian.planar2interleaved().ConvertToYV16() : vertMedian, U=3,V=3 )
  952.     vertMedDiff = Isyv16(vertMedDiff) && Isyuy2(Source) ? vertMedDiff.ConvertToYUY2().interleaved2planar() : vertMedDiff
  953.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  954.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1, planar=true )
  955.     vmNewDiff2  = Isyuy2(vmNewDiff2) ? vmNewDiff2.planar2interleaved().ConvertToYV16().mt_lutxy( vmNewDiff1.planar2interleaved().ConvertToYV16(), \
  956.     "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 ) : \
  957.     vmNewDiff2.mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  958.     vmNewDiff2  = Isyv16(vmNewDiff2) && Isyuy2(Source) ? vmNewDiff2.ConvertToYUY2().interleaved2planar() : vmNewDiff2
  959.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2, planar=true ), 1, planar=true )
  960.  
  961.     # Reweave final result
  962.     newfd = Isyuy2(Source) ? newFields.planar2interleaved().ConvertToYV16().mt_makediff( vmNewDiff3.planar2interleaved().ConvertToYV16(), U=3,V=3 ).ConvertToYUY2().interleaved2planar() : \
  963.     newFields.mt_makediff( vmNewDiff3, U=3,V=3 )
  964.     return Interleave( srcFields, newfd).SelectEvery( 4, 0,1,3,2 ).Weave()
  965. }
  966.  
  967.  
  968. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  969. # the source without introducing shimmer. All other arguments defined in main script
  970. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  971.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  972.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  973.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  974.                                  float MatchEnhance, int EdiThreads, bool lsb )
  975. {
  976.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  977.     yuy2 = Source.IsYUY2()
  978.     Source = yuy2 ? Source.interleaved2planar() : Source
  979.  
  980.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  981.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  982.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  983.     # this new source. Result will still be shimmer-free and closer to the original source.
  984.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  985.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  986.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  987.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  988.     errorTemporalSimilarity = 0.5  # S in formula described above
  989.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  990.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  991.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  992.                         ? Source : yuy2 ? mt_lutxy( Source.planar2interleaved().ConvertToYV16(), match1Clip.planar2interleaved().ConvertToYV16(), "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : \
  993.                         mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  994.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  995.                      !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  996.                              match1Update.planar2interleaved() \
  997.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  998.                                          .interleaved2planar()
  999.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  1000.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  1001.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  1002.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? yuy2 ? match1Degrain1.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1003.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? yuy2 ? match1Degrain2.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1004.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1005.                      (MatchTR1 == 0)   ? match1Edi : \
  1006.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1007.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1008.  
  1009.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1010.     malu26 = (SourceMatch > 1 && MatchEnhance > 0.0) ? yuy2 ? match1.planar2interleaved().ConvertToYV16().mt_lutxy( match1.RemoveGrain( 12, planar=true ).planar2interleaved().ConvertToYV16(), \
  1011.     "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : nop() : nop()
  1012.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? !yuy2 ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : malu26 : match1
  1013.  
  1014.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1015.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1016.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1017.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1018.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1019.     matchdifyuyin26= (SourceMatch > 1) ? yuy2 ? mt_makediff( Source.planar2interleaved().ConvertToYV16(), match2Clip.planar2interleaved().ConvertToYV16(), U=3,V=3 ).ConvertToYUY2().interleaved2planar() : nop() : nop()
  1020.     match2Diff     = (SourceMatch > 1) ? !yuy2 ? mt_makediff( Source, match2Clip, U=3,V=3 ) : matchdifyuyin26 : NOP()
  1021.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1022.                      !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1023.                              match2Diff.planar2interleaved() \
  1024.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1025.                                        .interleaved2planar()
  1026.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  1027.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  1028.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  1029.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? yuy2 ? match2Degrain1.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1030.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? yuy2 ? match2Degrain2.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1031.     match2         = (SourceMatch < 2) ? match1 : \
  1032.                      (MatchTR2 == 0)   ? match2Edi : \
  1033.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1034.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1035.  
  1036.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1037.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1038.     matlutin26 = !(SourceMatch < 3 || MatchTR2 == 0) ? yuy2 ? mt_lutxy( match2Edi.planar2interleaved().ConvertToYV16(), match2.planar2interleaved().ConvertToYV16(), \
  1039.     "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 ).ConvertToYUY2().interleaved2planar() : nop() : nop()
  1040.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1041.                          ? match2Edi : !yuy2 ? mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 ) : matlutin26
  1042.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, planar=true ) : NOP()
  1043.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  1044.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, planar=true, lsb=lsb ) : NOP()
  1045.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? yuy2 ? match3Degrain1.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1046.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? yuy2 ? match3Degrain2.planar2interleaved().ConvertToYV16().ditherpost(mode=6, slice=false).ConvertToYUY2().interleaved2planar() : match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1047.     match3         = (SourceMatch < 3) ? match2 : \
  1048.                      (MatchTR2 == 0)   ? match3Update : \
  1049.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1050.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1051.  
  1052.     # Apply difference calculated in source-match refinement
  1053.     return (SourceMatch < 2) ? match1 : yuy2 ? match1Shp.planar2interleaved().ConvertToYV16().mt_adddiff( match3.planar2interleaved().ConvertToYV16(), U=3,V=3 ).ConvertToYUY2().interleaved2planar() : \
  1054.     match1Shp.mt_adddiff( match3, U=3,V=3 )
  1055. }
  1056.  
  1057.  
  1058. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1059. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1060. {
  1061.     Replace = default( Replace, false )
  1062.     globalName = Prefix + "_" + Name
  1063.  
  1064.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1065.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1066.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1067.     catch (e)
  1068.     {
  1069.         Eval( "global " + globalName + " = Value" )
  1070.         Replace = true
  1071.     }
  1072.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1073. }
  1074.  
  1075. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1076. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1077. {
  1078.     Reuse = default( Reuse, false )
  1079.     globalName = Prefix + "_" + Name
  1080.  
  1081.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1082.     catch (e) { ret = NOP() }
  1083.     return ret
  1084. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!