Zielarstwo_Menu-v2.9.txt

; Makro: Zielarstwo_Menu-v2.9.txt
; Autor: Janusz [Frisky]
;======================================
;--- OPIS
; Skrypt zbiera wybrany rodzaj ziolek lub wszystkie lacznie
; z grzybkami i truflami
;-- Opis przyciskow:
; Start - uruchamia zebiranie do okolapostaci
; Sadzenie - sadzi szczepki ktore sa w plecaku postaci
;          jesli chcesz sadzic tylko jeden rodzaj rosliny trzymaj w lecaku
;          tylko jeden rodzaj szczepek.
; Stop - przerywa zrywanie, sadzenie, obcinanie i  przezucanie
; Obcinaj - obcina wszystkie krzaczki w plecaku
; Przezucaj - przezuca szczepki i zolka do plecakow o podanym id
;     Jak sprawdzic id plecaka? Otworz go i po prawej stronie w EasyUO w galezi
;     Container Info przepisz lub skopiuj zawartosc do zmiennej %ID_Plecaka_Na_Ziola
;     tak jak jest to nizej to smao ze zmienna %ID_Plecaka_Na_Szczepki

;UWAGA!! Tu wpisz id plecakow !! Mozna podac to samo id, wtedy wszystkie ziola/szczepki/krzaczki
; wyladuja w tym samym plecaku
set %ID_Plecaka_Na_Ziola OGTVYPD     ;Tu wpisz ID plecaka na obciete ziola
set %ID_Plecaka_Na_Szczepki OGTVYPD  ;Tu wpisz ID plecaka na szczepki
set %ID_Plecaka_Na_Krzaczki OGTVYPD  ;Tu wpisz ID plecaka na nie obciete ziola
set %Bank 1                 ; 1 - po wcisnieciu przerzucaj krzyknie do bankiera o skrzynie
                            ; 0 - po wcisnieciu przerzucaj krzyknie do magazyniera o skrzynie
;======================================
set %Szczepki CBF_GJJ_OIJ_CJJ_UIJ
set %TypyKrzaczkow VIJ_LIJ_HJJ_ZIJ
set %Click_Przerwij_X 187
set %Click_Przerwij_Y 165
set #lpc 2000
menu hideEUO
menu clear
menu window color btnface
menu window size 210 165
menu window title Zielarstwo 2.9
;=================== Rodzaj setu =====================
menu font size 8
menu text mtmiasto 10 1 Co zbieramc.
menu font size 10
menu font bgcolor white
menu combo create mcprodukt 10 20 190
menu combo add mcprodukt Wszystko
menu combo add mcprodukt Czosnek
menu combo add mcprodukt Mandragora
menu combo add mcprodukt Wilcze jagody
menu combo add mcprodukt Zenszen
menu combo add mcprodukt Krwawy mech
menu combo add mcprodukt Grzybki
;menu combo add mcprodukt Trufle
menu combo select mcprodukt 1
;------------------- Pole szukania ----------------
menu font bgcolor btnface
menu font size 8
menu text mtmiasto 10 56 Pole szukania.
menu Edit mePoleSz 100 52 25 14
;------------------ Wywalaj szczepki -----------
;menu text mtmiasto 135 60 Wywal
menu check mcWywalSzczepki 10 110 150 20 #false Wyrzucac Szczepki ?
;-----------------------------------------------
menu font bgcolor btnface
menu font size 9
;=================== przyciski =================
menu font color green
menu font style b
menu font bgcolor btnface
menu button mbstart 10 135 60 24 Start
menu font color black
menu button mbsadz 75 135 60 24 Sadzenie
menu button mbstop 140 135 60 24 Stop
menu button mbobcinaj 10 80 90 24 Obcinaj
menu button mbprzezucaj 110 80 90 24 Przerzucaj
menu show
;===============================================
set #lpc 10
set #menubutton N/A
repeat
    if #menubutton = mbsadz
       {
       set #menubutton N/A
       gosub ChodzenieDoSadzenia
       }
    if #menubutton = mbstart
      {
      set #menubutton N/A
      menu delete mbstart

      menu get mcprodukt
      set %nr_produktu #menures
      ignoreitem reset
      if %nr_produktu = 1
         set %Rodzaj_rosliny XIJ_NIJ_TIJ_FJJ_KBF
      if %nr_produktu = 2
         set %Rodzaj_rosliny XIJ
      if %nr_produktu = 3
         set %Rodzaj_rosliny NIJ
      if %nr_produktu = 4
         set %Rodzaj_rosliny TIJ
      if %nr_produktu = 5
         set %Rodzaj_rosliny FJJ
      if %nr_produktu = 6
         set %Rodzaj_rosliny TIJ
      if %nr_produktu = 7
         set %Rodzaj_rosliny KBF
      menu get mePoleSz
      set %Max_odleglosc #menures
      menu get mcWywalSzczepki
      set %WywalanieSzczepek #menures
      gosub SkanujTeren
      gosub MainLoop
      }
    if #menubutton = mbobcinaj
      {
      set #menubutton N/A
      gosub Obcinaj
      }
    if #menubutton = mbprzezucaj
      {
      set #menubutton N/A
      gosub Przezucaj
      }
    if #menubutton = CLOSED ;wcisnieto przycisk X
      {
      menu hide
      set #menubutton N/A
      halt
      }
until #false
;-------------------------------------------------
sub SkanujTeren ; jedziem
  event sysmessage Szukam krzaczkow.
  finditem %Rodzaj_rosliny G_ , %Max_odleglosc
  set #lpc 2000
  for #findindex 1 #findcnt
  {
    wait 3
    set %_x . #findindex #findx ;tworzenie tablicy
    set %_y . #findindex #findy ;tworzenie tablicy
    set %_z . #findindex #findz ;tworzenie tablicy
    set %krzak_id_ . #findindex #findid
    ignoreitem #findid
  }
  set #lpc 10
  set %IloscKrzaczkow #findcnt
  event sysmessage Znaleziono #findcnt krzaczkow.
return
;-------------------------------------------------
sub MainLoop ;parametr: ilosc znalezionych krzaczkw
  for %j 1 %IloscKrzaczkow
      {
      gosub Podejdz_do_rosliny %_x . %j %_y . %j %_z . %j
      if #RESULT = PetlaPrzyciskow
         return
      gosub Zrywaj_rosliny %krzak_id_ . %j
      if #RESULT = WcisnietoStop
         return
      ignoreitem %krzak_id_ . %j
      gosub WywalSzczepki
      }
  event sysmessage KONIEC. Wszystkie rosliny oberwane.
  gosub Rysuj_przycisk_start
  ignoreitem reset
return
;--------------------------------------------------
sub Podejdz_do_rosliny
  set %krzaczek_x %1
  set %krzaczek_y %2
  set %krzaczek_z %3
  move %krzaczek_x %krzaczek_y 0 5s
  if #menubutton = mbstop
  {
     set #menubutton N/A
     gosub Rysuj_przycisk_start
     return PetlaPrzyciskow
  }
  if #CHARPOSX <> %krzaczek_x && #CHARPOSY <> %krzaczek_y
     {
      set %czas #scnt + 6
      event pathfind %krzaczek_x %krzaczek_y %krzaczek_z
      repeat
        if #menubutton = mbstop
        {
           set #menubutton N/A
           gosub Rysuj_przycisk_start
           return PetlaPrzyciskow
        }
        if %czas < #scnt
        {
            set %czas #scnt + 6
            event pathfind %krzaczek_x %krzaczek_y %krzaczek_z
        }
        scanjournal 1
        if _Can't_get_there in #journal || stoisz_za_daleko in #journal || _That_is_too in #journal
        {
            move %krzaczek_x %krzaczek_y 0 5s
            return
        }
      until #CHARPOSX = %krzaczek_x && #CHARPOSY = %krzaczek_y
     }
return
;--------------------------------------------------
sub Zrywaj_rosliny
  set %krzak_id %1
  set #LTARGETKIND 2
  set #LOBJECTID %krzak_id
  event macro 17
  set %czas #scnt + 9
  wait 1s
  scanjournal 1
  if _I_can't_see_that. in #journal || _That_is_too in #journal
     {
     ignoreitem %krzak_id
     return
     }
  repeat
     scanjournal 1
     if %czas < #scnt
        {
        set #LTARGETKIND 2
        set #LOBJECTID %krzak_id
        event macro 17
        set %czas #scnt + 9
        wait 1s
        }
     if Z_tej_rosliny in #journal || stoisz_za_daleko in #journal
        return
  until Zaczynasz in #journal

  set %SprawdzPierwszyRaz 1
  set %Licznik 0
  set %JIndexStart #jindex
  repeat
      if %JIndexStart = #jindex
         {
         wait 1s
         }
      else
         {
         if %SprawdzPierwszyRaz = 1
            {
            set %Licznik #jindex
            set %SprawdzPierwszyRaz 0
            scanjournal %Licznik
            }
         else
           {
            set %Licznik ( %Licznik - 1 )
            if %JIndexStart = %Licznik
               set %Licznik #jindex
            scanjournal %Licznik
           }
         }
      if #menubutton = mbstop
        {
        click %Click_Przerwij_X %Click_Przerwij_Y
        gosub Rysuj_przycisk_start
        return WcisnietoStop
        }
      if Z_tej_rosliny in #journal || _I_can't_see_that. in #journal || _That_is_too in #journal
         break
  until #false
  ignoreitem %krzak_id
return
;--------------------------------------------------
sub Obcinaj
  gosub nozyczki
  if #RESULT = NozyczekBrak
     return
  finditem %TypyKrzaczkow C_ , #backpackid
  set %WyjdzZPetli 0
  for #findindex 1 #findcnt
     {
     set #lobjectid #findid
     event macro 17
     set %TimeObcinania #scnt2 + 20
     repeat
         if %TimeObcinania < #scnt2
            {
             set #lobjectid #findid
             event macro 17
             set %TimeObcinania #scnt2 + 20
            }
     until Rozpocz in #sysmsg
     repeat
         wait 2s
         gosub SprawdzGumpa
     until %WyjdzZPetli = 1
     set %WyjdzZPetli 0
     }
return
;--------------------------------------------
sub SprawdzGumpa
  set #lpc 2000
  set %dziennik #SYSMSG
  ;event sysmessage dziennik %dziennik
  str Pos %dziennik )
  set %Pozycja_nawiasu #StrRes
  set %end %Pozycja_nawiasu - 2
  str Mid %dziennik 2 %end
  set %Tyle_z_Tylu #StrRes
  str Pos %Tyle_z_Tylu z
  set %z_end #StrRes - 2
  str Mid %Tyle_z_Tylu 1 %z_end
  set %Pierwsza_wartosc #StrRes
  ;event sysmessage Pierwsza_wartosc %Pierwsza_wartosc
  str Pos %Tyle_z_Tylu _
  set %__start #StrRes + 3
  str Len %Tyle_z_Tylu
  set %Dlugosc #StrRes
  str Mid %Tyle_z_Tylu %__start %Dlugosc
  set %Druga_wartosc #StrRes
  ;event sysmessage Wartosci: %Pierwsza_wartosc z %Druga_wartosc
  if %Pierwsza_wartosc > %Druga_wartosc
     {
     click %Click_Przerwij_X %Click_Przerwij_Y
     set %WyjdzZPetli 1
     wait 6s
     set #lpc 10
     return
     }
  if %Pierwsza_wartosc = %Druga_wartosc
     {
     scanjournal 1
     if #JCOLOR = 40
        {
        click %Click_Przerwij_X %Click_Przerwij_Y
        wait 6s
        }
     set %WyjdzZPetli 1
     }
  else
     {
     set #lpc 10
     return
     }
  set #lpc 10
return
;---------------------------------------------
sub Przezucaj
  if 180_240 notin #CONTSIZE
  {
      if %Bank = 1
      {
         event macro 1 0 Bankier daj moja skrzynie.
      }
      else
      {
         event macro 1 0 Magazynier daj moja skrzynie.
      }
      set %timer #scnt + 10
      repeat
       if #menubutton = mbstop
       {
          set #menubutton N/A
          event sysmessage Przezucanie przerwane.
          return
       }
       if %timer < #scnt
       {
          event sysmessage Nie znaleziono otwartej skrzyni bankowej.
          return
       }
      until 180_240 in #CONTSIZE
  }
  set #lobjectid %ID_Plecaka_Na_Ziola
  event macro 17
  set %time #scnt2 + 20
  repeat
     if #menubutton = mbstop
     {
        set #menubutton N/A
        event sysmessage Przezucanie przerwane.
        return
     }
     if %time < #scnt2
     {
        set #lobjectid %ID_Plecaka_Na_Ziola
        event macro 17
        set %time #scnt2 + 20
     }
  until #CONTID = %ID_Plecaka_Na_Ziola
  ;przezucanie ziol
  finditem KZF_JUF_JZF_MZF_PZF_WZF_XWS C_ , #backpackid
  if #findkind <> -1
  {
      for #findindex 1 #findcnt
      {
           if #findstack = 0
              exevent drag #findid 1
           else
              exevent drag #findid #findstack
           wait 5
           exevent dropc %ID_Plecaka_Na_Ziola
           wait 5
      }
  }
  set %timeBrakPlecaka #scnt2 + 50
  set #lobjectid %ID_Plecaka_Na_Szczepki
  event macro 17
  set %time #scnt2 + 20
  repeat
   if #menubutton = mbstop
      {
      set #menubutton N/A
      event sysmessage Przezucanie przerwane.
      return
      }
   if %time < #scnt2
      {
      set #lobjectid %ID_Plecaka_Na_Szczepki
      event macro 17
      set %time #scnt2 + 20
      }
   if %timeBrakPlecaka < #scnt2
      {
      event sysmessage Nie ma plecaka na szczepki.
      return
      }
  until #CONTID = %ID_Plecaka_Na_Szczepki
  ;przezucanie szczepek
  finditem %Szczepki C_ , #backpackid
  if #findkind <> -1
  {
      for #findindex 1 #findcnt
      {
           if #findstack = 0
              exevent drag #findid 1
           else
              exevent drag #findid #findstack
           wait 5
           exevent dropc %ID_Plecaka_Na_Szczepki
           wait 5
      }
  }
  set %timeBrakPlecaka #scnt2 + 50
  set #lobjectid %ID_Plecaka_Na_Krzaczki
  event macro 17
  set %time #scnt2 + 20
  repeat
   if #menubutton = mbstop
      {
      set #menubutton N/A
      event sysmessage Przerzucanie przerwane.
      return
      }
   if %time < #scnt2
      {
      set #lobjectid %ID_Plecaka_Na_Krzaczki
      event macro 17
      set %time #scnt2 + 20
      }
   if %timeBrakPlecaka < #scnt2
      {
      event sysmessage Nie ma plecaka na szczepki.
      return
      }
  until #CONTID = %ID_Plecaka_Na_Krzaczki
  ;przezucanie szczepek
  finditem %TypyKrzaczkow C_ , #backpackid
  if #findkind <> -1
  {
      for #findindex 1 #findcnt
      {
           if #findstack = 0
              exevent drag #findid 1
           else
              exevent drag #findid #findstack
           wait 5
           exevent dropc %ID_Plecaka_Na_Krzaczki
           wait 5
      }
  }
  event sysmessage Przedmioty przezucone.
return
;---------------------------------------------
sub WywalSzczepki
  if %WywalanieSzczepek = #false
     return
  finditem %Szczepki C_ , #backpackid
  if #findkind = -1
  {
     return
  }
  for #findindex 1 #findcnt
     {
       finditem %Szczepki C_ , #backpackid
       if #findstack = 0
          exevent drag #findid 1
       else
          exevent drag #findid #findstack
       wait 5
       exevent dropg #CHARPOSX #CHARPOSY #CHARPOSZ
       wait 5
     }
return
;-----------------------------------------------
sub Rysuj_przycisk_start
  set #menubutton N/A
  menu font color green
  menu font style b
  menu font bgcolor btnface
  menu button mbstart 10 135 60 24 Start
return
;-----------------------------------------------
sub ChodzenieDoSadzenia
  set %Start_X #CHARPOSX
  set %Start_Y #CHARPOSY
  for %i 1 5
      {
      for %j 1 8
          {
          set %krok_x %Start_X
          set %krok_y %Start_Y + %j
          move %krok_x %krok_y 0 20s
          gosub Sadzenie
          if #RESULT = KoniecSadzenia
             {
             event sysmessage Sadzenie przerwane.
             return
             }
          }
      set %Start_X %Start_X + 1
      }
event sysmessage KONIEC SADZENIA.
return
;-------------------------------------------
sub Sadzenie
   finditem OIJ_GJJ_CJJ_UIJ C
   if #findkind = -1
      {
      event sysmessage Nie masz szczepek.
      return
      }
   set #lobjectid #findid
   event macro 17
   set %TimeCel #scnt2 + 20
   repeat
       if %TimeCel < #scnt2
          {
           set #lobjectid #findid
           event macro 17
           set %TimeCel #scnt2 + 20
          }
   until #targcurs = 1

   set #LTARGETX #CHARPOSX
   set #LTARGETY #CHARPOSY
   set #LTARGETZ #CHARPOSZ
   set #LTARGETKIND 2
   event macro 22
   set %TimeSadzenia #scnt2 + 20
   set %Time2 #scnt + 10
   repeat
      if %TimeSadzenia < #scnt2
         {
         event macro 22
         set %TimeSadzenia #scnt2 + 20
         }
      scanjournal 1
   until Probujesz in #journal

   repeat
    set %SprawdzPierwszyRaz 1
    set %Licznik 0
    set %JIndexStart #jindex
    repeat
        if %JIndexStart = #jindex
           {
           wait 1s
           }
        else
           {
           if %SprawdzPierwszyRaz = 1
              {
              set %Licznik #jindex
              set %SprawdzPierwszyRaz 0
              scanjournal %Licznik
              }
           else
             {
              set %Licznik ( %Licznik - 1 )
              if %JIndexStart = %Licznik
                 set %Licznik #jindex
              scanjournal %Licznik
             }
           }
        if #menubutton = mbstop
          {
          click %Click_Przerwij_X %Click_Przerwij_Y
          gosub Rysuj_przycisk_start
          return KoniecSadzenia
          }
   until Udalo in #journal
return
;-------------------------------------------
sub nozyczki
  finditem KAG C
  for #findindex 1 #findcnt
     {
      if #findtype = KAG
         {
          set %nozyczkiID #findid
         }
     }
  if N/A in %nozyczkiID
     {
      event sysmessage NIE MASZ NOZYCZEK W PLECAKU. SKRYPT ZATRZYMANY.
      return NozyczekBrak
     }
return
;Roslinki do zbierania:
; XIJ - czosnek
; NIJ - mandragora OIJ - szczepka
; TIJ - wilcze jagody
; FJJ - zenszen
; TIJ - krwawy mech
; KBF - grzybki
;Roslinki do wywalenia:
; CBF - szczepki grzybkow
; GJJ - szczepki wilczych jagod
; OIJ - szczepki mandragory