CarePackage v3

#include <a_samp>
#include <streamer>
#include <zcmd>
#include <foreach>

#define CAREPACKRESPAWN 120000
enum cPack {
	bool:CarePackageUsed,
	bool:CarePackageLanded,
	bool:PlaneMoveStage,
	Float:CarePackageRotation,
	CarePackagePlane,
	CarePackageFlare,
	CarePackageParachute,
	CarePackageBox,
	CarePackageStuff,
	Float:CarePackageLand[3],
	Text3D:CarePackageText,
	CarePackageInterior,
	CarePackageWorld,
}
enum cPstuff {
	type,
	id,
	name[26],
	value
}
new CarePackageContains[][cPstuff] = {
	{0,9,"Chainsaw",1},
	{0,22,"Colt-45",50},
	{0,23,"Colt-45 Silenced",50},
	{0,24,"Desert Eagle",50},
	{0,25,"Shotgun",50},
	{0,26,"Sawnoff Shotgun",50},
	{0,27,"Combat Shotgun",50},
	{0,28,"Micro SMG/Uzi",50},
	{0,29,"MP5",50},
	{0,30,"AK-47",50},
	{0,31,"M4",50},
	{0,32,"TEC-9",50},
	{0,33,"Country Rifle",50},
	{0,34,"Sniper Rifle",50},
	{0,35,"RPG",50},
	{0,36,"Heat Seeker",50},
	//{0,38,"Minigun",50},
	{0,37,"Flamethrower",50}
};
#define MAX_CARE_PACKAGES 25
new pCarePackage[MAX_CARE_PACKAGES][cPack];
new Iterator:CarePackages<MAX_CARE_PACKAGES>;
new CarePackageDespawnTimer[MAX_CARE_PACKAGES];
public OnFilterScriptInit() {
	print("\n--------------------------------------");
	print("Care Package System by EvilShadeZ");
	print("--------------------------------------\n");
	return 1;
}
CMD:carepackage(playerid, params[])
{
  	//if(pCarePackage[playerid][CarePackageUsed] == true) return SendClientMessage(playerid,0xFF0000FF,"Care package is already incomming");
	new Float:X,Float:Y,Float:Z;
	GetPlayerPos(playerid,Float:X,Float:Y,Float:Z);
	if(!CreateCarePackageForPlayer(playerid,Float:X,Float:Y,Float:Z)) return SendClientMessage(playerid,0xFF0000FF,"Care package limit reached!");
  	return 1;
}
stock CreateCarePackageForPlayer(playerid,Float:X,Float:Y,Float:Z) {
	new carepackid;
	for(new i = 0; i < MAX_CARE_PACKAGES; i++) {
	    if(pCarePackage[i][CarePackageUsed] == false) {
	        carepackid = i;
	        break;
	    }
	    if( i == MAX_CARE_PACKAGES-1) {
			return 0;
	    }
	}
	Iter_Add(CarePackages,carepackid);
	new angle = random(360);
	pCarePackage[carepackid][CarePackageUsed] = true;
	pCarePackage[carepackid][PlaneMoveStage] = false;
	pCarePackage[carepackid][CarePackageFlare] = CreateDynamicObject(18728,X,Y,Z-2,0,0,0,GetPlayerVirtualWorld(playerid),GetPlayerInterior(playerid),-1,250,250);
	pCarePackage[carepackid][CarePackageLand][0] = X;
    pCarePackage[carepackid][CarePackageLand][1] = Y;
    pCarePackage[carepackid][CarePackageLand][2] = Z-1.5;
    pCarePackage[carepackid][CarePackageRotation] = angle;
    pCarePackage[carepackid][CarePackageInterior] = GetPlayerInterior(playerid);
    pCarePackage[carepackid][CarePackageWorld] = GetPlayerVirtualWorld(playerid);
    GetXYFromPosWithAngle(X,Y,angle,300);
    pCarePackage[carepackid][CarePackagePlane] = CreateDynamicObject(14553,X,Y,Z+75,11.9,0,-angle,GetPlayerVirtualWorld(playerid),GetPlayerInterior(playerid),-1,500,500);
    MoveDynamicObject(pCarePackage[carepackid][CarePackagePlane], pCarePackage[playerid][CarePackageLand][0], pCarePackage[playerid][CarePackageLand][1], pCarePackage[playerid][CarePackageLand][2]+75, 30, 11.9, 0, -angle);
	foreach(new b : Player) Streamer_Update(b);
	pCarePackage[carepackid][CarePackageLanded] = false;
	return 1;
}
public OnDynamicObjectMoved(objectid) {
	foreach(new i : CarePackages) {
	    if(objectid == pCarePackage[i][CarePackagePlane]) {
	        if(pCarePackage[i][PlaneMoveStage] == false) {
	            pCarePackage[i][PlaneMoveStage] = true;
	            new Float:X,Float:Y,Float:Z,Float:PlaneFlyPos[2];
	            GetDynamicObjectPos(objectid, X, Y, Z);
             	PlaneFlyPos[0] = pCarePackage[i][CarePackageLand][0];
             	PlaneFlyPos[1] = pCarePackage[i][CarePackageLand][1];
             	GetXYFromPosWithAngle(PlaneFlyPos[0],PlaneFlyPos[1],pCarePackage[i][CarePackageRotation]+180,300);
				MoveDynamicObject(pCarePackage[i][CarePackagePlane], PlaneFlyPos[0], PlaneFlyPos[1], pCarePackage[i][CarePackageLand][2]+75, 30, 11.9, 0, -pCarePackage[i][CarePackageRotation]);
                //CarePackageParachute
                pCarePackage[i][CarePackageParachute] = CreateDynamicObject(2903,X,Y,Z,0,0,random(360),pCarePackage[i][CarePackageWorld],pCarePackage[i][CarePackageInterior],-1,200,200);
                MoveDynamicObject(pCarePackage[i][CarePackageParachute], pCarePackage[i][CarePackageLand][0], pCarePackage[i][CarePackageLand][1], pCarePackage[i][CarePackageLand][2], 15, 0, 0, random(360));
            	foreach(new b : Player) Streamer_Update(b);
				break;
	        } else if(pCarePackage[i][PlaneMoveStage] == true) {
	            DestroyDynamicObject(pCarePackage[i][CarePackagePlane]);
	            pCarePackage[i][CarePackagePlane] = -1;
         		foreach(new b : Player) Streamer_Update(b);
	            break;
	        }
	    } else if(objectid == pCarePackage[i][CarePackageParachute]) {
	        pCarePackage[i][CarePackageBox] = CreateDynamicObject(3013,pCarePackage[i][CarePackageLand][0], pCarePackage[i][CarePackageLand][1], pCarePackage[i][CarePackageLand][2]+0.7,0,0,random(360),GetPlayerVirtualWorld(i),GetPlayerInterior(i),-1,200,200);
            //CarePackageContains[][cPstuff]
            pCarePackage[i][CarePackageStuff] = random(sizeof(CarePackageContains));
            new string[128];
            pCarePackage[i][CarePackageLanded] = true;
            format(string,128,"{FFAF00}[{F3FF02}CARE PACKAGE{FFAF00}]\n{FFFFFF}%s",CarePackageContains[pCarePackage[i][CarePackageStuff]][name]);
            pCarePackage[i][CarePackageText] = Create3DTextLabel(string, 0x008080FF, pCarePackage[i][CarePackageLand][0], pCarePackage[i][CarePackageLand][1], pCarePackage[i][CarePackageLand][2]+1, 40.0, pCarePackage[i][CarePackageWorld], 0);
            CarePackageDespawnTimer[i] = SetTimerEx("DespawnCarePackage",CAREPACKRESPAWN,false,"i",i);
			DestroyDynamicObject(objectid);
	        DestroyDynamicObject(pCarePackage[i][CarePackageFlare]);
	        pCarePackage[i][CarePackageParachute] = -1;
	        pCarePackage[i][CarePackageFlare] = -1;
        	foreach(new b : Player) Streamer_Update(b);
	        break;
	    }
	}
}
forward DespawnCarePackage(i);
public DespawnCarePackage(i) {
    DestroyDynamicObject(pCarePackage[i][CarePackageBox]);
    Delete3DTextLabel(pCarePackage[i][CarePackageText]);
    pCarePackage[i][CarePackageBox] = -1;
	pCarePackage[i][CarePackageUsed] = false;
	pCarePackage[i][CarePackageLanded] = false;
	if(IsValidDynamicObject(pCarePackage[i][CarePackagePlane])) DestroyDynamicObject(pCarePackage[i][CarePackagePlane]);
	Iter_Remove(CarePackages,i);
	return 1;
}
public OnPlayerKeyStateChange(playerid, newkeys, oldkeys)
{
	if (newkeys && KEY_SECONDARY_ATTACK)
	{
	    foreach(new i : CarePackages) {
	        if(pCarePackage[i][CarePackageUsed] == true && pCarePackage[i][CarePackageLanded] == true) {
	            if(IsPlayerInRangeOfPoint(playerid,2,pCarePackage[i][CarePackageLand][0], pCarePackage[i][CarePackageLand][1], pCarePackage[i][CarePackageLand][2])) {
					KillTimer(CarePackageDespawnTimer[i]);
					DestroyDynamicObject(pCarePackage[i][CarePackageBox]);
	                Delete3DTextLabel(pCarePackage[i][CarePackageText]);
	                pCarePackage[i][CarePackageBox] = -1;
					new string[128];
					format(string,sizeof(string),"{FFAF00}[{F3FF02}CARE PACKAGE{FFAF00}]{FFFFFF} You've picked up %s from care package.",CarePackageContains[pCarePackage[i][CarePackageStuff]][name]);
					SendClientMessage(playerid,0xFFFFFFFF,string);
					OnPlayerPickUpCarePackage(playerid,pCarePackage[i][CarePackageStuff]);
					pCarePackage[i][CarePackageUsed] = false;
					pCarePackage[i][CarePackageLanded] = false;
					if(IsValidDynamicObject(pCarePackage[i][CarePackagePlane])) DestroyDynamicObject(pCarePackage[i][CarePackagePlane]);
					Iter_Remove(CarePackages,i);
					break;
				}
	        }
	    }
	}
	return 1;
}
forward OnPlayerPickUpCarePackage(playerid,pickupid);
public OnPlayerPickUpCarePackage(playerid,pickupid) {
	if(CarePackageContains[pickupid][type] == 0) GivePlayerWeapon(playerid,CarePackageContains[pickupid][id],CarePackageContains[pickupid][value]);

}
GetXYFromPosWithAngle(&Float:x, &Float:y,Float:Angle,Float:distance) {
    x += (distance * floatsin(Angle, degrees));
    y += (distance * floatcos(Angle, degrees));
}