VBS Script Clean Windows by DevilSnake88

'// Opmet Inspired by Colin Bowern: http://serverfault.com/a/341318
'// Edited by DevilSnake88
If Wscript.Arguments.Count < 1 Then
    WScript.Echo "Syntax: Supprimer-Updates-Windows7-10.vbs [Update ID]"
    WScript.Quit 1
End If

Dim objArgs
Set objArgs = Wscript.Arguments
Dim updateSession, updateSearcher
Set updateSession = CreateObject("Microsoft.Update.Session")
Set updateSearcher = updateSession.CreateUpdateSearcher()

Wscript.Stdout.Write "Recherche et traitement des mises a jour... "
Dim searchResult
Set searchResult = updateSearcher.Search("IsInstalled=0")

Dim update, kbArticleId, index, index2
WScript.Echo CStr(searchResult.Updates.Count) & " trouvee(s)."

For index = 0 To searchResult.Updates.Count - 1
    Set update = searchResult.Updates.Item(index)
    For index2 = 0 To update.KBArticleIDs.Count - 1
        kbArticleId = update.KBArticleIDs(index2)
        For Each hotfixId in objArgs
            If kbArticleId = hotfixId Then
                If update.IsHidden = False Then
                    WScript.Echo " - Mise a jour traitee: " & update.Title
                    WScript.Echo "--------------------------------------------------------------------------------", vbNewLine
                    update.IsHidden = True
                Else
                    WScript.Echo " - Mise a jour deja traitee: " & update.Title
                    WScript.Echo "--------------------------------------------------------------------------------", vbNewLine
                End If
            End If
        Next
    Next
Next
'// EOF