poserPiece flight

// Résumé : Poser un stock dans une opération
// Syntaxe :
//[ <Résultat> = ] poserPiece (<p_IdStock>, <p_IdOpération>, <p_datePose> [, <p_iIdTemps>])
//
// Paramètres :
//	p_IdStock : <indiquez ici le rôle de p_IdStock>
//	p_IdOpération : <indiquez ici le rôle de p_IdOpération>
//	p_datePose : <indiquez ici le rôle de p_datePose>
//	p_iIdTemps (valeur par défaut=0) : <indiquez ici le rôle de p_iIdTemps>
// Valeur de retour :
// 	booléen : <indiquez ici les valeurs possibles ainsi que leur interprétation>
//
// Exemple :
// Indiquez ici un exemple d'utilisation.
//
PROCEDURE poserPiece(LOCAL p_IdStock, LOCAL p_IdOpération,LOCAL p_datePose,LOCAL p_iIdTemps=0)

	// Recherche du stock
	HLitRecherchePremier(Stock,IDStock,p_IdStock)
	SI PAS HTrouve(Stock) ALORS
		RENVOYER Faux
	FIN

	// Recherche de l'opération
	HLitRecherchePremier(Operation,IDOperation,p_IdOpération)
	SI PAS HTrouve(Operation) ALORS
		RENVOYER Faux
	FIN

	// Recherche de l'aéronef
	HLitRecherchePremier(Aéronef,IDAéronef,Operation.IDAéronef)
	SI PAS HTrouve(Aéronef) ALORS
		RENVOYER Faux
	FIN

	SI PAS HRAZ(StockOperation) ALORS
		Erreur(ErreurInfo())
		RENVOYER Faux
	FIN

	//on supprime du stock tempotraire (le cas échéant)
	//Puis on ajoute a StockOperation
	sRequete est une chaîne="DELETE FROM StockTemporaire WHERE IdStock="+p_IdStock
	sdStock est une Source de Données
	SI PAS HExécuteRequêteSQL(sdStock,sRequete) ALORS
		Erreur(ErreurInfo())
		RENVOYER Faux
	FIN

	// Ajouter la liaison entre operation<->stock
	//
	HRAZ(StockOperation)
	StockOperation.IDOperation = p_IdOpération
	StockOperation.IDStock = p_IdStock
	SI PAS HAjoute(StockOperation) ALORS
		RENVOYER Faux
	FIN

	// Modification du stock
	//
	Stock.Enstock = Faux
	Stock.Quantité = 0

	Stock.TOIa = Aéronef.TSN
	Stock.TOOa = Stock.TOIa + Stock.TTO
	Stock.COIa = Aéronef.CSN

	SI PAS HModifie(Stock) ALORS
		RENVOYER Faux
	FIN

	// Ajout des histo stock
	//
	HRAZ(HistoStock)
	HistoStock.IDTempsTacheWO = p_iIdTemps
	HistoStock.IDStock = Stock.IDStock
	HistoStock.Etat=REPOSE
	HistoStock.IDOperation = StockOperation.IDOperation
	HistoStock.IDStockOperation = StockOperation.IDStockOperation
	HistoStock.DateInstallation = p_datePose
	HAjoute(HistoStock)

	PieceVersOperation(p_IdStock)

	RENVOYER Vrai