NMC2

#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Magenta
#property indicator_color2 Silver
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int    NMC2_period         = 40;
extern bool   Use_NMR_instead_NMM = false;
extern bool   Show_SD             = true;
extern int    SD_len              = 30;
extern double SD_up               = 2;
extern double SD_dn               = 2;

double NMC2[];
double SD[];

int init()
{
  string whichone = "NMM";
  if(Use_NMR_instead_NMM) whichone = "NMR";
  string nmc2name = "NMC2(" + NMC2_period + ", using " + whichone + ")";
  string sdname = "NMC2_SD(" + SD_len + ")";
  IndicatorShortName(nmc2name);
  IndicatorBuffers(2);
  SetIndexBuffer(0, NMC2);
  SetIndexLabel(0, nmc2name);
  SetIndexBuffer(1, SD);
  SetIndexLabel(1, sdname);
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();

  if(Bars <= NMC2_period) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMC2_period) limit = Bars - counted_bars;
  else                           limit = Bars - NMC2_period - 1;

  for(i = limit; i >= 0; i--)
    {
    double nms, nmm, nmr, nms2 = 0, nmm2 = 0, nmr2 = 0, whichone, avg, sign;
    for(ii = 1; ii <= NMC2_period; ii++)
      {
      double oLRSlope = 0, SumXY = 0, SumY = 0, SumX, SumXSqr, Divisor;
      if(ii > 1)
        {
        SumX = ii * (ii - 1) * 0.5;
        SumXSqr = ii * (ii - 1) * (2 * ii - 1) * 1/6;
        Divisor = (SumX * SumX) - ii * SumXSqr;
        for(int iii = 0; iii < ii; iii++)
          {
          SumXY += iii * MathLog(Close[i+iii]);
          SumY += MathLog(Close[i+iii]);
          }
        oLRSlope = (ii * SumXY - SumX * SumY) / Divisor;
        }
      nms2 += oLRSlope * MathSqrt(ii);
      nmm2 += (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
      nmr2 += (MathLog(Close[i+ii-1]) - MathLog(Close[i+ii])) * (MathSqrt(ii) - MathSqrt(ii-1));
      }
    nms = nms2 * 100;
    nmm = (nmm2 / NMC2_period) * 1000;
    nmr = nmr2 * 1000;
    if(Use_NMR_instead_NMM) whichone = nmr;
    else                    whichone = nmm;
    avg = ((MathAbs(nms) * whichone) + (MathAbs(whichone) * nms)) / 2;
    if(avg > 0)      sign = 1;
    else if(avg < 0) sign = -1;
    else             sign = 0;
    NMC2[i] = sign * MathSqrt(MathAbs(avg));
    }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMC2_period - 1 - SD_len)
        {
        if(NMC2[i] == 0)     SD[i] = 0;
        else if(NMC2[i] > 0) SD[i] = iBandsOnArray(NMC2, 0, SD_len, SD_up, 0, MODE_UPPER, i);
        else if(NMC2[i] < 0) SD[i] = iBandsOnArray(NMC2, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
        }

  return(0);
}