python2-pysces 0.8.0rc4 PKGBUILD

# Maintainer: Michael Schubert <mschu.dev at gmail>

pkgname=python2-pysces
_projectname=pysces
pkgver=0.8.0rc4
pkgrel=1
pkgdesc="Python simulator for Cellular Systems"
arch=('i686' 'x86_64')
depends=('python2-scipy' 'python2-matplotlib')
optdepends=('gnuplot: as an alternative plotting back-end and 3D plots'
            'ipython2: for interactive modelling sessions (highly recommended)'
            'libsbml: for SBML import and export'
            'python2-pysundials: for CVODE and Events support'
            'python2-pysces-metatool: for elementary mode support')
makedepends=('gcc-fortran')
url="http://pysces.sourceforge.net/"
license=('BSD' 'GPL')
source=("https://downloads.sourceforge.net/project/$_projectname/$_projectname/$_projectname-0.7/$_projectname-$pkgver.zip" "setup.py.patch")
md5sums=('85b76ff80536c303ff8ba2f3992720a3' 'fcab712678ee33a6943235d90a1ecd30')

build() {
  cd "$srcdir/pysces-$pkgver"
  # Arch Linux: 9 Fortran modules should be built as shared library
  # https://sourceforge.net/p/pysces/bugs/9/
  patch -p0 < "$srcdir/setup.py.patch"
  python2 setup.py build
}

package() {
  cd "$srcdir/pysces-$pkgver"
  python2 setup.py install --root="$pkgdir/" --skip-build --optimize=1
}